xcgh
xcgh

ASP的数据库类

一、前言
　　提到ASP操作数据库，大多数人会想到：共用的连接字串ConStr、Conn.Open ConStr建立数据库连接、Conn.Execute SqlCmd方式执行命令、RecordSet.Open Sql,Conn,1,1取得记录集，的确这种方法被99%的人或公司采用。对于操作数据库过程中产生的错误，恐怕99%的人不会进行处理，要么在程序的开头加入on error resume next“轻松”跳过去、要么让错误信息连同错误代码一同“暴尸”在浏览者面前。对于前一种情况可能会产生让人莫明其妙的怪异结果，后一种情况，可能会在某个时间（比如连接数据库时）暴露您的敏感信息，影响网站安全。当然，还是有个别负责的程序员同志会在容易产生错误的操作后面加入if err.xxxx来处理可能的错误，但这似乎不是一个好办法，一不小心就可能漏掉了。
　　我至今也没有想明白，为什么在VB和ASP.NET中都存在的On Error Goto，偏偏在ASP中被取消了。
　　另外不得不提的是，当您在前面使用on error resume next而在后面不想resume next了，对不起，没办法，您只能把它“贯彻到底”。看看其它语言的异常机制，try..catch..finally随心所欲，真是爽酷了！

　　说了这么多，并不要为ASP引入诸如异常机制等新的内容，毕竟ASP语言本身也决定这是不可能实现的（ASP.NET中实现了），只是想在ASP中最普遍的也是最容易出现错误的数据库操作中，找到一种有效的错误处理方式，并把conn、RecordSet等封装起来，达到最大限度的精简。于是便有了下面的数据库类。


二、数据库类
1、功能
　　正如前面所说，这个类的目的是把ADODB.Connection、Adodb.Recordset等烦琐的操作封装起来并在类里实现错误处理。现在看看类的成员、属性和方法：
　　1）成员：（没有公有或保护成员）
　　2）属性：
　　　　ClassName－返回类名
　　　　Version－返回版本
　　　　LastError－返回最后的错误
　　　　IgnoreError－设置/返回是否忽略数据库错误
　　　　Connection－返回连接对象（ADODB.Connection）
　　　　ConnectionString－设置/返回连接字串（本示例为SQL Server，如为其它请根据实际设定）
　　　　FieldCount、PageSize、PageCount、AbsolutePage、AbsolutePosition、Bof、Eof－请参考Adodb.Recordset相应内容
　　3）方法：
　　　　Setup－设置连接数据服务器的帐号、密码、数据库名、主机/IP
　　　　Connect－连接数据库
　　　　Close－关闭数据库连接并释放资源
　　　　Query－执行数据库查询命令并返回数据集
　　　　ExeSQL－执行SQL命令（不返回数据库）
　　　　FieldName－返回指定序号的字段名
　　　　Fields－返回指定的（序号或字段名）字段的值
　　　　Data－同上
　　　　MoveNext、MovePrevious、MoveFirst、MoveLast－请参考Adodb.Recordset相应内容


2、实现代码（DBSql.inc.asp）

内容太长，点击此处打开/折叠...
<%
'========================================================================
' CLASS NAME:  clsDB
' DESIGN BY :    彭国辉
' DATE:              2003-12-18
' SITE:               http://kacarton.yeah.net/
' Blog:               http://blog.csdn.net/conch
' EMAIL:             [email protected]
' MODIFY:
'   2004-6-25: 升级后的数据引擎，返回错误代号小于0（也可以是ASP对数值的
'              定义有变），修改错误检测err.number>0 ==> err.number<>0
'   2004-6-30：修改错误处理，忽略如游标类型改变等非错误性质的提示
'
'文章为作者原创，转载前请先与本人联系，转载请注明文章出处、保留作者信息，谢谢支持！
'========================================================================

 

Class clsDB

  ' name of this class
  ' var string
  ' @access    Private
  ' @see       property: Name
  Private m_strName

  ' version of this class
  ' var string
  ' @access    Private
  ' @see       property: Version
  Private m_strVersion

  ' Error Object
  ' @var ADODB.Connection.Errors
  ' @access    private
  ' @see       property: LastError
  Private m_LastError
 
  ' Ingore all Connection.Errors
  ' var Boolean
  ' @access    private
  ' @see       property: IgnoreError
  Private m_IgnoreError

  ' Connection Object
  ' var ADODB.Connection
  ' @access    Private
  ' @see       property: Connection
  Private m_Connection
 
  ' Is connection to database?
  ' var boolean
  ' @Private
  Private m_bIsConnect

  ' RecordSet
  ' var RecordSet
  ' @access    Private
  Private m_RecordSet

  ' Connection string
  ' var string
  ' @access    Private
  ' @see       property: ConnectionString
  Private m_ConneStr

  ' Database server host name or IP
  ' var string
  ' @access    Private
  ' @see       property: Host
  Private m_strHost

  ' Database name
  ' var string
  ' @access    Private
  ' @see       property: Database
  Private m_strDatabase

  ' Account to connection database
  ' var string
  ' @access    Private
  ' @see       property: UserName
  Private m_UserName

  ' Password to connection database
  ' var string
  ' @access    Private
  ' @see       property: Password
  Private m_Password

  ' get class name attribute.
  ' usage: oTemplate.Name
  ' access    public
  Public Property Get ClassName()
    ClassName = m_strName
  End Property

  ' get class version attribute.
  ' usage: oTemplate.Version
  ' access    public
  Public Property Get Version()
    Version = m_strVersion
  End Property
 
  ' Get class last error messages.
  ' usage: oTemplate.LastError
  ' @access    public
  Public Property Get LastError()
    LastError = m_LastError
  End Property
 
  ' Get or Set Ignore connection.errors
  Public Property Get IgnoreError()
    IgnoreError = m_IgnoreError
  End Property
 
  Public Property Let IgnoreError(ByVal Value)
    m_IgnoreError = Value
  End Property
 
  ' Get Connection
  Public Property Get Connection()
    Connection = m_Connection
  End Property
 
  ' Get connection string
  Public Property Get ConnectionString()
    ConnectionString = m_ConneStr
  End Property
 
  ' Set connection string
  Public Property Let ConnectionString(ByVal Value)
    m_ConneStr = Value
  End Property
 
  ' Get data fields count
  Public Property Get FieldCount()
    FieldCount = m_RecordSet.Fields.Count
  End Property
 
  ' Get RecordSet PageSize
  Public Property Get PageSize()
    on error resume next
    PageSize = m_RecordSet.PageSize
    if err.number<>0 then ShowError("Can not get PageSize!")
  End Property
 
  ' Set RecordSet Page Size
  Public Property Let PageSize(ByVal Value)
    on error resume next
    m_RecordSet.PageSize = Value
    if err.number<>0 then ShowError("Can not set PageSize to " & Value)
  End Property
 
  ' Get RecordSet page count
  Public Property Get PageCount()
    PageCount = m_RecordSet.PageCount
  End Property
 
  ' Get RecordSet record count
  Public Property Get RecordCount()
  on error resume next
    RecordCount = m_RecordSet.RecordCount
    if err.number<>0 then ShowError("Get RecordCount error.")
  End Property
 
  ' Get RecordSet Absolute Page
  Public Property Get AbsolutePage()
    on error resume next
    AbsolutePage = m_RecordSet.AbsolutePage
    if err.number<>0 then ShowError("Can not get AbsolutePage!")
  End Property
 
  ' Set RecordSet Absolute Page
  Public Property Let AbsolutePage(ByVal Value)
    on error resume next
    m_RecordSet.AbsolutePage = Value
    if err.number<>0 then ShowError("Can not set AbsolutePage to " & Value)
  End Property
 
  ' Get RecordSet Absolute Position
  Public Property Get AbsolutePosition()
    on error resume next
    AbsolutePosition = m_RecordSet.AbsolutePosition
    if err.number<>0 then ShowError("Can not get AbsolutePosition!")
  End Property
 
  ' Set RecordSet Absolute Position
  Public Property Let AbsolutePosition(ByVal Value)
    on error resume next
    m_RecordSet.AbsolutePosition = Value
    if err.number<>0 then ShowError("Can not set AbsolutePosition to " & Value)
  End Property

  ' Bof
  Public Property Get Bof()
    Bof = m_RecordSet.Bof
  end Property
 
  ' Eof
  Public Property Get Eof()
    Eof = m_RecordSet.EOF
  end Property
   
  'Setup the databease host name, database name, User name(account), password
  Public Sub Setup(Account, Password, Database, Host)
    m_UserName = Account
    m_Password = Password
    if Database<>"" then m_strDatabase = Database
    if Host<>"" then m_strHost = Host
    m_ConneStr = "Driver={SQL Server};Server=" & m_strHost & ";Database=" &_
                 m_strDatabase & ";Uid=" & m_UserName & ";Pwd=" & m_Password & ";"
  End Sub
 
  ' Connect to database
  Public Function Connect()
    on error resume next
    m_Connection.Open m_ConneStr
    if err.number<>0 Then ShowError("数据库连接错误:(Server:" & m_strHost & ", Database:" & m_strDatabase & ")")
    m_bIsConnect = true
    Connect = true  'todo://
  end Function
 
  ' Diconnect database
  Public Function Close()
    on error resume next
    Set m_RecordSet = Nothing
    Set m_Connection = Nothing
    m_bIsConnect = false
    Close = true
    if err.number<>0 then ShowError("切断数据库连接时出错")
  end Function
 
  ' Query
  Public Sub Query(SQLCommand)
    on error resume Next
    if not m_bIsConnect then Connect
    Set m_RecordSet = Server.CreateObject("Adodb.Recordset")
    'Set m_RecordSet = m_Connection.Execute(SQLCommand)
    m_RecordSet.Open SQLCommand, m_Connection, 1, 1
    if err.number<>0 then ShowError(SQLCommand):exit sub
    if m_Connection.Errors.Count>0 And m_IgnoreError=false then ProcessError(SQLCommand)
  End Sub
 
  ' ExeSQL Command
  Public Sub ExeSQL(SQLCommand)
    on error resume Next
    if not m_bIsConnect then Connect
    m_Connection.Execute SQLCommand
    if err.number<>0 then ShowError(SQLCommand):exit sub
    if m_Connection.Errors.Count>0 And m_IgnoreError=false then ProcessError(SQLCommand)
  End Sub
 
  ' Get Fields Name
  Public Function FieldName(ByVal FieldId)
    on error resume next
    FieldName = m_RecordSet.Fields(FieldId).Name
    if err.number<>0 then ShowError("不能读取字段" & FieldID & "名称!")
  End Function
 
  ' Get fields data
  Public Function Fields(ByVal FieldId)
    on error resume next
    Fields = m_RecordSet.Fields(FieldId)
    if err.number<>0 then ShowError("不能读取字段" & FieldID & "数据!")
  End Function
 
  ' Get fields data
  Public Function Data(ByVal FieldId)
    on error resume next
    Data = m_RecordSet.Fields(FieldId)
    if err.number<>0 then ShowError("不能读取" & FieldID & "数据!")
    'if m_Connection.Errors.Count>0 then ShowError("不能读取" & FieldID & "数据!")
  End Function
 
  ' Move to next record
  Public Sub MoveNext()
    on error resume next
    if m_bIsConnect then m_RecordSet.MoveNext
    if err.number<>0 then ShowError("MoveNext error")
  End Sub
   
  ' Move to Previous record
  Public Sub MovePrevious()
    on error resume next
    if m_bIsConnect then m_RecordSet.MovePrevious
    if err.number<>0 then ShowError("MovePrevious error")
  End Sub
   
  ' Move to First record
  Public Sub MoveFirst()
    on error resume next
    if m_bIsConnect then m_RecordSet.MoveFirst
    if err.number<>0 then ShowError("MoveFirst error")
  End Sub
   
  ' Move to Last record
  Public Sub MoveLast()
    on error resume next
    if m_bIsConnect then m_RecordSet.MoveLast
    if err.number<>0 then ShowError("MoveLast error")
  End Sub
 
  ' 2004-6-30
  Private Sub ProcessError(ByVal sqltxt)
    for i=0 to m_Connection.Errors.Count-1
      If m_Connection.Errors.Item(i).Number<>0 Then ShowError(sqltxt)
    Next
  End Sub
 
  ' This function is called whenever an error occurs and will handle the error
  ' Additionally the error message will be saved in m_strLastError.
 ' @param     $msg         a string containing an error message
  ' @access    private
  ' @return    void
  Private Sub ShowError(ByVal sqltxt)
    for i=0 to m_Connection.Errors.Count-1
      Response.Write m_Connection.Errors.Item(i) & "(" & m_Connection.Errors.Item(i).Number & ")<br>"
    Next
    m_LastError = Err.Description
   
    m_Connection.Errors.Clear
    Response.Write "<br>------------------------------------------------------<br>" &_
                   "<font color=red size=4>" & sqltxt & "</font>"
'     Response.Write "<br>------------------------------------------------------<br>" &_
'                    "<font color=red size=4>" & Left(sqltxt, 10) & "...(错误信息已被屏蔽)，请与网站管理员联系！</font>"
'     Response.End
  End Sub

  ' Class constructor, set class default attributes, you can change it
  Private Sub class_Initialize
    m_strName = "clsDB"
    m_strVersion = "1.0"
    Set m_Connection = Server.CreateObject("ADODB.Connection")
    '请修改此处为你连接数据库的默认值
    Setup "sa", "password", "Northwind", "(local)"
    m_bIsConnect = False
    m_IgnoreError = False
  End Sub

  ' Class destructor, free memory.
  Private Sub class_Terminate
    Set m_RecordSet = Nothing
    Set m_Connection = Nothing
  End Sub

End Class

%>

  


Trackback: http://tb.blog.csdn.net/TrackBack.aspx?PostId=42869


<script src="http://localhost:82/PromoteIcon.aspx?id=42869"></script>[ 收藏到我的网摘]   天蝎蝴蝶发表于 2004年07月16日 11:50:00
<link href="http://blog.csdn.net/nhconch/Services/Pingback.aspx" rel="pingback"><script>function hide(){showComment();}</script>
相关文章：
<script type="text/javascript">document.write(" ");</script>  
Estyle(靳田) 发表于2004-07-16 15:22:00  IP: 220.167.102.*
前面“On Error Resume Next”了，后面仍然可以“On Error Goto 0”来悬崖勒马，并非只能贯彻到底。
不得不说，虽然看起来更多地语言采用“Try...Catch”，但“On Error”也不失为一种优秀的异常处理机制。

 
Estyle(靳田) 发表于2004-07-16 15:46:00  IP: 220.167.102.*
另外，我觉得，对于异常处理。如果没有实现事务性，那么异常处理的意义也就小了很多。
还有，对于你的代码，异常处理分布在每个过程里面，不如做一个通用的异常处理页面，理由如下：
1、你的过程内的异常处理只是简单地捕获异常并显示友好错误信息，在修复方面的工作做得不多，意义不大且工作重复；
2、用户似乎不应该看到过多的错误细节。
实现方法大概是，先On Error Resume Next，再在页面末尾用SSI（不推荐）、Server.Execute或者Server.Transfer转到错误信息处理页面，统一进行错误捕获和信息反馈。
我觉得，这个数据库类可能并不太实用，大概看起来就是把Recordset和Connection对象的常用成员组合到了一起……
——这些都只是我个人的一些粗浅认识而已，还请多批评指教。

对了，我觉得对于异常处理，我们可以把重点放在异常修复上。考虑考虑？

 
天蝎蝴蝶 发表于2004-07-16 16:12:00  IP: 61.142.213.*
Estyle(靳田) 说得很有道理，这里面根本没有错误修理，而且错误显示还有很多值得改进的地方。至于在页尾才进行处理的话，可以会将上一个的错误带到后面，而形成一连串的错误，扩大了错误的影响。
这种方法与其他人（包括以往的同事）交流时，大部分也表示不大习惯。这个类只是一个引子，后面的文章会用到它。

 
天蝎蝴蝶 发表于2004-07-16 16:13:00  IP: 61.142.213.*
不知Estyle(靳田) 在异常修复上有什么好的方法的，我目前的思路比较零散。以后多交流！

 
inelm(木野狐) 发表于2004-08-15 09:19:00  IP: 61.171.12.*
>>> 但“On Error”也不失为一种优秀的异常处理机制。

靳田说的大部分我同意，但这句话不赞同的， on error 这种语法已经被证明了是 vb 的一个令人生厌的弱项。 在 vb.net 里面使用了先进的 try.. catch... finally 机制也正说明了这一点。

 
piggybank 发表于2004-11-12 16:06:00  IP: 220.163.28.*
呵呵
On Error Goto MY_ERROR_HANDLER
'Try Start
... ...
'Try End
On Error Goto 0

goto GO_ON

MY_ERROR_HANDLER:
'Catch something
Select Case Err.Number
Case xxxxxx
... ...
Case Else
End Select
... ...

GO_ON:
'Finnaly

完全可以做到类似 Try Catch 的捕获。只不过不那么“优美”而已。

另外，
Dim lngErrorNumber as Long
On Error Resume Next
'Try Start
... ...
'Try End

lngErrorNumber = Err.Number
On Error Goto 0

Select Case lngErrorNumber
Case 0
...
Case xxx
'Handle
...
Case Else
...
End Select

这样的处理结构也不错——与前者相比，比较适合针对一两句代码设置陷阱。

对于开发人员而言，在什么地方设置陷阱，如何处理等等，是一种高级编程策略的体现。至于能力高低因人和经验而异，但没有和有之间的差别意义就不同了。
VB 有错误捕获和处理的能力，VB.Net 在这方面也许更强
个人认为这谈不上VB/VBS的弱项。

 
piggybank 发表于2004-11-12 16:33:00  IP: 220.163.28.*
>我觉得，这个数据库类可能并不太实用，大概看起来就是把Recordset和Connection对象的常用成员组合到了一起……

同感。

if err.number<>0 Then ShowError("数据库连接错误:(Server:" & m_strHost & ", Database:" & m_strDatabase & ")")
m_bIsConnect = true

这一句漏掉了 :Exit Sub（当然，针对ASP可以在ShowError中用 Response.End 来结束，但对于上面的代码而言，逻辑上不完整）

由此想到的题外话：诸如此类的代码，最好不要省事，写为
If .... Then

Else

End If
哪怕中间空着，但逻辑很清楚，也不容易出现人为失误——看你别的代码都有，就这一句漏掉了。

封装函数、类的时候，往往有很多种策略。谈不上究竟哪种好，哪种不好——关键看你选择哪一个 View 了。

比如，既然封装成为一个 Class，那么对于调用者来说，应该由它自己决定如何处理错误——我看到你的代码里有 LastError，那怎么不用上它呢？封装方法和函数的思路有很多种，各有各的好处。我个人比较喜欢类似 COM 的方法的封装：每一个方法都是 Bool 类型。如果返回值为 False，则调用者需要检查 LastErrorNumber（而不是LastErrorMessage，为什么？）
当然，你也可以约定你的调用者用别的方式来调用。比如无论如何都要检查某个 Bool 类型的 Property，或者抛出错误（异常）——Err.RaiseError（Estyle纠正我一下，不记得语法了，我在CoffeeBar）让调用者自行处理，呵呵

题外话，On Error Resume Next 在这一点上有一个很好的作用：消极容错。使用时应该根据逻辑适当分段，否则通篇用一两个 On Error Resume Next，那除非是为了“隐藏错误”，谈不上“错误处理”。

所以，在你的类中，ShowError() 这个方法就有点“越俎代疱”了。不妨采用类似于 IgnoreError 这样的思路，提供标准的、默认的错误处理方式之外，让调用者也可以设置一下错误处理的方式，甚至可以定制 ShowError() 的具体内容——比如 EStyle 说的 SSI、Transfer、Execute等方式。

说到这里，再想想，虽然封装这样一个类的实际意义未必很大，但通过它和你做的其它一些东西合起来提供一个开发框架，调用者只需要按照这个框架开发、定制一下内容，还是很有意义的。
何况，当你的这个开发框架比较成熟之后，可以用程序来生成它们——产生式编程？意义就更加重大了。

呵呵，以前有个同事做了一个软件来生成代码，但我个人不太喜欢他的开发框架和代码。后来自己摸索，但却没时间完成自动生成了。今天刚好见到有个RapidTier的作品，看起来不错，不过是.Net的。但我觉得在VBS这样的语言针对OOP提供“超能力”的领域来摸索这个事情似乎更有挑战性 ^oo^


 
菜鸟1号 发表于2006-03-30 21:09:00  IP: 125.73.50.*
我这也有一个，不过不是很会用。咯咯

<%
Rem =======================================数据库类=====================

Rem 定义类名称
Class jz_DbAccess
Rem ==================使用说明=========================================
Rem = 作用：集成了用数据库工作时使用的常见功能
Rem = 公有变量：Conn Connection对象
Rem = 公有变量：comm Command对象
Rem = 公有变量：param Parameter对象
Rem = 公有变量：rs Recordset对象
Rem = 属性: DbPath 定义Access数据库路径及名称，只写属性。
Rem = 属性: SqlDatabaseName 定义SQL数据库名称，只写属性。
Rem = 属性: SqlUsername 定义SQL数据库用户名称，只写属性。
Rem = 属性: SqlPassword 定义SQL数据库用户密码，只写属性。
Rem = 属性: SqlLocalName 定义SQL数据库服务器名称，只写属性。
Rem = 属性: TableName 定义表名称，只写属性。
Rem = 属性: MeterList 定义表的列名称列表，可加入top 等SQL 语句，只写属性。
Rem = 属性: SortField 定义表Order By排列方式，只写属性。
Rem = 属性: FilterField 定义表 where 过滤方式，只写属性。
Rem = 方法：DbSet(IsSqlDataBase,OpenComm,OpenRs) 定义用Access还是用Sql,并创建Connection对象,Command对象,Recordset对象
Rem = 方法：AddRecord(FieldList,ValueList) 把记录加到数据库里
Rem = 方法：EditRecord(FieldList,ValueList,Primary) 在数据库里更新已有的记录
Rem = 方法：DeleteRecord(Primary)　从数据库里删除记录
Rem = 函数：GetRecord()　在筛选和排序的基础上返回Recordset
Rem = 函数：GetRecords(Primary) 按参数返回记录
Rem = 方法：RsOpen(Sql,CursorType, LockType) 按参数打开游标
Rem = 函数: RsGetRows(Sql,CursorType, LockType) 将 Recordset 对象的多个记录恢复到数组中
Rem = 函数: RsGetString(sql,Cursor_Type, Lock_Type,StringFormat, NumRows, ColumnDelimiter, RowDelimiter, NullExpr)将 Recordset 作为字符串返回。
Rem =========================================================================================

Rem 定义私有变量
Private LocalDbPath,LocalSqlDatabaseName,LocalSqlUsername,LocalSqlPassword,LocalSqlLocalName
Rem 定义私有变量
Private LocalTableName,LocalSortField,LocalMeterList,LocalFilterField,LocalFen
Rem 定义公有变量
Public Conn,comm,param,rs,ConnStr

Rem 使用Initialize事件提供有缺省值的某些属性。
Private Sub Class_Initialize()
LocalFen="{$AddDate}"
End Sub

Rem 设置使用Terminate事件
Private Sub Class_Terminate()
Rem 内置函数 IsObject(expression) 确定表达式expression是否是一个自动对象。
Rem 为自动对象时，将对象变量 Rs 设置为 Nothing,从内存中完全删除，
if IsObject(rs) then set rs = nothing
Rem 为自动对象时，将对象变量 Comm 设置为 Nothing,从内存中完全删除，
if IsObject(comm) then set comm = nothing
Rem 为自动对象时，将对象变量 Conn 设置为 Nothing,从内存中完全删除，
if IsObject(Conn) then set Conn = nothing
End sub

Rem 因为方法是需外部访问的而且没有返回值，故被声明为公有过程
Public Sub close()
Rem 把私有变量LocalMeterList赋值为"*"
LocalMeterList="*"
Rem 把私有变量LocalMeterList赋值为Empty
LocalSortField=Empty
Rem 把私有变量LocalMeterList赋值为Empty
LocalFilterField=Empty
End Sub

Rem Property Let　过程设置属性值。
Public Property Let DbPath(vNewValue)
Rem 私有变量LocalDbPath赋值为属性值
LocalDbPath=vNewValue
End Property


Rem Property Let　过程设置属性值。
Public Property Let SqlDatabaseName(vNewValue)
Rem 私有变量LocalSqlDatabaseName赋值为属性值
LocalSqlDatabaseName=vNewValue
End Property

Rem Property Let　过程设置属性值。
Public Property Let SqlUsername(vNewValue)
Rem 私有变量LocalSqlUsername赋值为属性值
LocalSqlUsername=vNewValue
End Property

Rem Property Let　过程设置属性值。
Public Property Let SqlPassword(vNewValue)
Rem 私有变量LocalSqlPassword赋值为属性值
LocalSqlPassword=vNewValue
End Property

Rem Property Let　过程设置属性值。
Public Property Let SqlLocalName(vNewValue)
Rem 私有变量LocalSqlLocalName赋值为属性值
LocalSqlLocalName=vNewValue
End Property

Rem Property Let　过程设置属性值。
Public Property Let TableName(vNewValue)
Rem 私有变量LocalTableName赋值为属性值
LocalTableName=vNewValue
End Property

Rem Property Let　过程设置属性值。
Public Property Let MeterList(vNewValue)
Rem 私有变量LocalMeterList赋值为属性值
LocalMeterList=vNewValue
End Property

Rem Property Let　过程设置属性值。
Public Property Let SortField(vNewValue)
Rem 私有变量LocalSortField赋值为属性值
LocalSortField=" Order By "&vNewValue
End Property

Rem Property Let　过程设置属性值。
Public Property Let FilterField(vNewValue)
Rem 私有变量LocalFilterField赋值为属性值
LocalFilterField=" where "&vNewValue&" "
End Property

Rem Property Let　过程设置属性值。
Public Property Let Fen(vNewValue)
Rem 私有变量LocalFen赋值为属性值
LocalFen=vNewValue
End Property

Rem 因为方法是需外部访问的而且没有返回值，故被声明为公有过程
Public Sub DbSet(IsSqlDataBase)
Rem 判断参数IsSqlDataBase的值
If IsSqlDataBase = 1 Then
Rem 给公有变量 ConnStr　赋值
ConnStr = "Provider = Sqloledb; User ID = " & LocalSqlUsername & "; Password = " & LocalSqlPassword & "; Initial Catalog = " & LocalSqlDatabaseName & "; Data Source = " & LocalSqlLocalName & ";"
Else
Rem 给公有变量 ConnStr　赋值
ConnStr ="Provider = Microsoft.Jet.OLEDB.4.0;Data Source = " & Server.MapPath(LocalDbPath)
End If

End Sub

Rem 因为方法是不需外部访问的而且没有返回值，故被声明为私有过程
Private Sub Open_Obj(ObjType)
Select Case (ObjType)
Case ("Conn")
Rem 判断是否 不为自动对象时
If Not IsObject(Conn) then
Rem 语句 On Error 当一个错误发生时，这条语句就执行紧靠发生错误语句后面的语句，或者执行紧靠调用进程后面的语句。
On Error Resume Next
Rem 语句 Set 赋予一个变量或一个性质对象引用。当赋予的值为Nothing 时，使obectva 和任何以前指明的对象解除关系。
Set Conn = Server.CreateObject("ADODB.Connection")
Rem 使用连接属性打开数据库连接
conn.open ConnStr
Rem 判断是否发生错误
Rem 任何涉及 ADO 对象的操作都可能产生一个或多个提供者错误。产生错误时，可以将一个或多个 Error 对象置于 Connection 对象的 Errors 集合中。其他 ADO 操作产生错误时，将清空 Errors 集合，并且将新的 Error 对象置于 Errors 集合中
If Err Then
Rem 对 Errors 集合使用 Clear 方法，来删除集合中现有的全部 Error 对象。发生错误时，ADO 将自动清空 Errors 集合，并以基于新错误的 Error 对象填充集合。
err.Clear
Rem 语句 Set 赋予一个变量或一个性质对象引用。当赋予的值为Nothing 时，使obectva 和任何以前指明的对象解除关系。
Set Conn = Nothing
Rem 发送提示
Response.Write "数据库连接出错，请检查连接字串。"
Rem 停止
Response.End
End If
End If
Case ("Comm")
Rem 判断是否 不为自动对象时
if Not IsObject(comm) then
Rem 语句 Set 赋予一个变量或一个性质对象引用。当赋予的值为Nothing 时，使obectva 和任何以前指明的对象解除关系。
set comm=Server.Createobject("ADODB.Command")
Rem 指示指定的 Command 对象当前所属的 Connection 对象。
comm.ActiveConnection=conn
End if
Case ("Rs")
Rem 判断是否 不为自动对象时
If not IsObject(rs) Then set Rs = Server.CreateObject( "ADODB.Recordset" )
ENd Select

End Sub

Rem 因为方法是不需外部访问的而且有返回值，故被声明为私有函数
Private Function FieldListStr(FieldList,ValueList,format_type)

Rem 定义局部变量
Dim ChoppedFieldList,ChoppedValueList
Dim FieldValueList(2)
Dim FieldNum,ValueNum,i,post
Dim Field_str,Str_i,Value_str

Rem 把参数FieldList通过{$jz}断层分割转换为数组，赋值给局部变量ChoppedFieldList
Rem 内置函数 Split(expression[,delimiter[,count[,compare]]]) 把一个字符串分割并转换成数组。
ChoppedFieldList=Split(FieldList,LocalFen)

Rem 把参数ValueList通过{$jz}断层分割转换为数组，赋值给局部变量ChoppedValueList
Rem 内置函数 Split(expression[,delimiter[,count[,compare]]]) 把一个字符串分割并转换成数组。
ChoppedValueList=Split(ValueList,LocalFen)

Rem 把ChoppedFieldList的数组第一维的上边界，赋值给局部变量FieldNum
Rem 内置函数 UBound(arrayname[,dimension]) 返回数组某维的上边界。缺省维数时，为第一维。
FieldNum=UBound(ChoppedFieldList)

Rem 把ChoppedValueList的数组第一维的上边界，赋值给局部变量ValueNum
Rem 内置函数 UBound(arrayname[,dimension]) 返回数组某维的上边界。缺省维数时，为第一维。
ValueNum=UBound(ChoppedValueList)

Rem 判断 局部变量FieldNum与局部变量ValueNum是否相等，不等时，退出函数
if FieldNum<>ValueNum Then Exit Function

Rem 根据局部变量ValueNum，修改局部变量Value_str为二维数组
ReDim Value_str(3,ValueNum)

Rem 为局部变量Str_i赋初始量为0
Str_i=0

Rem 自定义私有过程 Open_Obj
Open_Obj "Conn"

Rem 打开一个将要增加记录的到表的连接
Set Rs = conn.Execute(LocalTableName,,2)

Rem 通过FieldNum进行循环
For i=0 to FieldNum

Rem 通过参数 format_type　给局部变量Field_str以不同的方式赋值
Select Case (format_type)

Case ("Add")

Rem 对局部变量Field_str进行字符串串联
Rem 自定义函数私有Str_add,以传入的三个参数进行字符串转换

Field_str=Str_add(Field_str,ChoppedFieldList(i),",")

Case ("Edit")

Rem 对局部变量Field_str进行字符串串联
Rem Str_add自定义私有函数,以传入的三个参数进行字符串转换
Field_str=Str_add(Field_str,ChoppedFieldList(i)&"=?",",")

ENd Select

Rem 局数变量数组Value_str第一维0赋值
Value_str(0,i)=ChoppedFieldList(i)
Rem 使用Recordset 对象含有由 Field 对象组成的 Fields 集合的Type属性可返回字段的基本特性，赋值给局数变量数组Value_str第一维1
Value_str(1,i)=Rs.Fields(ChoppedFieldList(i)).type
Rem 使用Recordset 对象含有由 Field 对象组成的 Fields 集合的DefinedSize 属性可返回已声明的字段大小，赋值给局数变量数组Value_str第一维2
Value_str(2,i)=rs.Fields(ChoppedFieldList(i)).DefinedSize
Rem 从局部变量数组ChoppedValueList中赋对应的值给赋值给局数变量数组Value_str第一维3
Value_str(3,i)=ChoppedValueList(i)


Next

Rem 使用 Close 方法可关闭 Connection 对象或 Recordset 对象以便释放所有关联的系统资源。
Rs.close

Rem 给局部变量数组FieldValueList赋值
FieldValueList(0)=Field_str
FieldValueList(1)=Value_str
FieldValueList(2)=FieldNum

Rem 局部变量数组FieldValueList的值赋给FieldListStr函数返回值
FieldListStr=FieldValueList
End Function

Rem 因为方法是不需外部访问的而且有返回值，故被声明为私有函数
Private Function Str_add(add_str,Str,char_str)
Rem 判断参数add_str是否为空值
if add_str="" then
Rem 为空时，函数返回值为参数Str
Str_add=str
else
Rem 不为空时,函数返回值为参数add_str&char_str&str
str_add=add_str&char_str&str
end if
End Function

Rem 因为方法是不需外部访问的而且没有返回值，故被声明为私有过程
Private Sub Param_cmd(str_0,str_1)
Rem 创建局部变量
dim i
Rem 通过参数Str_0循环
rem comm.Parameters.Refresh
for i=0 to str_0
Rem 用指定的属性创建新的 Parameter 对象
Rem Param 为公有变量
rem Response.Write(str_1(0,i)&"---"&str_1(1,i)&"---"&str_1(2,i)&"---"&str_1(3,i))

set param=comm.CreateParameter(str_1(0,i),str_1(1,i),&H0001,str_1(2,i),str_1(3,i))
Rem 使用 Append 方法将它们添加到 Parameters 集合

comm.Parameters.Append param
next
rem comm.Parameters.Refresh
End Sub

Rem 因为方法是不需外部访问的而且有返回值，故被声明为私有函数
Private Function str_addNum(Num,str,char_str)
Rem 创建局部变量
Dim i
Rem 通过参数Num循环
For i=0 to Num
Rem 循环进行字符串串联,并赋值给函数返回值
Rem 自定义私有函数Str_add,通过三个参数转换
str_addNum=Str_add(str_addNum,Str,char_str)
Next
End Function

Rem 因为方法是需外部访问的而且没有返回值，故被声明为公有过程
Public Sub AddRecord(FieldList,ValueList)
Rem 创建局部变量
Dim FieldValueList
Rem 判断私有变量LocalTableName是否为空
if (LocalTableName="") then
Rem 设置错误提示信息
Err.Raise vbobjectError+1,"DBAccess Server","TableName　未设置"
Rem 退出Sub 过程
Exit Sub
End if

Rem 通过自定义私有变量FieldListStr获取转换后的数组。
FieldValueList=FieldListStr(FieldList,ValueList,"Add")

Rem 判断FieldListStr是否为数组
If Not IsArray(FieldValueList) Then
Rem 退出Sub 过程
Exit Sub
Else

Rem 自定义私有过程 Open_Obj
Open_Obj "Conn"

Rem 自定义私有过程 Open_Obj
Open_Obj "Comm"

Rem 指示 Command 对象的类型为将 CommandText 作为命令或存储过程调用的文本化定义进行计算。
comm.CommandType=&H0001
Rem 使用 CommandText 属性定义命令（例如，SQL 语句）的可执行文本
comm.CommandText="Insert into "&LocalTableName&" ("&FieldValueList(0)&") values ("&str_addNum(FieldValueList(2),"?",",")&")"

rem Response.Write("Insert into "&LocalTableName&" ("&FieldValueList(0)&") values ("&str_addNum(FieldValueList(2),"?",",")&")")

Rem 调用自定义私有过程Param_cmd,添加到 Parameters 集合
Param_cmd FieldValueList(2),FieldValueList(1)

Rem 执行在对象的 CommandText 属性中指定的查询。如果 CommandText 属性指定按行返回查询，执行所产生的任何结果都将存储在新的 Recordset 对象中。如果该命令不是按行返回查询，则提供者返回关闭的 Recordset 对象。
comm.Execute


end if
End Sub

Rem 因为方法是需外部访问的而且没有返回值，故被声明为公有过程
Public Sub EditRecord(FieldList,ValueList,Primary)
Rem 创建局部变量
Dim FieldValueList
Rem 判断私有变量LocalTableName是否为空
if (LocalTableName="") then
Rem 设置错误提示信息
Err.Raise vbobjectError+1,"DBAccess Server","TableName　未设置"
Rem 退出Sub 过程
Exit Sub
End if

Rem 通过自定义私有变量FieldListStr获取转换后的数组。
FieldValueList=FieldListStr(FieldList,ValueList,"Edit")

Rem 判断FieldListStr是否为数组
If Not IsArray(FieldValueList) Then
Exit Sub
Else

Rem 自定义私有过程 Open_Obj
Open_Obj "Conn"

Rem 自定义私有过程 Open_Obj
Open_Obj "Comm"

Rem 指示 Command 对象的类型为将 CommandText 作为命令或存储过程调用的文本化定义进行计算。
comm.CommandType=&H0001
Rem 使用 CommandText 属性定义命令（例如，SQL 语句）的可执行文本
comm.CommandText="UpDate "&LocalTableName&" set "&FieldValueList(0)&" Where "&Primary

Rem 调用自定义私有过程Param_cmd,添加到 Parameters 集合
Param_cmd FieldValueList(2),FieldValueList(1)

Rem 执行在对象的 CommandText 属性中指定的查询。如果 CommandText 属性指定按行返回查询，执行所产生的任何结果都将存储在新的 Recordset 对象中。如果该命令不是按行返回查询，则提供者返回关闭的 Recordset 对象。
comm.Execute



end if

End Sub

Rem 因为方法是需外部访问的而且没有返回值，故被声明为公有过程
Public Sub DeleteRecord(Primary)
Rem 判断私有变量LocalTableName是否为空
if (LocalTableName="") then
Rem 设置错误提示信息
Err.Raise vbobjectError+1,"DBAccess Server","TableName　未设置"
Rem 退出Sub 过程
Exit Sub
End if

Rem 自定义私有过程 Open_Obj
Open_Obj "Conn"

Rem 执行 Sql　文本
conn.execute("Delete from "&LocalTableName&" where "&Primary)

End Sub

Rem 因为方法是需外部访问的而且有返回值，故被声明为公有函数
Public Function GetRecord()
Rem 判断私有变量LocalTableName是否为空
if (LocalTableName="") then
Rem 设置错误提示信息
Err.Raise vbobjectError+1,"DBAccess Server","TableName　未设置"
Rem 退出函数
Exit Function
End if

Rem 自定义私有过程 Open_Obj
Open_Obj "Conn"


Rem 设置涵数返回值为Recordset对象
set GetRecord=conn.execute("select "&LocalMeterList&" from "&LocalTableName&LocalFilterField&LocalSortField)
End Function

Rem 因为方法是需外部访问的而且有返回值，故被声明为公有函数
Public Function GetRecords(Primary)

Rem 自定义私有过程 Open_Obj
Open_Obj "Conn"

Rem 设置涵数返回值为Recordset对象，参数为Sql文本
set GetRecords=conn.execute(Primary)
End Function

Rem 因为方法是需外部访问的而且没有返回值，故被声明为公有过程
Public sub RsOpen(sql,Cursor_Type,Lock_Type)

Rem 自定义私有过程 Open_Obj
Open_Obj "Conn"

Rem 自定义私有过程 Open_Obj
Open_Obj "Rs"

Rem 打开游标
Rs.Open sql, Conn, Cursor_Type, Lock_Type,&H0001

End sub

Rem 因为方法是需外部访问的而且有返回值，故被声明为公有函数
Public Function RsGetRows(sql,Cursor_Type, Lock_Type,Rows)

Rem 自定义私有过程 Open_Obj
Open_Obj "Conn"

Rem 自定义私有过程 Open_Obj
Open_Obj "Rs"

Rem 打开游标
Rs.Open sql, Conn, Cursor_Type, Lock_Type,&H0001
Rem 当前记录位置是否位于 Recordset 对象的最后一个记录之后，为True时,将 Recordset 对象的多个记录恢复到数组中
if not rs.eof then RsGetRows=rs.GetRows(Rows)
Rem 使用 Close 方法可关闭 Connection 对象或 Recordset 对象以便释放所有关联的系统资源。
rs.close

End Function


Rem 因为方法是需外部访问的而且有返回值，故被声明为公有函数
Public Function RsGetString(sql,Cursor_Type, Lock_Type,StringFormat, NumRows, ColumnDelimiter, RowDelimiter, NullExpr)

Rem 自定义私有过程 Open_Obj
Open_Obj "Conn"

Rem 自定义私有过程 Open_Obj
Open_Obj "Rs"

Rem 打开游标
Rs.Open sql, Conn, Cursor_Type, Lock_Type,&H0001
Rem 当前记录位置是否位于 Recordset 对象的最后一个记录之后，为True时,将 Recordset 作为字符串返回。
if not rs.eof then RsGetString=rs.GetString(StringFormat, NumRows, ColumnDelimiter, RowDelimiter, NullExpr)
Rem 使用 Close 方法可关闭 Connection 对象或 Recordset 对象以便释放所有关联的系统资源。
rs.close
End Function



End Class
%>

3、使用示例
<!--#INCLUDE file="DBSql.inc.asp"-->
<%
Function HTMLEncode(str)
    If IsNull(str) Then HTMLEncode = "(NULL)" _
    Else HTMLEncode = Server.HTMLEncode(str)
End Function

Dim sql, i
Set sql = New clsDB
sql.Connect
sql.ExeSQL("update Customers set Address='中华人民共和国' where ID=1")
sql.Query("select * from Customers")
Response.Write "<table border=1><tr>"
For i=0 To sql.FieldCount-1
    Response.Write "<td>" &  Server.HTMLEncode(sql.FieldName(i)) & "</td>"
Next
Response.Write "</tr>"
While Not sql.Eof
    For i=0 To sql.FieldCount-1
        Response.Write "<td>" & HTMLEncode(sql.Data(i)) & "</td>" '此处可直接用字段名代替i
    Next
    Response.Write "</tr>"
    sql.MoveNext
Wend
Response.Write "</table>"
sql.Close
Set sql = Nothing
%>


三、小结
　　这还只是一个比较粗糙的数据库类，还有很多ADODB的特性没有添加在内，而且灵活性也不够。本文旨在为大家提供另一种思路，各位在看完本文后觉得还是有一点收获的话，我就很满足了。
　　此外，我的下一篇文章《将ASP查询分页封装起来》中将用到这个类。

 

你可能感兴趣的:(数据结构,sql,sql,server,asp.net,asp)

  • 理解Gunicorn：Python WSGI服务器的基石 范范0825 ipythonlinux运维
    理解Gunicorn：PythonWSGI服务器的基石介绍Gunicorn，全称GreenUnicorn，是一个为PythonWSGI（WebServerGatewayInterface）应用设计的高效、轻量级HTTP服务器。作为PythonWeb应用部署的常用工具，Gunicorn以其高性能和易用性著称。本文将介绍Gunicorn的基本概念、安装和配置，帮助初学者快速上手。1.什么是Gunico
  • mysql禁用远程登录 igotyback mysql
    去mysql库中的user表里，将host都改成localhost之后刷新权限FLUSHPRIVILEGES;
  • SQL Server_查询某一数据库中的所有表的内容 qq_42772833 SQLServer数据库sqlserver
    1.查看所有表的表名要列出CrabFarmDB数据库中的所有表（名），可以使用以下SQL语句：USECrabFarmDB;--切换到目标数据库GOSELECTTABLE_NAMEFROMINFORMATION_SCHEMA.TABLESWHERETABLE_TYPE='BASETABLE';对这段SQL脚本的解释：SELECTTABLE_NAME：这个语句的作用是从查询结果中选择TABLE_NAM
  • 数组去重 好奇的猫猫猫
    整理自js中基础数据结构数组去重问题思考？如何去除数组中重复的项例如数组：[1,3,4,3,5]我们在做去重的时候，一开始想到的肯定是，逐个比较，外面一层循环，内层后一个与前一个一比较，如果是久不将当前这一项放进新的数组，挨个比较完之后返回一个新的去过重复的数组不好的实践方式上述方法效率极低，代码量还多，思考？有没有更好的方法这时候不禁一想当然有了！！！hashtable啊，通过对象的hash办法
  • MYSQL面试系列-04 king01299 面试mysql面试
    MYSQL面试系列-0417.关于redolog和binlog的刷盘机制、redolog、undolog作用、GTID是做什么的？innodb_flush_log_at_trx_commit及sync_binlog参数意义双117.1innodb_flush_log_at_trx_commit该变量定义了InnoDB在每次事务提交时，如何处理未刷入（flush）的重做日志信息（redolog）。它
  • 回溯算法-重新安排行程 chirou_ 算法数据结构图论c++图搜索
    leetcode332.重新安排行程这题我还没自己ac过，只能现在凭着刚学完的热乎劲把我对题解的理解记下来。本题我认为对数据结构的考察比较多，用什么数据结构去存数据，去读取数据，都是很重要的。classSolution{private:unordered_map>targets;boolbacktracking(intticketNum,vector&result){//1.确定参数和返回值//2
  • Redis系列：Geo 类型赋能亿级地图位置计算 Ly768768 redisbootstrap数据库
    1前言我们在篇深刻理解高性能Redis的本质的时候就介绍过Redis的几种基本数据结构，它是基于不同业务场景而设计的：动态字符串(REDIS_STRING)：整数(REDIS_ENCODING_INT)、字符串(REDIS_ENCODING_RAW)双端列表(REDIS_ENCODING_LINKEDLIST)压缩列表(REDIS_ENCODING_ZIPLIST)跳跃表(REDIS_ENCODI
  • Faiss：高效相似性搜索与聚类的利器 网络·魚 大数据faiss
    Faiss是一个针对大规模向量集合的相似性搜索库，由FacebookAIResearch开发。它提供了一系列高效的算法和数据结构，用于加速向量之间的相似性搜索，特别是在大规模数据集上。本文将介绍Faiss的原理、核心功能以及如何在实际项目中使用它。Faiss原理：近似最近邻搜索：Faiss的核心功能之一是近似最近邻搜索，它能够高效地在大规模数据集中找到与给定查询向量最相似的向量。这种搜索是近似的，
  • nosql数据库技术与应用知识点 皆过客，揽星河 NoSQLnosql数据库大数据数据分析数据结构非关系型数据库
    Nosql知识回顾大数据处理流程数据采集(flume、爬虫、传感器)数据存储(本门课程NoSQL所处的阶段)Hdfs、MongoDB、HBase等数据清洗(入仓)Hive等数据处理、分析(Spark、Flink等)数据可视化数据挖掘、机器学习应用(Python、SparkMLlib等)大数据时代存储的挑战(三高)高并发(同一时间很多人访问)高扩展(要求随时根据需求扩展存储)高效率(要求读写速度快)
  • SpringBlade dict-biz/list 接口 SQL 注入漏洞 文章永久免费只为良心 oracle数据库
    SpringBladedict-biz/list接口SQL注入漏洞POC:构造请求包查看返回包你的网址/api/blade-system/dict-biz/list?updatexml(1,concat(0x7e,md5(1),0x7e),1)=1漏洞概述在SpringBlade框架中，如果dict-biz/list接口的后台处理逻辑没有正确地对用户输入进行过滤或参数化查询（PreparedSta
  • 数据结构之哈希表 X同学的开始 数据结构数据结构散列表
    哈希表(散列表)出现的原因在顺序表中查找时，需要从表头开始，依次遍历比较a[i]与key的值是否相等，直到相等才返回索引i；在有序表中查找时，我们经常使用的是二分查找，通过比较key与a[i]的大小来折半查找，直到相等时才返回索引i。最终通过索引找到我们要找的元素。但是，这两种方法的效率都依赖于查找中比较的次数。我们有一种想法，能不能不经过比较，而是直接通过关键字key一次得到所要的结果呢？这时，
  • Linux MariaDB使用OpenSSL安装SSL证书 Meta39 MySQLOracleMariaDBLinuxWindowsssllinuxmariadb
    进入到证书存放目录，批量删除.pem证书警告：确保已经进入到证书存放目录find.-typef-iname\*.pem-delete查看是否安装OpenSSLopensslversion没有则安装yuminstallopensslopenssl-devel开启SSL编辑/etc/my.cnf文件（没有的话就创建，但是要注意，在/etc/my.cnf.d/server.cnf配置了datadir的，
  • Python开发常用的三方模块如下： 换个网名有点难 python开发语言
    Python是一门功能强大的编程语言，拥有丰富的第三方库，这些库为开发者提供了极大的便利。以下是100个常用的Python库，涵盖了多个领域：1、NumPy，用于科学计算的基础库。2、Pandas，提供数据结构和数据分析工具。3、Matplotlib，一个绘图库。4、Scikit-learn，机器学习库。5、SciPy，用于数学、科学和工程的库。6、TensorFlow，由Google开发的开源机
  • 网络编程基础 记得开心一点啊 网络
    目录♫什么是网络编程♫Socket套接字♪什么是Socket套接字♪数据报套接字♪流套接字♫数据报套接字通信模型♪数据报套接字通讯模型♪DatagramSocket♪DatagramPacket♪实现UDP的服务端代码♪实现UDP的客户端代码♫流套接字通信模型♪流套接字通讯模型♪ServerSocket♪Socket♪实现TCP的服务端代码♪实现TCP的客户端代码♫什么是网络编程网络编程，指网络上
  • 关于Mysql 中 Row size too large (＞ 8126) 错误的解决和理解 秋刀prince mysqlmysql数据库
    提示：啰嗦一嘴，数据库的任何操作和验证前，一定要记得先备份！！！不会有错；文章目录问题发现一、问题导致的可能原因1、页大小2、行格式2.1compact格式2.2Redundant格式2.3Dynamic格式2.4Compressed格式3、BLOB和TEXT列二、解决办法1、修改页大小（不推荐）2、修改行格式3、修改数据类型为BLOB和TEXT列4、其他优化方式（可以参考使用）4.1合理设置数据
  • 自然语言处理_tf-idf _feivirus_ 算法机器学习和数学自然语言处理tf-idf逆文档频率词频
    importpandasaspdimportmath1.数据预处理docA="Thecatsatonmyface"docB="Thedogsatonmybed"wordsA=docA.split("")wordsB=docB.split("")wordsSet=set(wordsA).union(set(wordsB))print(wordsSet){'on','my','face','sat',
  • K近邻算法_分类鸢尾花数据集 _feivirus_ 算法机器学习和数学分类机器学习K近邻
    importnumpyasnpimportpandasaspdfromsklearn.datasetsimportload_irisfromsklearn.model_selectionimporttrain_test_splitfromsklearn.metricsimportaccuracy_score1.数据预处理iris=load_iris()df=pd.DataFrame(data=ir
  • 数据结构 | 栈和队列 TT-Kun 数据结构与算法数据结构栈队列C语言
    文章目录栈和队列1.栈：后进先出（LIFO）的数据结构1.1概念与结构1.2栈的实现2.队列：先进先出（FIFO）的数据结构2.1概念与结构2.2队列的实现3.栈和队列算法题3.1有效的括号3.2用队列实现栈3.3用栈实现队列3.4设计循环队列结论栈和队列在计算机科学中，栈和队列是两种基本且重要的数据结构，它们在处理数据存储和访问顺序方面有着独特的规则和应用。本文将详细介绍栈和队列的概念、结构、实
  • [Python] 数据结构 详解及代码 AIAdvocate 算法python数据结构链表
    今日内容大纲介绍数据结构介绍列表链表1.数据结构和算法简介程序大白话翻译,程序=数据结构+算法数据结构指的是存储,组织数据的方式.算法指的是为了解决实际业务问题而思考思路和方法,就叫:算法.2.算法的5大特性介绍算法具有独立性算法是解决问题的思路和方式,最重要的是思维,而不是语言,其(算法)可以通过多种语言进行演绎.5大特性有输入,需要传入1或者多个参数有输出,需要返回1个或者多个结果有穷性,执行
  • 4.C_数据结构_队列 荣世蓥 数据结构数据结构
    概述什么是队列：队列是限定在两端进行插入操作和删除操作的线性表。具有先入先出(FIFO)的特点相关名词：队尾：写入数据的一段队头：读取数据的一段空队：队列中没有数据，队头指针=队尾指针满队：队列中存满了数据，队尾指针+1=队头指针循环队列1、基本内容循环队列是以数组形式构成的队列数据结构。循环队列的结构体如下：typedefintdata_t;//队列数据类型#defineN64//队列容量typ
  • MongoDB知识概括 GeorgeLin98 持久层mongodb
    MongoDB知识概括MongoDB相关概念单机部署基本常用命令索引-IndexSpirngDataMongoDB集成副本集分片集群安全认证MongoDB相关概念业务应用场景：传统的关系型数据库（如MySQL），在数据操作的“三高”需求以及应对Web2.0的网站需求面前，显得力不从心。解释：“三高”需求：①Highperformance-对数据库高并发读写的需求。②HugeStorage-对海量数
  • JAVA·一个简单的登录窗口 MortalTom java开发语言学习
    文章目录概要整体架构流程技术名词解释技术细节资源概要JavaSwing是Java基础类库的一部分，主要用于开发图形用户界面（GUI）程序整体架构流程新建项目，导入sql.jar包（链接放在了文末），编译项目并运行技术名词解释一、特点丰富的组件提供了多种可视化组件，如按钮（JButton）、文本框（JTextField）、标签（JLabel）、下拉列表（JComboBox）等，可以满足不同的界面设计
  • 入门MySQL——查询语法练习 K_un
    前言：前面几篇文章为大家介绍了DML以及DDL语句的使用方法，本篇文章将主要讲述常用的查询语法。其实MySQL官网给出了多个示例数据库供大家实用查询，下面我们以最常用的员工示例数据库为准，详细介绍各自常用的查询语法。1.员工示例数据库导入官方文档员工示例数据库介绍及下载链接：https://dev.mysql.com/doc/employee/en/employees-installation.h
  • C++八股 Petrichorzncu 八股总结c++开发语言
    这里写目录标题C++内存管理C++的构造函数，复制构造函数，和析构函数深复制与浅复制：构造函数和析构函数哪个能写成虚函数，为什么？C++数据结构内存排列结构体和类占用的内存：==虚函数和虚表的原理==虚函数虚表（Vtable）虚函数和虚表的实现细节==内存泄漏==指针的工作原理函数的传值和传址new和delete与malloc和freeC++内存区域划分C++11新特性C++常见新特性==智能指针
  • 博客网站制作教程 2401_85194651 javamaven
    首先就是技术框架：后端：Java+SpringBoot数据库：MySQL前端：Vue.js数据库连接：JPA(JavaPersistenceAPI)1.项目结构blog-app/├──backend/│├──src/main/java/com/example/blogapp/││├──BlogApplication.java││├──config/│││└──DatabaseConfig.java
  • ubuntu安装wordpress lissettecarlr
    1安装nginx网上安装方式很多，这就就直接用apt-get了apt-getinstallnginx不用启动啥，然后直接在浏览器里面输入IP:80就能看到nginx的主页了。如果修改了一些配置可以使用下列命令重启一下systemctlrestartnginx.service2安装mysql输入安装前也可以更新一下软件源，在安装过程中将会让你输入数据库的密码。sudoapt-getinstallmy
  • 【树一线性代数】005入门 Owlet_woodBird 算法
    Index本文稍后补全，推荐阅读：https://blog.csdn.net/weixin_60702024/article/details/141874376分析实现总结本文稍后补全，推荐阅读：https://blog.csdn.net/weixin_60702024/article/details/141874376已知非空二叉树T的结点值均为正整数，采用顺序存储方式保存，数据结构定义如下:t
  • python获取子进程返回值_Python对进程Multiprocessing子进程返回值 weixin_39752157 python获取子进程返回值
    在实际使用多进程的时候，可能需要获取到子进程运行的返回值。如果只是用来存储，则可以将返回值保存到一个数据结构中；如果需要判断此返回值，从而决定是否继续执行所有子进程，则会相对比较复杂。另外在Multiprocessing中，可以利用Process与Pool创建子进程，这两种用法在获取子进程返回值上的写法上也不相同。这篇中，我们直接上代码，分析多进程中获取子进程返回值的不同用法，以及优缺点。初级用法
  • 【数据结构-一维差分】力扣2848. 与车相交的点 hlc@ 数据结构数据结构leetcode算法
    给你一个下标从0开始的二维整数数组nums表示汽车停放在数轴上的坐标。对于任意下标i，nums[i]=[starti,endi]，其中starti是第i辆车的起点，endi是第i辆车的终点。返回数轴上被车任意部分覆盖的整数点的数目。示例1：输入：nums=[[3,6],[1,5],[4,7]]输出：7解释：从1到7的所有点都至少与一辆车相交，因此答案为7。示例2：输入：nums=[[1,3],[5
  • JavaScript `Map` 和 `WeakMap`详细解释 跳房子的前端 JavaScript原生方法javascript前端开发语言
    在JavaScript中，Map和WeakMap都是用于存储键值对的数据结构，但它们有一些关键的不同之处。MapMap是一种可以存储任意类型的键值对的集合。它保持了键值对的插入顺序，并且可以通过键快速查找对应的值。Map提供了一些非常有用的方法和属性来操作这些数据对：set(key,value):将一个键值对添加到Map中。如果键已经存在，则更新其对应的值。get(key):获取指定键的值。如果键
  • knob UI插件使用 换个号韩国红果果 JavaScriptjsonpknob
    图形是用canvas绘制的 js代码 var paras = { max:800, min:100, skin:'tron',//button type thickness:.3,//button width width:'200',//define canvas width.,canvas height displayInput:'tr
  • Android+Jquery Mobile学习系列(5)-SQLite数据库 白糖_ JQuery Mobile
    目录导航   SQLite是轻量级的、嵌入式的、关系型数据库，目前已经在iPhone、Android等手机系统中使用,SQLite可移植性好，很容易使用，很小，高效而且可靠。   因为Android已经集成了SQLite，所以开发人员无需引入任何JAR包，而且Android也针对SQLite封装了专属的API，调用起来非常快捷方便。   我也是第一次接触S
  • impala-2.1.2-CDH5.3.2 dayutianfei impala
    最近在整理impala编译的东西，简单记录几个要点： 根据官网的信息（https://github.com/cloudera/Impala/wiki/How-to-build-Impala）： 1. 首次编译impala，推荐使用命令： ${IMPALA_HOME}/buildall.sh -skiptests -build_shared_libs -format 2.仅编译BE ${I
  • 求二进制数中1的个数 周凡杨 java算法二进制
    解法一： 对于一个正整数如果是偶数，该数的二进制数的最后一位是 0 ，反之若是奇数，则该数的二进制数的最后一位是 1 。因此，可以考虑利用位移、判断奇偶来实现。   public int bitCount(int x){ int count = 0; while(x!=0){ if(x%2!=0){ /
  • spring中hibernate及事务配置 g21121 Hibernate
    hibernate的sessionFactory配置： <!-- hibernate sessionFactory配置 --> <bean id="sessionFactory" class="org.springframework.orm.hibernate3.LocalSessionFactoryBean"> <
  • log4j.properties 使用 510888780 log4j
    log4j.properties 使用 一.参数意义说明 输出级别的种类 ERROR、WARN、INFO、DEBUG ERROR 为严重错误 主要是程序的错误 WARN 为一般警告，比如session丢失 INFO 为一般要显示的信息，比如登录登出 DEBUG 为程序的调试信息 配置日志信息输出目的地 log4j.appender.appenderName = fully.qua
  • Spring mvc-jfreeChart柱图（2） 布衣凌宇 jfreechart
    上一篇中生成的图是静态的，这篇将按条件进行搜索，并统计成图表，左面为统计图，右面显示搜索出的结果。 第一步：导包 第二步；配置web.xml(上一篇有代码) 建BarRenderer类用于柱子颜色 import java.awt.Color; import java.awt.Paint; import org.jfree.chart.renderer.category.BarR
  • 我的spring学习笔记14-容器扩展点之PropertyPlaceholderConfigurer aijuans Spring3
    PropertyPlaceholderConfigurer是个bean工厂后置处理器的实现，也就是BeanFactoryPostProcessor接口的一个实现。关于BeanFactoryPostProcessor和BeanPostProcessor类似。我会在其他地方介绍。 PropertyPlaceholderConfigurer可以将上下文（配置文件）中的属性值放在另一个单独的标准java
  • maven 之 cobertura 简单使用 antlove maventestunitcoberturareport
    1. 创建一个maven项目 2. 创建com.CoberturaStart.java package com; public class CoberturaStart { public void helloEveryone(){ System.out.println("=================================================
  • 程序的执行顺序 百合不是茶 JAVA执行顺序
          刚在看java核心技术时发现对java的执行顺序不是很明白了,百度一下也没有找到适合自己的资料,所以就简单的回顾一下吧   代码如下;     经典的程序执行面试题 //关于程序执行的顺序 //例如： //定义一个基类 public class A(){ public A(
  • 设置session失效的几种方法 bijian1013 web.xmlsession失效监听器
    在系统登录后，都会设置一个当前session失效的时间，以确保在用户长时间不与服务器交互，自动退出登录，销毁session。具体设置很简单，方法有三种：（1）在主页面或者公共页面中加入：session.setMaxInactiveInterval(900);参数900单位是秒，即在没有活动15分钟后，session将失效。这里要注意这个session设置的时间是根据服务器来计算的，而不是客户端。所
  • java jvm常用命令工具 bijian1013 javajvm
    一.概述         程序运行中经常会遇到各种问题，定位问题时通常需要综合各种信息，如系统日志、堆dump文件、线程dump文件、GC日志等。通过虚拟机监控和诊断工具可以帮忙我们快速获取、分析需要的数据，进而提高问题解决速度。 本文将介绍虚拟机常用监控和问题诊断命令工具的使用方法，主要包含以下工具:       &nbs
  • 【Spring框架一】Spring常用注解之Autowired和Resource注解 bit1129 Spring常用注解
    Spring自从2.0引入注解的方式取代XML配置的方式来做IOC之后，对Spring一些常用注解的含义行为一直处于比较模糊的状态，写几篇总结下Spring常用的注解。本篇包含的注解有如下几个： Autowired Resource Component Service Controller Transactional 根据它们的功能、目的，可以分为三组，Autow
  • mysql 操作遇到safe update mode问题 bitray update
        我并不知道出现这个问题的实际原理,只是通过其他朋友的博客,文章得知的一个解决方案,目前先记录一个解决方法,未来要是真了解以后,还会继续补全.     在mysql5中有一个safe update mode,这个模式让sql操作更加安全,据说要求有where条件,防止全表更新操作.如果必须要进行全表操作,我们可以执行 SET
  • nginx_perl试用 ronin47 nginx_perl试用
    因为空闲时间比较多，所以在CPAN上乱翻，看到了nginx_perl这个项目(原名Nginx::Engine)，现在托管在github.com上。地址见：https://github.com/zzzcpan/nginx-perl 这个模块的目的，是在nginx内置官方perl模块的基础上，实现一系列异步非阻塞的api。用connector/writer/reader完成类似proxy的功能（这里
  • java-63-在字符串中删除特定的字符 bylijinnan java
    public class DeleteSpecificChars { /** * Q 63 在字符串中删除特定的字符 * 输入两个字符串，从第一字符串中删除第二个字符串中所有的字符。 * 例如，输入”They are students.”和”aeiou”，则删除之后的第一个字符串变成”Thy r stdnts.” */ public static voi
  • EffectiveJava--创建和销毁对象 ccii 创建和销毁对象
    本章内容： 1. 考虑用静态工厂方法代替构造器 2. 遇到多个构造器参数时要考虑用构建器（Builder模式） 3. 用私有构造器或者枚举类型强化Singleton属性 4. 通过私有构造器强化不可实例化的能力 5. 避免创建不必要的对象 6. 消除过期的对象引用 7. 避免使用终结方法 1. 考虑用静态工厂方法代替构造器     类可以通过
  • [宇宙时代]四边形理论与光速飞行 comsci
       从四边形理论来推论 为什么光子飞船必须获得星光信号才能够进行光速飞行？    一组星体组成星座  向空间辐射一组由复杂星光信号组成的辐射频带，按照四边形-频率假说  一组频率就代表一个时空的入口    那么这种由星光信号组成的辐射频带就代表由这些星体所控制的时空通道，该时空通道在三维空间的投影是一
  • ubuntu server下python脚本迁移数据 cywhoyi pythonKettlepymysqlcx_Oracleubuntu server
    因为是在Ubuntu下，所以安装python、pip、pymysql等都极其方便，sudo apt-get install pymysql， 但是在安装cx_Oracle（连接oracle的模块）出现许多问题，查阅相关资料，发现这边文章能够帮我解决，希望大家少走点弯路。http://www.tbdazhe.com/archives/602 1.安装python 2.安装pip、pymysql
  • Ajax正确但是请求不到值解决方案 dashuaifu Ajaxasync
    Ajax正确但是请求不到值解决方案   解决方案：1 .     async: false ,    2.     设置延时执行js里的ajax或者延时后台java方法！！！！！！！   例如：   $.ajax({     &
  • windows安装配置php+memcached dcj3sjt126com PHPInstallmemcache
    Windows下Memcached的安装配置方法 1、将第一个包解压放某个盘下面，比如在c:\memcached。 2、在终端（也即cmd命令界面）下输入 'c:\memcached\memcached.exe -d install' 安装。 3、再输入： 'c:\memcached\memcached.exe -d start' 启动。（需要注意的: 以后memcached将作为windo
  • iOS开发学习路径的一些建议 dcj3sjt126com ios
    iOS论坛里有朋友要求回答帖子，帖子的标题是： 想学IOS开发高阶一点的东西，从何开始，然后我吧啦吧啦回答写了很多。既然敲了那么多字，我就把我写的回复也贴到博客里来分享，希望能对大家有帮助。欢迎大家也到帖子里讨论和分享，地址：http://bbs.csdn.net/topics/390920759   下面是我回复的内容：   结合自己情况聊下iOS学习建议，
  • Javascript闭包概念 fanfanlovey JavaScript闭包
    1.参考资料 http://www.jb51.net/article/24101.htm http://blog.csdn.net/yn49782026/article/details/8549462 2.内容概述 要理解闭包，首先需要理解变量作用域问题 内部函数可以饮用外面全局变量 var n=999; 　　functio
  • yum安装mysql5.6 haisheng mysql
    1、安装http://dev.mysql.com/get/mysql-community-release-el7-5.noarch.rpm   2、yum install mysql   3、yum install mysql-server   4、vi /etc/my.cnf   添加character_set_server=utf8
  • po/bo/vo/dao/pojo的详介 IT_zhlp80 javaBOVODAOPOJOpo
        JAVA几种对象的解释 PO:persistant object持久对象,可以看成是与数据库中的表相映射的java对象。最简单的PO就是对应数据库中某个表中的一条记录，多个记录可以用PO的集合。PO中应该不包含任何对数据库的操作. VO:value object值对象。通常用于业务层之间的数据传递，和PO一样也是仅仅包含数据而已。但应是抽象出的业务对象,可
  • java设计模式 kerryg java设计模式
    设计模式的分类：    一、 设计模式总体分为三大类： 1、创建型模式（5种）：工厂方法模式，抽象工厂模式，单例模式，建造者模式，原型模式。 2、结构型模式（7种）：适配器模式，装饰器模式，代理模式，外观模式，桥接模式，组合模式，享元模式。 3、行为型模式（11种）：策略模式，模版方法模式，观察者模式，迭代子模式，责任链模式，命令模式，备忘录模式，状态模式，访问者
  • [1]CXF3.1整合Spring开发webservice——helloworld篇 木头.java springwebserviceCXF
    Spring 版本3.2.10 CXF 版本3.1.1 项目采用MAVEN组织依赖jar 我这里是有parent的pom，为了简洁明了，我直接把所有的依赖都列一起了，所以都没version，反正上面已经写了版本 <project xmlns="http://maven.apache.org/POM/4.0.0" xmlns:xsi="ht
  • Google 工程师亲授：菜鸟开发者一定要投资的十大目标 qindongliang1922 工作感悟人生
    身为软件开发者，有什么是一定得投资的？ Google 软件工程师 Emanuel Saringan 整理了十项他认为必要的投资，第一项就是身体健康，英文与数学也都是必备能力吗？来看看他怎么说。（以下文字以作者第一人称撰写）） 你的健康 无疑地，软件开发者是世界上最久坐不动的职业之一。 每天连坐八到十六小时，休息时间只有一点点，绝对会让你的鲔鱼肚肆无忌惮的生长。肥胖容易扩大罹患其他疾病的风险，
  • linux打开最大文件数量1,048,576 tianzhihehe clinux
    File descriptors are represented by the C int type. Not using a special type is often  considered odd, but is, historically, the Unix way. Each Linux process has a maximum number of files th
  • java语言中PO、VO、DAO、BO、POJO几种对象的解释 衞酆夼 javaVOBOPOJOpo
    PO:persistant object持久对象 最形象的理解就是一个PO就是数据库中的一条记录。好处是可以把一条记录作为一个对象处理，可以方便的转为其它对象。可以看成是与数据库中的表相映射的java对象。最简单的PO就是对应数据库中某个表中的一条记录，多个记录可以用PO的集合。PO中应该不包含任何对数据库的操作。 BO:business object业务对象 封装业务逻辑的java对象
按字母分类： ABCDEFGHIJKLMNOPQRSTUVWXYZ其他