结合PXA270 Bootloader实例详细分析ARM映象文件
结合PXA270 Bootloader实例详细分析ARM映象文件
最近花了一个月的时间终于把PXA270的板子Bootloader 部分整出来了，颇费周折；其中的很长一段时间，一直被ARM可执行程序的执行机理迷惑：搞不懂ARM的映象文件组成、代码重定位、地址重映射remap等，网上查了N多资料看了N多技术帖子总算整清楚。如今写出来整理一下思路，也为其它初始进入ARM系统设计的兄弟们提供点资料借鉴，少走些弯路是好。
ARM学习过程中，初学者最难突破的应当是ARM映象文件形态和ARM启动代码分析了，本文将以我的Bootloader源码为例，力求作个透彻分析。
如下给出我的开发环境：
² Cpu：INTEL PXA270 (ARM V5TE)
² Board:INTEL MAINSTONE 2
² Memory:64MByte SDRAM,32MByte NorFlash(Inte E28F128),32MByte NandFlash
² Cross-complier:cross_3.3.2
一、关于映象文件和load region和execute region：
1. ARM映象文件组成
我们在ADS中编译源代码文件后的生成文件有两个：.axf和.bin文件。.bin文件是二进制格式执行文件，它才是真正可下载到FLASH中运行的；.axf文件是ADS的调试文件，利用UltraEdit查看其二进制代码，可以发现.axf其实是在.bin文件基础上增加文件头标识、文件尾表示（U－boot中的mkimage工具在映象文件中加入64kbyte的文件头，以供U-Boot识别）、再插入ADS的调试符号。打开ADS的调试器，可对.axf文件调试。
2. ARM映象文件加载域（load region）、运行域(execute region)
看了很多ARM教材这方面都没怎么涉及，有的书本提到感觉始终太过术语话，不太好明白。这里我首先对些关键概念做个简单名词解释，相信大家一看就懂：
² RO：Read-only
RW：Read-write.
ZI：Zero-initialized
² 段(Section)：描述映像文件的代码或数据块。
² 输入段(input section)：它包含着代码，初始化数据或标记了在应用程序运行之前必须要初始化为0的一段内存。
² 输出段(output section)：它包含了一系列具有相同的RO，RW或ZI属性的输入段。
² 域(Regions)：在一个映像文件中，一个域包含了1至3个输出段。1个或多个域（一般是一个）组织在一起，就构成了最终的映像文件。
² 加载时地址：是指映像文件位于存储器(在该映像文件没有运行时，如FLASH)中的地址。
² 运行时地址：是指映像文件在运行时的地址（映象文件内存中运行）。
其实举个实例来分析：我的源代码编译后生成的二进制zybootloader.bin文件就是一个域，打开ADS的”Realese Settings”标签页“listing”，选中“Image map””Symbols”，编译生成目标文件时，ADS就会生成映象、符号的地址表。观察发现它由三个输出段组成:RO、RW、ZI，各输出段大小如图：
二、 源代码详细分析
说了这么多，拿我自己的Bootloader启动代码来给大家分析一下，就再清楚不过的了。
Bootloader在进入C代码运行之前，先经历一些代码位置无关的顺序初始化例程：
² 获取外部目标头文件，声明外部变量
² 主程序入口，定义中断向量表，跳转到复位异常
² 设置处理器工作模式为SVC，并禁止中断（bootloader运行过程中一直都要禁止）
² 初始化GPIO、内存控制寄存器
² 初始化电源管理寄存器，设置CPU工作频率时钟
² 为六大中断分配堆栈空间
以上步骤大家结合datasheet可以对照看懂。
最后一步，最最关键的啦，Bootloader将要做个“乾坤大挪移”动作，然后对ZI区清零：
Step 1:复制RO到SDRAM,程序将无缝切换到SDRAM空间运行；
Step 2:复制RW到SDRAM，这里包括已初始化的全局变量；并且对ZI段未初始化的全局变量全部清零！OK，现在程序可以安全跳入C主函数运行了！下图为两步的示意图，其中：
|Image＄＄RO＄＄Base| ; RO段起始地址
|Image＄＄RO＄＄Limit| ; RO段结束地址加1
|Image＄＄RW＄＄Base| ; RW段起始地址
|Image＄＄RW＄＄Limit| ; RW段结束地址加1
|Image＄＄ZI＄＄Base| ; ZI段起始地址
|Image＄＄ZI＄＄Limit| ; ZI段结束地址加1
编译器从R0_base 和RW_base来得到这些地址。
源代码详细分析：
;/************************************************************************ /
;Step 1 将FLASH的CODE拷贝到SDRAM中（RO_BASE指定的地址）
;===============================================
;bl xlli_icache_enable ; Enable I-Cache, D-Cache, BTB
;don't enable cache, make it's safe for download and boot!
;bl LedFlash ;led flash test after xlli_icache_enable, hzh
IF RELOCATE_ROM=1
adr r0, MAIN
ldr r2, BaseOfROM
cmp r0, r2
ldreq r0, TopOfROM
beq InitRam
ldr r3, TopOfROM
0
ldmia r0!, {r4-r7}
stmia r2!, {r4-r7}
cmp r2, r3
bcc %B0;无符号数小于
sub r2, r2, r3 ; r2 超出r3
sub r0, r0, r2 ;确保取得RW区精确起始地址
;Step 2:初始化SDRAM,将RW段拷贝到SDRAM
InitRam
ldr r2, BaseOfBSS
ldr r3, BaseOfZero
0
cmp r2, r3
ldrcc r1, [r0], #4
strcc r1, [r2], #4
bcc %B0
；对SDRAM ZI段清零
mov r0, #0
ldr r3, EndOfBSS
1
cmp r2, r3
strcc r0, [r2], #4
bcc %B1
;跳转到C的主函数Main中
ldr pc, =GotoMain
GotoMain
;mov r0, #3
;bl LedSet
;IF :DEF: BOOTABLE
ldr r0, EndOfBSS
;ELSE
;ldr r0,=|Image$$ZI$$Limit|
;
bl PlatformMain
b GotoMain
ENDIF
BaseOfROM DCD |Image$$RO$$Base|
TopOfROM DCD |Image$$RO$$Limit|
BaseOfBSS DCD |Image$$RW$$Base|
BaseOfZero DCD |Image$$ZI$$Base|
EndOfBSS DCD |Image$$ZI$$Limit|
二、 后续
已经今天暂且写到这里，PXA270的Bootloader已经做成功了，后面将会结合自己的开发笔记陆续对U-Boot 1.1.6在我的开发板PXA270上的移植流程和LINUX内核启动代码作分析。