VBS: 自动下载每天NBA比赛集锦

 NBA季后赛到了，写个vbs自动下载每天NBA比赛集锦，拷到手机上就可以在路上慢慢看

sdate="20130502"
strURL = "http://www.nba.com/gameline/"&sdate&"/"
'这里记得有http, 没有的话就会出错
curLocation = left(wscript.scriptfullname,instrrev(wscript.scriptfullname,"\")-1)&"\"
'当前目录
strLocation = "nba.html"

f_wget strurl,curLocation&strlocation
'当用f_wget (strfileurl,strlocation)会出错Cannot use parentheses when calling a Sub
'调用过程时不能加括号。
'这只是概要提示，其实参数个数为1个或没有时可以加括号。
'解决方法：去掉f_wget函数的括号，或把这个函数的结果赋给一个变量，或使用call


'------------------f_wget function start----------------------------'
'功能：下载并保存在指定目录，argum_savefile需要带目录'
'当前目录的写法：　curLocation = left(wscript.scriptfullname,instrrev(wscript.scriptfullname,"\")-1)&"\"
Function f_wget(argum_ulr,argum_savefile)
    Set objXMLHTTP = CreateObject("MSXML2.XMLHTTP")
    objXMLHTTP.open "GET", argum_ulr, false
    objXMLHTTP.send()

    If objXMLHTTP.Status = 200 Then
    Set objADOStream = CreateObject("ADODB.Stream")
    objADOStream.Open
    objADOStream.Type = 1 'adTypeBinary

    objADOStream.Write objXMLHTTP.ResponseBody
    objADOStream.Position = 0    'Set the stream position to the start

    Set objFSO = Createobject("Scripting.FileSystemObject")
    If objFSO.Fileexists(argum_savefile) Then objFSO.DeleteFile argum_savefile
    Set objFSO = Nothing

    objADOStream.SaveToFile argum_savefile
    objADOStream.Close
    Set objADOStream = Nothing
    End if
    Set objXMLHTTP = Nothing
End Function
'---------------------------------------------------------------------'
'''
'---------------------------Function f_replace------------------------'
'功能：将指定目录的文件中字符替代成另一个字符,arg_file需要带目录'
'当前目录的写法：　curLocation = left(wscript.scriptfullname,instrrev(wscript.scriptfullname,"\")-1)&"\"
Function f_replace(arg_file,arg_find,arg_rep)
    If arg_file<>"" Then
    'Dim FS, FileStream
    Set FS = CreateObject("Scripting.FileSystemObject")
    on error resume Next
    Set FileStream = FS.OpenTextFile(arg_file)
    FileContents = FileStream.ReadAll
    End If
    dFileContents = replace(FileContents, arg_find, arg_rep, 1, -1, 1)
    if dFileContents <> FileContents Then
    'Dim OutStream, FS
    on error resume Next
    'Set FS = CreateObject("Scripting.FileSystemObject")
    Set OutStream = FS.OpenTextFile(arg_file, 2, True)
    OutStream.Write dFileContents
    End If
    Set FS = Nothing
End Function
'----------------------------------------------------------'
Find = chr(34)
ReplaceWith = Chr(10)
f_replace curLocation&strLocation,Find,ReplaceWith

Set fso = CreateObject("Scripting.FileSystemObject")
Set MyFile= fso.OpenTextFile(curLocation&strLocation, 1 , TRUE)
'读入文本文件，按行进行判断
do until MyFile.atendofstream
    strline=MyFile.readline
    If InStr(strline,"/video/channels/playoffs/2013/") = 1 Then
        strline2=right(strline,Len(strline)-6)
        strline3=Left(strline2,Len(strline2)-11)
        strline4="http://ht.cdn.turner.com/nba/big"&strline3&"_nba_576x324.flv"
        strline5=right(strline,Len(strline)-47)
        strline6=Left(strline5,Len(strline5)-21)
        strline7=curLocation&sdate&"-"&strline6&".flv"
        f_wget strline4,strline7
   End If
loop
Set fso = nothing