使用组策略计算机启动脚本部署 Office 2010

在测试环境中部署 Office 2010

本节阐述并介绍了组策略计算机启动脚本基础设施的测试网络环境。它还包括了使用组策略计算机启动脚本部署 Microsoft Office Professional Plus 2010 的过程步骤。

网络环境

下图中显示了本文的测试网络环境。

所有服务器（A 和 B）都运行 Windows Server 2008 R2，并且是同一域 (CPANDL.COM) 的成员，该域包括运行 Windows 7 Professional 和 Windows Vista 的客户端计算机 (C)。每台客户端计算机的完全限定的域名 (FQDN)、每台服务器所运行的应用程序和角色、带有所含计算机的组织单位 (OU) 以及组策略对象 (GPO) 如下所列：

• A �C <DC.CPANDL.COM> Active Directory、DNS、DHCP、GPO-Office2010_GPO、OU-Office2010_OU、W7C01 和 WVC02 是 OU Office2010_OU 的成员

• B �C <FS.CPANDL.COM> 文件服务、文件共享-\\FS\Office2010SourceFiles（只读访问）、文件共享-\\FS\Office2010LogFiles（读写访问）

• C �C <W7C01.CPANDL.COM 和 WVC02.CPANDL.COM> Windows 7 Professional 和 Windows Vista Enterprise

重要：
确保经过验证的用户对网络共享具有读取访问权限。在此示例中，网络共享为 \\FS\Office2010SourceFiles。

注意：
Office2010_GPO 链接到 Office2010_OU。这样，就能够将 GPO 的设置分配给 OU 内所含的计算机对象。若要将 GPO 链接到 OU，请使用 MMC 管理单元“组策略管理”。

在生产环境中自定义并部署 Office 2010 之前，我们建议您阅读以下文章：规划 Office 2010 的批量激活、部署 Office 2010 的批量激活、Office 2010 自定义概述、为 Office 2010 创建网络安装点、2007 Office system 中的 Office 自定义工具、Office 2010 中的 Config.xml 文件、自定义 Office 2010 和 64 位 Office 2010 版本。

自定义 Office 2010 安装程序

用于为 Office 2010 创建安装程序自定义文件的程序文件是从包含 Office 安装 CD 中所有文件的副本的源目录中运行的。在本例中，源文件已复制到 \\FS\Office2010SourceFiles。

在 Office 2010 中，由安装程序来控制整个安装。这包括 Windows Installer 在 2007 Office system 之前的 Office 版本中处理的过程。自定义安装程序的默认行为使您可以控制过程。在本例中，您使用 Config.xml 文件来自定义 Office 2010 无提示安装的安装，并使用 Office 自定义工具 (OCT) 来自定义 Office 2010 产品的安装，例如，指定批量许可证密钥和选择要安装 Microsoft Office 中的哪些应用程序。在计算机上安装 Office 时，安装程序将应用 config.xml 和 .msp 文件（通过使用 OCT 创建）中的自定义项。

在 Config.xml 中指定无提示安装选项

若要为 Office 2010 产品配置不需要用户交互的无提示安装（无人参与安装），请为要安装的产品修改 Config.xml 文件并将 Display 元素的 Level 属性设置为 "none" (Display Level="none")，然后保存 Config.xml 文件，如以下过程所示。Display 元素指定安装程序向用户显示的用户界面级别。

1. 使用文本编辑器工具（例如记事本）打开所安装 Office 产品（本例中为 Office Professional Plus 2010）的 Config.xml 文件。默认情况下，Config.xml 文件位于核心产品 .WW 文件夹（本例中为 \\FS\Office2010SourceFiles\ProPlus.WW）中。

2. 找到包含 Display 元素的行，如下面的示例所示：

   <!-- <Display Level="full" CompletionNotice="yes" SuppressModal="no" AcceptEula="no" /> -->

3. 通过要使用的无提示选项修改 Display 元素项。请确保删除注释分隔符“<!--”和“-->”。例如，使用以下语法：

   <Display Level="none" CompletionNotice="no" SuppressModal="yes" AcceptEula="yes" />

   这些选项将指示安装程序以无提示方式运行，防止提示用户输入信息，并防止安装等待任何用户交互。有关语法和 Config.xml 的详细信息，请参阅 Office 2010 中的 Config.xml 文件中的 Display 元素。

4. 保存 Config.xml 文件，在本例中保存到 \\FS\Office2010SourceFiles\ProPlus.WW。

使用 OCT 指定批量许可证密钥并选择要安装的应用程序

1. 若要自定义 Office 安装程序，请使用命令行 setup.exe /admin 启动 Office 自定义工具。在本例中，在命令提示符处，从程序包源目录 \\FS\Office2010SourceFiles 中运行setup.exe /admin。

2. 在本例中，若要输入批量许可证密钥并选择要安装的应用程序，请按如下方式修改和配置设置：

3. 选择位于“授权和用户界面”下的“输入另一个产品密钥”选项，然后输入一个有效的多次激活密钥 (MAK) 密钥。

   注意：
   在本例中，由于无提示安装的参数是在 Config.xml 文件中配置的，因此在使用 OCT 时不必同时配置这些参数。这是因为您在 Config.xml 中定义的自定义项优先于使用 OCT 所创建自定义文件中的自定义项。

   
   

4. 选择位于“功能”下的“设置功能安装状态”选项，然后选择要安装哪些应用程序。在本例中，为了加快安装过程，只选择了 Microsoft Word。

   有关可在使用 OCT 时配置的不同参数的其他资源，请参阅 2007 Office system 中的 Office 自定义工具、配置 Office 2010 的功能安装状态和为 Office 2010 配置用户设置。

5. 保存并命名新创建的 .msp 文件，然后将其放在包含源文件的计算机上 Office 2010 的 \Updates 文件夹中，在本例中，该位置为 \\FS\Office2010SourceFiles\Updates\Office2010ProPlus.MSP。

警告：
只支持在 Updates 文件夹中包含每个产品的一个安装程序自定义 .msp 文件。如果在部署 Office 2010 的初始安装，并且希望部署 Office 2010 软件更新（例如 Service Pack 和修补程序），安装程序可以在安装过程中应用产品更新。您可以将在安装完成后应用的 Office 2010 产品更新放在 Updates 文件夹中。有关详细信息，请参阅 2007 Office system 中的 Office 自定义工具

下一步是在域控制器（本例中为 DC.CPANDL.COM）上配置脚本。

在域控制器上配置脚本

在域控制器上配置脚本的过程涉及以下步骤：

1. 将脚本复制到 GPO 的启动文件夹。

2. 将脚本添加到 GPO。

3. 为启动脚本设置最长运行时间。

警告：
通过组策略可以影响组织中成百上千台计算机的配置。因此，在将所有新组策略配置或部署移到生产环境中之前在测试环境中对其进行严格测试至关重要。有关暂存组策略部署的详细信息，请参阅组策略规划和部署指南 (http://go.microsoft.com/fwlink/?linkid=182208&clcid=0x804) 中的暂存组策略部署。

将脚本复制到 GPO 的启动文件夹

本例包括一个示例批处理文件脚本，该脚本阐释如何在尚未安装产品的情况下运行 Microsoft Office Setup.exe，并将错误或成功信息记录到集中式日志文件。已为此测试部署方案修改了该脚本开头处的变量。例如，添加了带有 Office14 前缀的产品名称 ProPlus 以及 Office 源文件 \\FS\Office2010SourceFiles 和日志文件 \\FS\Office2010LogFiles 的路径。此示例脚本随后复制到记事本中，并使用文件名 Office2010StartupScript.bat 保存。然后，该脚本文件将保存到域控制器上 GPO 启动脚本的默认目录，在本例中为 C:\Windows\SYSVOL\sysvol\adatum.com\Policies\{GUID of GPO}\Machine\Scripts\Startup。

注意：
可通过右键单击 GPO（在本例中为 Office2010_GPO），然后单击“属性”，在 MMC 管理单元的“组策略管理编辑器”中找到表示该 GPO 的 GUID。GUID 列在“唯一的名称”字段中。

setlocal

REM *********************************************************************
REM Environment customization begins here. Modify variables below.
REM *********************************************************************

REM Get ProductName from the Office product's core Setup.xml file, and then add "office14." as a prefix. 
set ProductName=Office14.PROPLUS

REM Set DeployServer to a network-accessible location containing the Office source files.
set DeployServer=\\FS\Office2010SourceFiles

REM Set ConfigFile to the configuration file to be used for deployment (required)
set ConfigFile=\\FS\Office2010SourceFiles\ProPlus.WW\config.xml

REM Set LogLocation to a central directory to collect log files.
set LogLocation=\\FS\Office2010LogFiles

REM *********************************************************************
REM Deployment code begins here. Do not modify anything below this line.
REM *********************************************************************

IF NOT "%ProgramFiles(x86)%"=="" (goto ARP64) else (goto ARP86)

REM Operating system is X64. Check for 32 bit Office in emulated Wow6432 uninstall key
:ARP64
reg query HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432NODE\Microsoft\Windows\CurrentVersion\Uninstall\%ProductName%
if NOT %errorlevel%==1 (goto End)

REM Check for 32 and 64 bit versions of Office 2010 in regular uninstall key.(Office 64bit would also appear here on a 64bit OS) 
:ARP86
reg query HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\%ProductName%
if %errorlevel%==1 (goto DeployOffice) else (goto End)

REM If 1 returned, the product was not found. Run setup here.
:DeployOffice
start /wait %DeployServer%\setup.exe /config %ConfigFile%
echo %date% %time% Setup ended with error code %errorlevel%. >> %LogLocation%\%computername%.txt

REM If 0 or other was returned, the product was found or another error occurred. Do nothing.
:End

Endlocal

将脚本添加到 GPO

若要将脚本添加到 GPO，请使用 MMC 管理单元“组策略管理编辑器”，并右键单击“启动”（“GPO”|“计算机配置”|“策略”|“Windows 设置”|“脚本(启动/关机)”|“启动”），依次单击“属性”、“添加”、“浏览”，然后突出显示并选择脚本文件，在本例中为 Office2010StartupScript.bat。

设置启动脚本的最长运行时间

默认情况下，系统最多只允许合并的脚本组运行 600 秒（10 分钟）。管理员可以使用策略设置调整此时间间隔以确保启动脚本完成运行。“组策略脚本的最长等待时间”策略设置指定系统等待组策略所应用的脚本运行的时间。此设置限制了组策略所应用的所有登录、启动和关机脚本完成运行所需的总时间。与任何组策略部署一样，您必须在暂存环境中全面测试您的启动脚本，然后再将它们部署到您的生产环境。通过测试，可以帮助您确定要用于特定网络环境的“组策略脚本的最长等待时间”策略的值。此值设置得过低可能导致安装过早终止。有些因素可能会影响此值，如网络速度、客户端计算机硬件以及在客户端计算机上运行的其他脚本。通过全面测试此策略设置，您可以确定要用于特定环境的适当的值。

在此示例方案中，“组策略脚本的最长等待时间”策略设置的值设置为 0，该值将指示系统在脚本完成之前一直等待，而不管脚本花费了多长时间。

若要更改 GPO（本例中为 Office2010_GPO）的“组策略脚本的最长等待时间”策略的值，请使用 MMC 管理单元“组策略管理编辑器”，并双击“组策略脚本的最长等待时间”（“GPO”|“计算机配置”|“策略”|“管理模板”|“系统”|“脚本”）。

将对 GPO 所做的计算机启动脚本策略更改应用于目标计算机（本例中为 W7C01.CPANDL.COM 和 WVC02.CPANDL.COM）后，计算机启动脚本将在计算机启动时执行。您可以在客户端计算机上的命令提示符处发出以下命令行，而不是等待域控制器在客户端计算机上刷新策略： gpupdate /force您可以使用策略的结果集 (RSoP) MMC 管理单元来验证计算机启动脚本的计算机策略设置是否存在于客户端计算机上。

验证计算机启动脚本状态

在本例中，脚本日志记录信息写入 computername.txt 文件并保存到网络共享 \\FS\Office2010LogFiles。日志文件中的返回代码 0 表示安装成功完成。返回代码 3010 表示需要重新启动。有关 Office 产品的 Windows Installer 进程的其他错误代码的详细信息，请参阅 Microsoft 知识库文章 290158：Office 2003 产品和 Office XP 产品中 Windows Installer 进程的错误代码和错误信息列表。