U-Boot系列之三:u-boot整体结构及启动代码分析(有加入一些新东西)

一、U-BOOT的目录结构
u-boot目录下有18个子目录，分别存放管理不同的源程序。这些目录中所要存放的文件有其规则，可以分成三类。
 第一类目录与处理器体系结构或者开发板硬件直接相关；
 第二类目录是一些通用的函数或者驱动程序；
 第三类目录是u-boot的应用程 序、工具或者文档。
Board ：和一些已有开发板相关的文件，比如Makefile和u-boot.lds等都和具体开发板的硬件和地址分配有关，主要包含SDRAM、FLASH驱动。
Common ：与体系结构无关的文件，实现各种命令的C文件。
CPU ：CPU相关文件，其中的子目录都是以u-boot所支持的 CPU为名，比如有子目录arm926ejs、mips、mpc8260和nios等，每个特定的子目录中都包括cpu.c和interrupt.c和 start.S。其中cpu.c初始化cpu、设置指令cache和数据cache等；interrupt.c设置系统的各种终端和异常，比如快速中断， 开关中断、时钟中断、软件中断、预取中止和未定义指令等；start.S是u-boot启动时执行的第一个文件，他主要是设置系统堆栈和工作方式，为进入 C程序奠定基础。
Disk ：disk驱动的分区处理代码、
Doc ：文档。
Drivers ：通用设备驱动程序，比如各种网卡、支持 CFI的flash、串口和USB总线等。
Dtt ：数字温度测量器或者传感器的驱动
Examples ：一些独立运行的应用程序的例子。
Fs ： 支持文件系统的文件，u-boot现在支持cramfs、fat、fdos、jffs2、yaffs和registerfs。
Include ：头 文件，还有对各种硬件平台支持的会变文件，系统的配置文件和对文件系统支持的文件，其configs子目录下与目标板相关的配置头文件是移植过程中经常要修改的文件。
Net ：与网络有关的代码，BOOTP协议、TFTP协议 RARP协议和NFS文件系统的实现。
Lib_ppc ：存放对PowerPC体系结构通用的文件，主要用于实现PowerPC平台通用的函数，与 PowerPC体系结构相关的代码。
Lib_i386 ：存放对X86体系结构通用的文件，主要用于实现X86平台通用的函数，与PowerPc体 系结构相关的代码。
Lib_arm ：存放对ARM体系结构通用的文件，主要用于实现ARM平台通用的函数，与ARM体系结构相关的代码。
Lib_generic ： 通用的多功能函数实现。
Post ：上电自检。
Rtc ： 实时时钟驱动。
Tools ：创建S-Record格式文件和U-BOOT images的工具。

 

二、移植步骤

为了使U-Boot支持新的开发板,一种简便的做法是在U-Boot已经支持的开发板中选择一种和目标板接近的,并在其基础 上进行修改。代码修改的步骤如下：
1)在board目录下创建fs2410目录,添加fs2410.c、flash.c、 memsetup.s、u-boot.lds和config.mk等(这几个文件直接从smdk2410文件夹中拷贝过来，而且直接将smdk2410.c修改为fs2410即可，然后在Makefile中将目标文件改为fs2410);
2)在cpu目录下创建arm920t目录,主要包含start.s、 interrupts.c、cpu.c、serial.c和speed.c等文件(在cpu目录下创建目录只是在u-boot不支持你板子上面的处理器时才要重建，而且一般也是可以从已有的cpu目录中拷贝过来的);
3)在include/configs目录下添加 fs2410.h(实际上就是将smdk2410.h重命名为fs2410.h),它定义了全局的宏定义等;
4)修改u-boot根目录下的Makefile文件：
fs2410_config : unconfig@./mkconfig $(@:_config=) arm arm920t fs2410 NULL s3c24x0
5)运行make fs2410_config,如果没有错误,就可以开始进行与硬件相关的代码移植工作。由于这部分代码与硬件紧密相关,所以要熟悉开发板的硬件配置, 可参考各芯片的用户手册。

 

以上几步还只是对你自己的板子进行了移植和配置，接下来就需要将你修改过的u-boot进行编译拉，为了使得你编译的u-boot能够在特定的板子上运行，所以必须要进行交叉编译，所以还得在宿主机上安装交叉编译环境，然后将交叉编译器路径加入到当前的环境变量中。

 

 

三、u-boot的编译
u-boot的源码是通过GCC和Makefile组织编译的，顶层目录下的Makefile首先可以设置板子的定义，然 后递归地调用各级目录下的Makefile，最后把编译过的程序链接成u-boot的映像。
顶层目录下的Makefile，它是负责U-Boot 整体配置编译。每一种开发板在Makefile都需要有板子配置的定义，如smdk2410定义如下：
smdk2410_config: unconfig
                @./mkconfig $(@:_config=) arm arm920t smdk2410
执行配置U-Boot的命令make smdk2410_config，通过./mkconfig脚本生成include/config.mk的配置文件。文件内容是根据Makefile对板 子的配置生成的。
配置环境和编译过程如下所述,U-boot的编译环境配置需要：cross-2.95.3.tar.bz2，将文件拷贝到/home/amoi/working/下，然后对对文件进行解压，在/usr/local/目录下建立一个arm文件夹（mkdir –p /usr/local/arm （-p  是需要时创建上层目录，如目录早已存在则不当作错误））将cross-2.95.3.tar.bz2解压出来的移动到/usr/local/arm/下 （mv 2.95.3 /usr/local/arm/）
移动后添加环境变量export PATH=$PATH:/usr/local/2.95.3/bin/。

将交叉编译器的环境都配置好了之后，就可以直接进入到u-boot的顶层目录运行make,Makefile里面可以不用甚至交叉编译器的前缀，里面有根据不同的体系结构来定义不同的交叉编译器前缀，会在顶层目录下生成u-boot、u-boot.bin、u-boot.map、2 u-boot.srec四个文件。

 

四、u-boot系统启动流程
大多数bootloader都分为stage1和stage2两部分，u-boot也不例外。依赖于CPU体系结构的代码（如设备初始化代码等）通常都放在stage1且可以用汇编语言来实现，而stage2则通常用C语言来实现，这样可以实现复杂的功能，而且 有更好的可读性和移植性。
1、Stage1  start.S代码结构
u-boot的stage1代码通常放在start.S文件中， 他用汇编语言写成，其主要代码部分如下：
（1）定义入口。由于一个可执行的Image必须有一个入口点，并且只能有一个全局入口，通常这个入口放 在ROM（Flash）的0x0地址，因此，必须通知编译器以使其知道这个入口，该工作可通过修改连接器脚本来完成。
（2）设置异常向量 （Exception Vector）。
（3）设置CPU的速度、时钟频率及终端控制寄存器。
（4）初始化内存控制器。
（5）将 ROM中的程序复制到RAM中。
（6）初始化堆栈。
（7）转到RAM中执行，该工作可使用指令ldr pc来完成。
2、 Stage2  C语言代码部分
lib_arm/board.c中的start arm boot是C语言开始的函数也是整个启动代码中C语言的主函数，同时还是整个u-boot（armboot）的主函数，该函数只要完成如下操作：
（1） 调用一系列的初始化函数。
（2）初始化Flash设备。
（3）初始化系统内存分配函数。
（4）如果目标系统拥有NAND设备，则 初始化NAND设备。
（5）如果目标系统有显示设备，则初始化该类设备。
（6）初始化相关网络设备，填写IP、MAC地址等。
（7） 进去命令循环（即整个boot的工作循环），接受用户从串口输入的命令，然后进行相应的工作。
3、U-Boot的启动顺序
主要顺序如下图 所示
 
                         函数顺序               初始化顺序
                                 图为 U-Boot顺序

下面就根据代码进行解释：
/*********************** 中断向量 ***********************/
.globl _start                         //u-boot启动入口
_start: b       reset               //复位向量并且跳转到reset
 ldr pc, _undefined_instruction  //未定义指令异常
 ldr pc, _software_interrupt   //软件中断异常
 ldr pc, _prefetch_abort  //预取指中止
 ldr pc, _data_abort  //预取数中止
 ldr pc, _not_used
 ldr pc, _irq                     //中断向量
 ldr pc, _fiq                     //中断向量

 

_undefined_instruction: .word undefined_instruction
_software_interrupt:    .word software_interrupt
_prefetch_abort:        .word prefetch_abort
_data_abort:            .word data_abort
_not_used:              .word not_used
_irq:                   .word irq
_fiq:                   .word fiq

并通过下段代码拷贝到内存里
relocate:                             //把uboot重新定位到RAM
 adr r0, _start                  // r0 是代码的当前位置，也就是u-boot第一条指令的地址
 ldr r2, _armboot_start               //r2 是armboot的开始地址
 ldr r3, _armboot_end                //r3 是armboot的结束地址，这里有时候也会用_bss_start来代替_armboot_end,因为bss段就在armboot段上面，比邻，这里说的上面是指在内存中，地址是向下递减的，所以越在上面地址越大。
 sub r2, r3, r2                      // r2得到armboot的大小
 ldr r1, _TEXT_BASE            // r1 得到目标地址 ，将要加载到RAM中的地址0x30008000赋值给r1，这里应该还有个将u-boot当前的地址和将要加载到RAM中的地址进行比较，如果相等，则表示u-boot已经被重定位到RAM中，也就不需要下面的重定位拉。

// /board/smdk2410/config.mk中定义了_TEXT_BASE，表示把u-boot搬到内存中的相应位置，在这里是 0x33F00000，相对于0x30000000来说是63MB的地方，朋友们可能要疑惑了，前面的文章不是介绍了我们用的板子是32M内存吗？那怎么 是63M的地方呢，其实2410支持地址循环 ，这里其实就是31M的地方，哈哈，那u-boot不是把自己放在SDRAM中的最高的地方吗？的确是这样 的。
 add r2, r0, r2                       // r2 得到源结束地址
copy_loop:                             //重新定位代码
 ldmia r0!, {r3-r10}                  //从源地址[r0]中复制
 stmia r1!, {r3-r10}                  //复制到目标地址[r1]
 cmp  r0, r2                        //复制数据块直到源数据末尾地址[r2]
 ble copy_loop

系统上电或reset后，cpu的PC一般都指向0x0地址，在0x0地址上的指令是
reset:                                 //复位启动子程序
/******** 设置CPU为SVC32模式***********/
 mrs r0,cpsr                       //将CPSR状态寄存器读取，保存到R0中
 bic r0,r0,#0x1f
 orr r0,r0,#0xd3                //CPSR中后5位为10011则表示进入到SVC管理模式
 msr cpsr,r0  
                     //将R0写入状态寄存器中
/************** 关闭看门狗 ******************/
 ldr      r0, =pWTCON //0x0写到0x53000000地址上，其实该地址是看门狗的控制寄存器，该指令就是关闭看门狗。
 mov     r1, #0x0
 str       r1, [r0]

/************** 关闭所有中断 *****************/
 mov r1, #0xffffffff
 ldr r0, =INTMSK //将0xffffffff写到INTMSK代表的地址上，屏蔽中断
 str r1, [r0]
 ldr r2, =0x7ff
 ldr r0, =INTSUBMSK //对于2410还要设置此寄存器
 str r2, [r0]

/************** 初始化系统时钟 *****************/
 ldr r0, =LOCKTIME
 ldr     r1, =0xffffff
 str     r1, [r0]

clear_bss:
        ldr       r0, _bss_start           //找到bss的起始地址
        add      r0, r0, #4              //从bss的第一个字开始
        ldr       r1, _bss_end           // bss末尾地址
        mov      r2, #0x00000000       //清零 

clbss_l:str        r2, [r0]                // bss段空间地址清零循环
        add     r0, r0, #4
        cmp     r0, r1
        bne      clbss_l

/***************** 关键的初始化子程序 ************************/
/ * cpu初始化关键寄存器
 * 设置重要寄存器
 * 设置内存时钟
* /
cpu_init_crit:
 /** flush v4 I/D caches*/
 mov r0, #0
 mcr p15, 0, r0, c7, c7, 0 /* flush v3/v4 cache */
 mcr p15, 0, r0, c8, c7, 0 /* flush v4 TLB */

/************* disable MMU stuff and caches ****************/
 mrc p15, 0, r0, c1, c0, 0
 bic r0, r0, #0x00002300 @ clear bits 13, 9:8 (--V- --RS)
 bic r0, r0, #0x00000087 @ clear bits 7, 2:0 (B--- -CAM)
 orr r0, r0, #0x00000002 @ set bit 2 (A) Align
 orr r0, r0, #0x00001000 @ set bit 12 (I) I-Cache
 mcr p15, 0, r0, c1, c0, 0

/******* 在重新定位前，我们要设置RAM的时间，因为内存时钟依赖开发板硬件的，你将会找到board目录底下的memsetup.S。**************/
 mov ip, lr
#ifndef CONFIG_S3C2440A_JTAG_BOOT
 bl memsetup        //调用memsetup子程序（在board/smdk2442memsetup.S）
#endif
 mov lr, ip
 mov pc, lr                        //子程序返回，lr寄存器一般用在两种情况下，一种是在调用b,bl指令转去执行子程序，则要将当前指令地址保存，执行完后恢复，另一个则是中断
 
memsetup:  
/**************** 初始化内存 **************/
        mov     r1, #MEM_CTL_BASE
        adrl    r2, mem_cfg_val
        add     r3, r1, #52
1:       ldr     r4, [r2], #4
        str     r4, [r1], #4
        cmp     r1, r3
        bne     1b

/*********** 跳转到原来进来的下一个指令（start.S文件里） ***************/ 
mov     pc, lr                 //子程序返回

/****************** 建立堆栈 *******************/
 ldr r0, _armboot_end               //armboot_end重定位
 add r0, r0, #CONFIG_STACKSIZE    //向下配置堆栈空间，最后我们在u-boot之后建立堆栈，为C语言的执行创建环境，否则是不允许执行C程序的，大小为128*1024
 sub sp, r0, #12                  //为abort-stack预留个3字

/**************** 跳转到C代码去 **************/
 ldr pc, _start_armboot           //跳转到start_armboot函数入口，start_armboot
字保存函数入口 指针
_start_armboot: .word start_armboot    //start_armboot函数在lib_arm/board.c中实现
从此进入第二阶段C语言代码部分