[汇编理论]80x86保护模式
一.保护方式简介
80386有三种工作方式:实模式,保护模式和虚拟8086模式。本文介绍保护方式下的80386及相关的程序设计内容。实模式下的80386寄存器，寻址方式和指令等基本概念，除特别说明外在保护方式下仍然保持。
尽管实方式下80386的功能要大大超过其先前的处理器(8086/8088,80186,80286)，但只有在保护方式下， 80386才能真正发挥更大的作用。在保护方式下，全部32条地址线有效，可寻址高达4G字节的物理地址空间;扩充的存储器分段管理机制和可选的存储器分页管理机制，不仅为存储器共享和保护提供了硬件支持，而且为实现虚拟存储器提供了硬件支持;支持多任务，能够快速地进行任务切换和保护任务环境;4个特权级和完善的特权检查机制，既能实现资源共享又能保证代码和数据的安全和保密及任务的隔离;支持虚拟8086方式，便于执行8086程序。
<一>存储管理机制
为了对存储器中的程序及数据实现保护和共享提供硬件支持，为了对实现虚拟存储器提供硬件支持，在保护方式下,80386不仅采用扩充的存储器分段管理机制，而且提供可选的存储器分页管理机制。这些存储管理机制由80386存储管理部件MMU实现。
1.目标
80386有32根地址线，在保护方式下，它们都能发挥作用，所以可寻址的物理地址空间高达4G字节。在以80386及其以上处理器为CPU的PC兼容机系统中，把地址在1M以下的内存称为常规内存，把地址在1M 以上的内存称为扩展内存。
80386还要对实现虚拟存储器提供支持。虽然与8086可寻址的1M字节物理地址空间相比，80386可寻址的物理地址空间可谓很大，但实际的微机系统不可能安装如此达的物理内存。所以，为了运行大型程序和真正实现多任务，必须采用虚拟存储器。虚拟存储器是一种软硬件结合的技术，用于提供比在计算机系统中实际可以使用的物理主存储器大得多的存储空间。这样，程序员在编写程序时不用考虑计算机中物理存储器的实际容量。
80386还要对存放在存储器中的代码及数据的共享和保护提供支持。任务甲和任务乙并存，任务甲和任务乙必须隔离，以免相互影响。但它们又可能要共享部分代码和数据。所以，80386既要支持任务隔离，又要支持可共享代码和数据的共享，还要支持特权保护。
2.地址空间和地址转换
保护方式下的虚拟存储器由大小可变的存储块构成，这样的存储块称为段。80386采用称为描述符的数据来描述段的位置、大小和使用情况。虚拟存储器的地址(逻辑地址)由指示描述符的选择子和段内偏移两部分构成，这样的地址集合称为虚拟地址空间。80386支持的虚拟地址空间可达64T字节。程序员编写程序时使用的存储地址空间是虚拟地址空间，所以，他们可认为有足够大的存储空间可供使用。
显然，只有在物理存储器中的程序才能运行，只有在物理存储器中的数据才能访问。因此，虚拟地址空间必须映射到物理地址空间，二维的虚拟地址必须转化成一维的物理地址。由于物理地址空间远小于虚拟地址空间，所以只有虚拟地址空间中的部分可以映射到物理地址空间。由于物理存储器的大小要远小于物理地址空间，所以只有上述部分中的部分才能真正映射到物理存储器。
每一个任务有一个虚拟地址空间。为了避免多个并行任务的多个虚拟地址空间直接映射到同一个物理地址空间，采用线性地址空间隔离虚拟地址空间和物理地址空间。线性地址空间由一维的线性地址构成，线性地址空间和物理地址空间对等。线性地址32位长，线性地址空间容量为4G字节。
80386分两步实现虚拟地址空间到物理地址空间到物理地址空间的映射，也就是分两步实现虚拟地址到物理地址的转换，但第二步是可选的。下图是地址映射转换的示意图。
通过描述符表和描述符，分段管理机制实现虚拟地址空间到线性地址空间的映射，实现把二维的虚拟地址转换为一维的线性地址。这一步总是存在的。
分页管理机制把线性地址空间和物理地址空间分别划分为大小相同的块，这样的块称为页。通过在线性地址空间的页与物理地址空间的页建立之间建立的映射表，分页管理机制实现线性地址空间到物理地址空间的映射，实现线性地址到物理地址的转换。分页管理机制是可选的，在不采用分页管理机制时，线性地址空间就等同于物理地址空间，线性地址就等于物理地址。
分段管理机制所使用的可变大小的块，时分段管理机制比较适宜处理复杂系统的逻辑分段。存储块的大小可以根据适当的逻辑含义进行定义，而不用考虑固定大小的页所强加的人为限制。每个段可作为独立的单位处理，以简化段的保护及共享。分页机制使用的固定大小的块最适合于管理物理存储器，无论是管理内存还是外存都同样有效。分页管理机制能够有效地支持实现虚拟存储器。
段及分页这两种机制是两种不同的转换机制，是整个地址转换函数的不同的转换级。虽然两种机制都利用存储在主存储器中的转换表，但这些表具有独立的结构。事实上，段表存储在线性地址空间，而页表存储在物理地址空间。因此，段转换表可由分页机制重新进行定位而不需段机制的参与。段转换机制把虚拟地址转换为线性地址，并在线性地址中访问段转换机制的表格，而不会觉察分页机制已把线性地址转换为物理地址。类似地，分页机制对于程序产生的地址所使用的虚拟地址空间一无所知。分页机制只是直接地把线性地址转换为物理地址，并且在物理地址中访问转换表格，并不知道虚拟地址空间的存在，甚至不知道段转换机制的存在。
3.虚拟存储器概念
虚拟存储器是一种设计技术，用于提供比在计算机系统中实际可以使用的物理主存储器大得多的存储空间。使用者会产生一种错觉，好象在程序中可以使用非常大的物理存储空间。使用虚拟存储器的好处是：一个程序可以很容易地在物理存储器容量大不一样的、配置范围很广的计算机上运行；编程人员使用虚拟存储器可以写出比任何实际配置的物理存储器都大得多的程序。虚拟存储器由存储管理机制及一个大容量的快速硬盘存储器支持。在程序运行的任何时刻，只把虚拟地址空间的一小部分映射到主存储器，其余部分则存储在磁盘上。因为只有存储在主存储器中的部分虚拟存储器可由处理器使用，这种虚拟存储技术将依赖程序内部访问存储器的局部化特性，在程序执行中只需整个虚拟存储器中的少量存储内容在主存储器中驻留。而当访问存储器的范围发生变化时，有必要把虚拟存储器的某些部分从磁盘调入主存储器，虚拟存储器的另外的部分，也能从主存储器传送回磁盘上。
地址转换机制以两种方式支持虚拟存储器。
第一，把实际驻留在主存储器中的那部分虚拟存储器标记为无效，并建立起虚拟存储器驻留部分的虚拟-- 物理映射关系，把驻留部分的相应虚拟存储器地址，转换为对应物理存储器的地址。如果程序访问的虚拟地址对应于虚拟存储器未驻留的部分，将由于无效映射信息而引起异常。操作系统通过把未驻留部分从磁盘上读入到主存储器中，来处理这种异常，并根据需要更新地址转换表。在引起异常的原因排除以后，异常处理程序完成异常事件的处理，并返回原来的程序恢复执行。在后面的文章中将会看到，从异常处理程序返回后，这时要重新执行一次原来引起异常的指令，而该指令在后一次执行时自然会成功地完成。
第二，地址转换机制通过收集驻留在主存储器中的虚拟存储器部分的使用统计信息来支持虚拟存储器，这些使用统计信息，在主存储器空间紧缺时，帮助操作系统决定可以将哪些部分传送回磁盘。
<二>保护机制
为了支持多任务，对各任务实施保护是必需的。从80286开始，处理器就具备了保护机制。保护机制能有效地实现不同任务之间的保护和同一任务内的保护。
1.不同任务之间的保护
保护的一个重要方面是应用程序之间的保护。通过把每个任务放置在不同的虚拟地址空间的方法来实现任务与任务的隔离，达到应用程序之间保护的目的。虚拟地址到物理地址的映射函数在每个任务中进行定义，随着任务切换，映射函数也切换。任务A的虚拟地址空间映射到物理地址空间的某个区域，而任务B的虚拟地址空间映射到物理地址空间的另外区域，彼此独立，互不相干。因此，两个不同的任务，尽管虚拟存储单元地址相同，但实际的物理存储单元地址可以不同。
每个任务各有一组独立的映射表，即具有不同的地址转换函数。在80386上，每个任务都有自己的段表及页表。当处理器进行切换并执行新的任务时，这种任务切换的一个重要部分，就是为新任务切换任务的转换表。为了使操作系统与所有的应用程序相隔离，可以把操作系统存储在一个单一的任务中。然而，我们即将看到，在一个任务内操作的保护机制，更适合于保护操作系统，使其不被应用程序破坏。这种机制，使操作系统由所有任务共享，并且可在每一任务中对其进行访问，而且仍然保护了操作系统，使其不被应用程序破坏。这种保护操作系统的方法，是把操作系统存储在虚拟地址空间的一个公共区域，然后，再使每一任务按此区域分配一个同样的虚拟地址空间，并进行同样的虚拟--物理地址映射。各个任务公用的这部分虚拟地址空间，被称为全局地址空间。
仅由一个任务占有的虚拟地址空间部分，即不被任何其它任务共享的虚拟地址部分，称为局部地址空间。局部地址空间包含的代码和数据，是任务私有的，需要与系统中的其它任务相隔离。
再每个任务中有不同的局部地址空间。因此，两个不同的任务中，对同一虚拟地址的访问，实际上转换为不同的物理地址。这就使操作系统对每个任务的存储器，可以赋予相同的虚拟地址，仍然保证任务的隔离。另一方面，对全局地址空间中同一虚拟地址的访问，在所有任务中都转换为同样的物理地址，从而支持公共的代码及数据的共享，例如对操作系统的共享。
2.同一任务内的保护
在一个任务之内，定义有四种执行特权级别，用于限制对任务中的段进行访问。按照包含在段中的数据的重要性和代码的可信程度，给段指定特权级别。把最高的特权级别分配给最重要的数据段和最可信任的代码段。具有最高特权级别的数据，只能由最可信任的代码访问。给不重要的数据段和一般代码段分配较低的特权级别。具有最低特权级别的数据，可被具有任何特权级别的代码访问。
特权级别用数字0、1、2和3表示，数字0表示最高特权级别，而数字3表示最低特权级别，即数字较大的级别具有较低的特权。为了避免模糊和混淆，在比较特权级别时，不使用“大于”或“小于”这样的术语，而使用“里面”或“内层”这样的术语表示较高特权级，级别的数字较小；使用“外面”或“外层”这样的术语表示较低特权级别，级别的数字较大。0级为最内层的特权级别，3级为最外层的特权级别，按这样的表示方法，四种特权级的层次关系如下图(图中右边的数字为特权级)所示。
每一特权级都有各自独立的程序堆栈，以避免与共享栈区有关的保护问题。当一个程序从一个特权级切换到另一个特权级执行时，程序使用的堆栈，从原特权级的栈段改变为新特权级的栈段。对于堆栈段寄存器 SS来说，描述符特权级(DPL)必须等于当前代码段的特权级(CPL)。从一个特权级切换到另一特权级的方法将在控制转移方法一文中描述。
每个存储器段都与一个特权级别相联系。特权级别限制是指，只有足够级别的程序，才可对相应的段进行访问。在任何时候，一个任务总是在四个特权级之一下运行，任务在特定时刻的特权级称为当前特权级 (Current Privilege level)，标记为CPL，即当前运行程序的特权级。每当一个程序试图访问一个段时，就把CPL与要访问的段的特权级进行比较，以决定是否允许这一访问。对给定CPL执行的程序，允许访问同一级别或外层级别的数据段。如上图所示，CodeK可访问同级的数据段DataK，也可访问外层的DataOS、 DataAP1及DataAP2等。如果试图访问内层级别的数据段则是非法的，并引起异常。如上图所示，CodeOS可访问同级的DataOS，也可访问外层的DataAP1和DataAP2等，但不能访问内层的DataK。
虽然应用程序都在最外层，但由于各个不同的应用程序存储在不同的虚拟地址空间中，所以各应用程序被隔离保护。如上图所示，最外层的CodeAP1只能访问DataAP1，不可能访问同级的另一应用程序的DataAP2；同样，CodeAP2只能访问DataAP2，不可能访问DataAP1。
这实际上是组合保护。应用程序1和操作系统构成任务A，应用程序2和操作系统构成任务B。操作系统被任务A和任务B共享，在任务A和任务B的两个不同的虚拟地址空间中，操作系统占用虚拟地址空间相同的部分。
特权级的典型用法是，把操作系统的核心部分放在0级，操作系统的其余部分放在1级，而应用程序放在3 级，留下的2级供中间软件使用。对特权级进行这样的安排，使得在0级的操作系统核心有权访问任务中的所有存储段；而在3级的应用程序只能访问程序本身的存储段，这些存储段也是在3级(注意，Windows 9X 操作系统只使用了0级和3级，以便于移植到精简指令集的计算机上，如RS4000等，这些处理器一般只有两个特权级，即系统级和用户级)。
二.分段管理机制
本文介绍保护方式下的段定义以及由段选择子及段内偏移构成的二维虚拟地址如何被转换为一维线性地址。
<一>段定义和虚拟地址到线性地址的转换
段是实现虚拟地址到线性地址转换机制的基础。在保护方式下，每个段由如下三个参数进行定义：段基地址(Base Address)、段界限(Limit)和段属性(Attributes)。
段基地址规定线性地址空间中段的开始地址。在80386保护方式下，段基地址长32位。因为基地址长度与寻址地址的长度相同，所以任何一个段都可以从32位线性地址空间中的任何一个字节开始，而不象实方式下规定的边界必须被16整除。
段界限规定段的大小。在80386保护模式下，段界限用20位表示，而且段界限可以是以字节为单位或以4K字节为单位。段属性中有一位对此进行定义，把该位成为粒度位，用符号G标记。G=0表示段界限以字节位位单位，于是20位的界限可表示的范围是1字节至1M字节，增量为1字节；G=1表示段界限以4K字节为单位，于是20位的界限可表示的范围是4K字节至4G字节，增量为4K字节。当段界限以4K字节为单位时，实际的段界限LIMIT可通过下面的公式从20 位段界限Limit计算出来：
LIMIT=limit*4K+0FFFH=(Limit SHL 12)+0FFFH
所以当粒度为1时，段的界限实际上就扩展成32位。由此可见，在80386保护模式下，段的长度可大大超过64K字节。
基地址和界限定义了段所映射的线性地址的范围。基地址Base是线性地址对应于段内偏移为 0的虚拟地址，段内偏移为X的虚拟地址对应Base+X的线性地址。段内从偏移0到Limit范围内的虚拟地址对应于从Base到Base+Limit范围内的线性地址。
下图表示一个段如何从虚拟地址空间定位到线性地址空间。图中BaseA等代表段基地址， LimitA等代表段界限。另外，段C接在段A之后，也即BaseC=BaseA+LimitA。
例如：设段A的基地址等于00012345H，段界限等于5678H，并且段界限以字节为单位(G=0)，那么段A对应线性地址空间中从00012345H-000179BDH的区域。如果段界限以4K字节为单位 (G=1)，那么段A对应线性地址空间中从00012345H-0568B344H(=00012345H+5678000H+0FFFH) 的区域。
通过增加段界限，可以使段的容量得到扩展。这对于那些要在内存中扩展容量的普通数据段很有效，但对堆栈段情况就不是这样。因为堆栈底在高地址端，随着压栈操作的进行，堆栈向低地址方向扩展。为了适应普通数据段和堆栈数据段在两个相反方向上的扩展，数据段的段属性中安排了一个扩展方向位，标记为ED。ED=0表示向高端扩展，ED=1表示向低端扩展。一般只有堆栈数据段才使用向低端扩展的属性(堆栈段也可使用向上扩展的段)，这是因为，向下扩展的段是为以下两个目的而设计的：
第一，堆栈段被定义为独特段，即DS和SS包含不同的选择器。
第二，一个堆栈段是靠将它复制到一个更大的段来扩充自己(而不是靠将现存的页增加到它的段上)。不打算用这种方法实现堆栈的设计者不需要定义向下扩展的段。
需要注意的是，只有数据段的段属性中才有扩展方向属性位ED，也就是说只有数据段(堆栈段作为特殊的数据段)才有向上扩展和向下扩展之分，其它段都是自然的向上扩展。
数据段的扩展方向和段界限一起决定了数据段内偏移的有效范围。当段最大为1M字节时，在向高端扩展的段内，从0到Limit的偏移是合法有效的偏移，而从Limit+1到1M-1的偏移是非法无效的偏移；在向低端扩展的段内，情形刚好相反，从0到Limit的偏移是非法无效的偏移，而从Limit+1到1M-1的偏移是合法有效的偏移，注意边界值Limit对应地址的有效性。段最大为4G时，情形类似。由此可见，如果一个段是向下扩展的，则所有的偏移必须大于限长，因为其限长是指下限，其基地址从高地址出开始。反之，若一个段是向上扩展的，则所有偏移必须小于等于限长，因为其限长是指上限，基地址从低地址处开始。通过使用段环绕，可以把向下扩展段定义到任何线性地址且可定义为任何大小。
在每次把虚拟地址转换为线性地址的过程中，要对偏移进行检查。如果偏移不在有效的范围内，那么就引起异常。
段属性规定段的主要特性。例如上面已经提到的段粒度G就是段属性的一部分。在对段进行各种访问时，将对访问是否合法进行检查，主要依据是段属性。例如：如果向一个只读段进行写入操作，那么不仅不能写入，而且会引起异常。在下面会详细说明各个段熟属性位的定义和作用。
<二>存储段描述符
用于表示上述定义段的三个参数的数据结构称为描述符。每个描述符长8个字节。在保护方式下，每一个段都有一个相应的描述符来描述。按描述符所描述的对象来划分，描述符可分为如下三类：存储段描述符、系统段描述符、门描述符(控制描述符)。下面先介绍存储段描述符。
1.存储段描述符的格式
存储段是存放可由程序直接进行访问的代码和数据的段。存储段描述符描述存储段，所以存储段描述符也被称为代码和数据段描述符。存储段描述符的格式如下表所示。表中上面一排是对描述符8个字节的使用的说明，最低地址字节(假设地址为m)在最右边，其余字节依次向左，直到最高字节(地址为m+7)。下一排是对属性域各位的说明。
| 存储段 描述符 |
m+7 | m+6 | m+5 | m+4 | m+3 | m+2 | m+1 | m+0 |
| Base(31...24) | Attributes | Segment Base(23...0) | Segment Limite(15...0) | |||||
| 存储段 描述符 属 性 |
Byte m+6 | Byte m+5 | ||||||||||||||
| BIT7 | BIT6 | BIT5 | BIT4 | BIT3 | BIT2 | BIT1 | BIT0 | BIT7 | BIT6 | BIT5 | BIT4 | BIT3 | BIT2 | BIT1 | BIT0 | |
| G | D | 0 | AVL | Limit(19...16) | P | DPL | DT1 | TYPE | ||||||||
从上表可知，长32位的段基地址(段开始地址)被安排在描述符的两个域中，其位0—位23 安排在描述符内的第2—第4字节中，其位24—位31被安排在描述符内的第7字节中。长20 位的段界限也被安排在描述符的两个域中，其位0—位15被安排在描述符内的第0—第1字节中，其位16—位19被安排在描述符内的第6字节的低4位中。
使用两个域存放段基地址和段界限的原因与80286有关。在80286保护方式下，段基地址只有24位长，而段界限只有16位长。80286存储段描述符尽管也是8字节长，但实际只使用低 6字节，高2字节必须置为0。80386存储段描述符这样的安排，可使得80286的存储段描述符的格式在80386下继续有效。
80386描述符中的段属性也被安排在两个域中。下面对其定义及意义作说明。
(1)P位称为存在(Present)位。P=1表示描述符对地址转换是有效的，或者说该描述符所描述的段存在，即在内存中；P=0表示描述符对地址转换无效，即该段不存在。使用该描述符进行内存访问时会引起异常。
(2)DPL表示描述符特权级(Descriptor Privilege level)，共2位。它规定了所描述段的特权级，用于特权检查，以决定对该段能否访问。
(3)DT位说明描述符的类型。对于存储段描述符而言，DT=1，以区别与系统段描述符和门描述符(DT=0)。
(4)TYPE说明存储段描述符所描述的存储段的具体属性。
其中的位0指示描述符是否被访问过(Accessed)，用符号A标记。A=0表示尚未被访问，A=1 表示段已被访问。当把描述符的相应选择子装入到段寄存器时，80386把该位置为1，表明描述符已被访问。操作系统可测试访问位，已确定描述符是否被访问过。
其中的位3指示所描述的段是代码段还是数据段，用符号E标记。E=0表示段为数据段，相应的描述符也就是数据段(包括堆栈段)描述符。数据段是不可执行的，但总是可读的。 E=1表示段是可执行段，即代码段，相应的描述符就是代码段描述符。代码段总是不可写的，若需要对代码段进行写入操作，则必须使用别名技术，即用一个可写的数据段描述符来描述该代码段，然后对此数据段进行写入。
在数据段描述符中(E=0的情况)，TYPE中的位1指示所描述的数据段是否可写，用W标记。 W=0表示对应的数据段不可写。反之，W=1表示数据段是可写的。注意，数据段总是可读的。TYPE中的位2是ED位，指示所描述的数据段的扩展方向。ED=0表示数据段向高端扩展，也即段内偏移必须小于等于段界限。ED=1表示数据段向低扩展，段内偏移必须大于段界限。
在代码段描述符中(E=1的情况)，TYPE中的位1指示所描述的代码段是否可读，用符号R标记。R=0表示对应的代码段不可读，只能执行。R=1表示对应的代码段可读可执行。注意代码段总是不可写的，若需要对代码段进行写入操作，则必须使用别名技术。在代码段中，TYPE中的位2指示所描述的代码段是否是一致代码段，用C标记。C=0表示对应的代码段不是一致代码段(普通代码段)，C=1表示对应的代码段是一致代码段。关于一致代码段的说明，后面的文章将会详细介绍。
存储段描述符中的TYPE字段所说明的属性可归纳为下表：
|
|
(5)G为就是段界限粒度(Granularity)位。G=0表示界限粒度为字节；G=1表示界限粒度为4K 字节。注意，界限粒度只对段界限有效，对段基地址无效，段基地址总是以字节为单位。
(6)D位是一个很特殊的位，在描述可执行段、向下扩展数据段或由SS寄存器寻址的段(通常是堆栈段)的三种描述符中的意义各不相同。
在描述可执行段的描述符中，D位决定了指令使用的地址及操作数所默认的大小。D=1表示默认情况下指令使用32位地址及32位或8位操作数，这样的代码段也称为32位代码段；D=0 表示默认情况下，使用16位地址及16位或8位操作数，这样的代码段也称为16位代码段，它与80286兼容。可以使用地址大小前缀和操作数大小前缀分别改变默认的地址或操作数的大小。
在向下扩展数据段的描述符中，D位决定段的上部边界。D=1表示段的上部界限为4G；D=0表示段的上部界限为64K，这是为了与80286兼容。
在描述由SS寄存器寻址的段描述符中，D位决定隐式的堆栈访问指令(如PUSH和POP指令)使用何种堆栈指针寄存器。D=1表示使用32位堆栈指针寄存器ESP；D=0表示使用16位堆栈指针寄存器SP，这与80286兼容。
(7)AVL位是软件可利用位。80386对该位的使用未左规定，Intel公司也保证今后开发生产的处理器只要与80386兼容，就不会对该位的使用做任何定义或规定。
此外，描述符内第6字节中的位5必须置为0，可以理解成是为以后的处理器保留的。
2.存储段描述符的结构类型表示
根据存储段描述符的结构，可定义如下的汇编语言描述符结构类型：
DESC STRUC LIMITL DW 0 ;段界限低16位 BASEL DW 0 ;基地址低16位 BASEM DB 0 ;基地址中间8位 ATTRIB DB 0 ;段属性 LIMITH DB 0 ;段界限的高4位(包括段属性的高4位) BASEH DB 0 ;基地址的高8位 DESC ENDS
利用结构类型DESC能方便地在程序中说明存储段描述符。例如：下面的描述符DATAS描述一个可读写的有效(存在的)数据段，基地址是100000H，以字节为单位的界限是0FFFFH，描述符特权级DPL=3。
DATAS DESC <0FFFFH,,10H,0F2H,,>
再如：下述描述符CODEA描述一个只可执行的有效的32位代码段，基地址是12345678H，以 4K字节位单位的段界限值是10H(以字节位单位的界限是10FFFH)，描述符特权级DPL=0。
CODEA DESC <10H,5678H,34H,98H,0C0H,12H>
<三>全局和局部描述符表
一个任务会涉及多个段，每个任务需要一个描述符来描述，为了便于组织管理，80386把描述符组织成线性表。由描述符组成的线性表称为描述符表。在80386中有三种类型的描述符表：全局描述符表GDT(Global Descriptor Table)、局部描述符表LDT(Local Descriptor Table)和中断描述符表IDT(Interrupt Descriptor Table)。在整个系统中，全局描述符表GDT和中断描述符表IDT只有一张，局部描述符表可以有若干张，每个任务可以有一张。
例如，下列描述符表有6个描述符构成：
DESCTAB LABEL BYTE DESC1 DESC <1234H,5678H,34H,92H,,> DESC1 DESC <1234H,5678H,34H,93H,,> DESC1 DESC <5678H,1234H,56H,98H,,> DESC1 DESC <5678H,1234H,56H,99H,,> DESC1 DESC <0FFFFH,,10H,16H,,> DESC1 DESC <0FFFFH,,10H,90H,,>
每个描述符表本身形成一个特殊的数据段。这样的特殊数据段最多可包含有8K(8192)个描述符.
关于中断描述符表IDT在以后的文章中介绍。
每个任务的局部描述符表LDT含有该任务自己的代码段、数据段和堆栈段的描述符，也包含该任务所使用的一些门描述符，如任务门和调用门描述符等。随着任务的切换，系统当前的局部描述符表LDT也随之切换。
全局描述符表GDT含有每一个任务都可能或可以访问的段的描述符，通常包含描述操作系统所使用的代码段、数据段和堆栈段的描述符，也包含多种特殊数据段描述符，如各个用于描述任务LDT的特殊数据段等。在任务切换时，并不切换GDT。
通过LDT可以使各个任务私有的各个段与其它任务相隔离，从而达到受保护的目的。通过GDT可以使各任务都需要使用的段能够被共享。下图给出了任务A和任务B所涉及的有关段既隔离受保护，又合用共享的情况。通过任务A的局部描述符表LDTA和任务B的局部描述符表LDTB，把任务A所私有的代码段CodeA及数据段DataA与任务B所私有的代码段CodeB和数据段DataB及DataB2隔离，但任务A和任务B通过全局描述符表GDT共享代码段CodeK及CodeOS和数据段DataK及DataOS。
一个任务可使用的整个虚拟地址空间分为相等的两半，一半空间的描述符在全局描述符表中，另一半空间的描述符在局部描述符表中。由于全局和局部描述符表都可以包含多达8192个描述符，而每个描述符所描述的段的最大值可达4G字节，因此最大的虚拟地址空间可为：
4GB*8192*2=64MMB=64TB
<四>段选择子
在实模式下，逻辑地址空间中存储单元的地址由段值和段内偏移两部分组成。在保护方式下，虚拟地址空间(相当于逻辑地址空间)中存储单元的地址由段选择子和段内偏移两部分组成。与实模式相比，段选择子代替了段值。
段选择子长16位，其格式如下表所示。从表中可见，段选择子的高13位是描述符索引(Index)。所谓描述符索引是指描述符在描述符表中的序号。段选择子的第2位是引用描述符表指示位，标记为TI(Table Indicator)，TI=0指示从全局描述符表GDT中读取描述符；TI=1指示从局部描述符表LDT中读取描述符。
| 选择子 结 构 |
BIT15 | BIT14 | BIT13 | BIT12 | BIT11 | BIT10 | BIT9 | BIT8 | BIT7 | BIT6 | BIT5 | BIT4 | BIT3 | BIT2 | BIT1 | BIT0 |
| 描述符索引 | TI | RPL | ||||||||||||||
选择子确定描述符，描述符确定段基地址，段基地址与偏移之和就是线性地址。所以，虚拟地址空间中的由选择子和偏移两部分构成的二维虚拟地址，就是这样确定了线性地址空间中的一维线性地址。
选择子的最低两位是请求特权级RPL(Requested Privilege Level)，用于特权检查。 RPL字段的用法如下：
每当程序试图访问一个段时，要把当前特权级与所访问段的特权级进行比较，以确定是否允许程序对该段的访问。使用选择子的RPL字段，将改变特权级的测试规则。在这种情况下，与所访问段的特权级比较的特权级不是CPL，而是CPU与RPL中更外层的特权级。 CPL存放在CS寄存器的RPL字段内，每当一个代码段选择子装入CS寄存器中时，处理器自动地把CPL存放到CS的RPL字段。
由于选择子中的描述符索引字段用13位表示，所以可区分8192个描述符。这也就是描述符表最多包含8192个描述符的原因。由于每个描述符长8字节，根据上表所示选择子的格式，屏蔽选择子低3位后所得的值就是选择子所指定的描述符在描述符表中的偏移，这可认为是安排选择子高13位作为描述符索引的原因。
有一个特殊的选择子称为空(Null)选择子，它的Index=0，TI=0，而RPL字段可以为任意值。空选择子有特定的用途，当用空选择子进行存储访问时会引起异常。空选择子是特别定义的，它不对应于全局描述符表GDT中的第0个描述符，因此处理器中的第0个描述符总不被处理器访问，一般把它置成全0。但当TI=1时，Index为0的选择子不是空选择子，它指定了当前任务局部描述符表LDT中的第0个描述符。
<五>段描述符高速缓冲寄存器
在实模式下，段寄存器含有段值，为访问存储器形成物理地址时，处理器引用相应的某个段寄存器并将其值乘以16，形成20位的段基地址。在保护模式下，段寄存器含有段选择子，如上所述，为了访问存储器形成线性地址时，处理器要使用选择子所指定的描述符中的基地址等信息。为了避免在每次存储器访问时，都要访问描述符表而获得对应的段描述符，从80286开始每个段寄存器都配有一个高速缓冲寄存器，称之为段描述符高速缓冲寄存器或描述符投影寄存器，对程序员而言它是不可见的。每当把一个选择子装入到某个段寄存器时，处理器自动从描述符表中取出相应的描述符，把描述符中的信息保存到对应的高速缓冲寄存器中。此后对该段访问时，处理器都使用对应高速缓冲寄存器中的描述符信息，而不用再从描述符表中取描述符。
各段描述符高速缓冲寄存器之内容如下表所示。其中，32位段基地址直接取自描述符， 32位的段界限取自描述符中20位的段界限，并根据描述符属性中的粒度位转换成以字节为单位。其它十个特性根据描述符中的属性而定，“Y”表示“是”，“N”表示“否” ，“R”表示必须可读，“W”表示必须可写，“P”表示必须存在，“D”表示根据描述符中属性而定。
| 段描 述符 高速 缓冲 寄存 器的 内容 |
段寄存器 | 段基地址 | 段界限 | 段属性 | |||||||||
| 存在性 | 特权级 | 已存取 | 粒度 | 扩展方向 | 可读性 | 可写性 | 可执行 | 堆栈大小 | 一致特权 | ||||
| CS | 32位基地址 | 32位段界限 | P | D | D | D | D | D | N | Y | - | D | |
| SS | 32位基地址 | 32位段界限 | P | D | D | D | D | R | W | N | D | - | |
| DS | 32位基地址 | 32位段界限 | P | D | D | D | D | D | D | N | - | - | |
| ES | 32位基地址 | 32位段界限 | P | D | D | D | D | D | D | N | - | - | |
| FS | 32位基地址 | 32位段界限 | P | D | D | D | D | D | D | N | - | - | |
| GS | 32位基地址 | 32位段界限 | P | D | D | D | D | D | D | N | - | - | |
段描述符高速缓冲寄存器再处理器内，所以可对其进行快速访问。绝大多数情况下，对存储器的访问是在对应选择子装入到段寄存器之后进行的，所以，使用段描述符高速缓冲寄存器可以得到很好的执行性能。
段描述符高速缓冲寄存器之内保存的描述符信息将一直保存到重新把选择子装载到段寄存器时再更新。程序员尽管不可见段描述符高速缓冲寄存器，但必须注意到它的存在和它的上述更新时机。例如，在改变了描述符表中的某个当前段的描述符后，也要更新对应的段描述符高速缓冲寄存器的内容，即使段选择子未作改变，这可通过重新装载段寄存器实现。
二.控制寄存器和系统地址寄存器
80386控制寄存器和系统地址寄存器如下表所示。它们用于控制工作方式，控制分段管理机制及分页管理机制的实施。
| 控 制 寄存器 |
CRx | BIT31 | BIT30—BIT12 | BIT11—BIT5 | BIT4 | BIT3 | BIT2 | BIT1 | BIT0 |
| CR0 | PG | 0000000000000000 | ET | TS | EM | MP | PE | ||
| CR1 | 保留 | ||||||||
| CR2 | 页故障线性地址 | ||||||||
| CR3 | 页目录表物理页码 | 000000000000 | |||||||
| BIT47—BIT16 | BIT15—BIT0 | |
| 全局描述符表寄存器GDTR | 基地址 | 界限 |
| 中断描述符表寄存器IDTR | 基地址 | 界限 |
|
|
<一>控制寄存器
从上表可见，80386有四个32位的控制寄存器，分别命名位CR0、CR1、CR2和CR3。但CR1被保留，供今后开发的处理器使用，在80386中不能使用CR1，否则会引起无效指令操作异常。CR0包括指示处理器工作方式的控制位，包含启用和禁止分页管理机制的控制位，包含控制浮点协处理器操作的控制位。CR2及CR3由分页管理机制使用。CR0中的位5—位30及CR3中的位0至位11是保留位，这些位不能是随意值，必须为0。
控制寄存器CR0的低16位等同于80286的机器状态字MSW。
1.保护控制位
控制寄存器CR0中的位0用PE标记，位31用PG标记，这两个位控制分段和分页管理机制的操作，所以把它们称为保护控制位。PE控制分段管理机制。PE=0，处理器运行于实模式；PE=1，处理器运行于保护方式。PG控制分页管理机制。PG=0，禁用分页管理机制，此时分段管理机制产生的线性地址直接作为物理地址使用；PG=1，启用分页管理机制，此时线性地址经分页管理机制转换位物理地址。关于分页管理机制的具体介绍在后面的文章中进行。
下表列出了通过使用PE和PG位选择的处理器工作方式。由于只有在保护方式下才可启用分页机制，所以尽管两个位分别为0和1共可以有四种组合，但只有三种组合方式有效。PE=0且PG=1是无效组合，因此，用PG为1且PE为0的值装入CR0寄存器将引起通用保护异常。
需要注意的是，PG位的改变将使系统启用或禁用分页机制，因而只有当所执行的程序的代码和至少有一部分数据在线性地址空间和物理地址空间具有相同的地址的情况下，才能改变PG位。
| PG和PE 位与处 理器工 作模式 |
PG | PE | 处理器工作方式 |
| 0 | 0 | 实模式 | |
| 0 | 1 | 保护模式，禁用分页机制 | |
| 1 | 0 | 非法组合 | |
| 1 | 1 | 保护方式，启用分页机制 |
2.协处理器控制位
控制寄存器CR0中的位1—位4分别标记为MP(算术存在位)、EM(模拟位)、TS(任务切换位) 和ET(扩展类型位)，它们控制浮点协处理器的操作。
当处理器复位时，ET位被初始化，以指示系统中数字协处理器的类型。如果系统中存在 80387协处理器，那么ET位置1；如果系统中存在80287协处理器或者不存在协处理器，那么ET位清0。
EM位控制浮点指令的执行是用软件模拟，还是由硬件执行。EM=0时，硬件控制浮点指令传送到协处理器；EM=1时，浮点指令由软件模拟。
TS位用于加快任务的切换，通过在必要时才进行协处理器切换的方法实现这一目的。每当进行任务切换时，处理器把TS置1。TS=1时，浮点指令将产生设备不可用(DNA)异常。 MP位控制WAIT指令在TS=1时，是否产生DNA异常。MP=1和TS=1时，WAIT产生异常；MP=0时，WAIT指令忽略TS条件，不产生异常。
3.CR2和CR3
控制寄存器CR2和CR3由分页管理机制使用。
CR2用于发生页异常时报告出错信息。当发生页异常时，处理器把引起页异常的线性地址保存在CR2中。操作系统中的页异常处理程序可以检查CR2的内容，从而查出线性地址空间中的哪一页引起本次异常。
CR3用于保存页目录表的其始物理地址。由于目录是页对齐的，所以仅高20位有效，低12 位保留未用。向CR3中装入一个新值时，低12位必须为0；但从CR3中取值时，低12位被忽略。每当用MOV指令重置CR3的值时，会导致分页机制高速缓冲区的内容无效，用此方法，可以在启用分页机制之前，即把PG位置1之前，预先刷新分页机制的高速缓存。CR3寄存器即使在CR0寄存器的PG位或PE位为0时也可装入，如在实模式下也可设置CR3，以便进行分页机制的初始化。在任务切换时，CR3要被改变，但是如果新任务中CR3的值与原任务中CR3的值相同，那么处理器不刷新分页高速缓存，以便当任务共享也表时有较快的执行速度。
<二>系统地址寄存器
全局描述符表GDT、局部描述符表LDT和中断描述符表IDT等都是保护方式下非常重要的特殊段，它们包含有为段机制所用的重要表格。为了方便快速地定位这些段，处理器采用一些特殊的寄存器保存这些段的基地址和段界限。我们把这些特殊的寄存器称为系统地址寄存器。
1.全局描述符表寄存器GDTR
如本文开始处的表格所示，GDTR长48位，其中高32位为基地址，低16位为界限。由于GDT 不能有GDT本身之内的描述符进行描述定义，所以处理器采用GDTR为GDT这一特殊的系统段提供一个伪描述符。GDTR给定了GDT，如下图所示。
GDTR中的段界限以字节为单位。由于段选择子中只有13位作为描述符索引，而每个描述符长8个字节，所以用16位的界限足够。通常，对于含有N个描述符的描述符表的段界限设为8*N-1。
利用结构类型可定义伪描述符如下：
PDESC STRUC
LIMIT DW 0
BASE DD 0
PDESC ENDS
2.局部描述符表寄存器LDTR
局部描述符表寄存器LDTR规定当前任务使用的局部描述符表LDT。如本文开始处的表格所示，LDTR类似于段寄存器，由程序员可见的16位的寄存器和程序员不可见的高速缓冲寄存器组成。实际上，每个任务的局部描述符表LDT作为系统的一个特殊段，由一个描述符描述。而用于描述符LDT的描述符存放在GDT中。在初始化或任务切换过程中，把描述符对应任务LDT的描述符的选择子装入LDTR，处理器根据装入LDTR可见部分的选择子，从GDT中取出对应的描述符，并把LDT的基地址、界限和属性等信息保存到LDTR的不可见的高速缓冲寄存器中。随后对LDT的访问，就可根据保存在高速缓冲寄存器中的有关信息进行合法性检查。
LDTR寄存器包含当前任务的LDT的选择子。所以，装入到LDTR的选择子必须确定一个位于GDT中的类型为LDT的系统段描述符，也即选择子中的TI位必须是0，而且描述符中的类型字段所表示的类型必须为LDT。
可以用一个空选择子装入LDTR，这表示当前任务没有LDT。在这种情况下，所有装入到段寄存器的选择子都必须指示GDT中的描述符，也即当前任务涉及的段均由GDT中的描述符来描述。如果再把一个TI位为1的选择子装入到段寄存器，将引起异常。
3.中断描述符表寄存器IDTR
中断描述符表寄存器IDTR指向中断描述符表IDT。如本文开始处的表格所示，IDTR长48 位，其中32位的基地址规定IDT的基地址，16位的界限规定IDT的段界限。由于80386只支持256个中断/异常，所以IDT表最大长度是2K，以字节位单位的段界限为7FFH。IDTR 指示IDT的方式与GDTR指示GDT的方式相同。
4.任务状态段寄存器TR
任务状态段寄存器TR包含指示描述当前任务的任务状态段的描述符选择子，从而规定了当前任务的状态段。任务状态段的格式在后面的文章中介绍。如本文开始处的表格所示，TR也有程序员可见和不可见两部分。当把任务状态段的选择子装入到TR可见部分时，处理器自动把选择子所索引的描述符中的段基地址等信息保存到不可见的高速缓冲寄存器中。在此之后，对当前任务状态段的访问可快速方便地进行。装入到TR的选择子不能为空，必须索引位于GDT中的描述符，且描述符的类型必须是TSS。
四.实模式与保护模式切换实例
本文介绍两个实现实模式与保护模式切换的实例，通过他们说明如何实现实模式与保护模式的切换， 也说明保护模式下的80386及其编程。
<一>演示实模式和保护模式切换的实例(实例一)
实例一的逻辑功能是，以十六进制数的形式显示从内存地址110000H开始的256个字节的值。本实例指定该内存区域的目的仅仅是想说明切换到保护模式的必要性，因为在实模式下不能访问该指定内存区域，只有在保护模式下才能访问到该指定区域。
本实例的具体实现步骤是：(1)作切换到保护方式的准备；(2)切换到保护方式；(3)把指定内存区域的内容传送到位于常规内存的缓冲区中；(4)切换回实模式；(5)显示缓冲区内容。
1.包含文件
386保护模式汇编语言程序用到的包含文件如下所示，该包含文件在后面的程序中还要用到。
;名称:386SCD.INC
;功能:符号常量等的定义
;----------------------------------------------------------------------------
;IFNDEF __386SCD_INC
;__386SCD_INC EQU 1
;----------------------------------------------------------------------------
.386P
;----------------------------------------------------------------------------
;打开A20地址线
;----------------------------------------------------------------------------
EnableA20 MACRO
push ax
in al,92h
or al,00000010b
out 92h,al
pop ax
ENDM
;----------------------------------------------------------------------------
;关闭A20地址线
;----------------------------------------------------------------------------
DisableA20 MACRO
push ax
in al,92h
and al,11111101b
out 92h,al
pop ax
ENDM
;----------------------------------------------------------------------------
;16位偏移的段间直接转移指令的宏定义(在16位代码段中使用)
;----------------------------------------------------------------------------
JUMP16 MACRO Selector,Offset
DB 0eah ;操作码
DW Offset ;16位偏移量
DW Selector ;段值或段选择子
ENDM
;----------------------------------------------------------------------------
;32位偏移的段间直接转移指令的宏定义(在32位代码段中使用)
;----------------------------------------------------------------------------
COMMENT <JUMP32>
JUMP32 MACRO Selector,Offset
DB 0eah ;操作码
DD OFFSET
DW Selector ;段值或段选择子
ENDM
<JUMP32>
;-------------------------------------------------
JUMP32 MACRO Selector,Offset
DB 0eah ;操作码
DW OFFSET
DW 0
DW Selector ;段值或段选择子
ENDM
;----------------------------------------------------------------------------
;16位偏移的段间调用指令的宏定义(在16位代码段中使用)
;----------------------------------------------------------------------------
CALL16 MACRO Selector,Offset
DB 9ah ;操作码
DW Offset ;16位偏移量
DW Selector ;段值或段选择子
ENDM
;----------------------------------------------------------------------------
;32位偏移的段间调用指令的宏定义(在32位代码段中使用)
;----------------------------------------------------------------------------
COMMENT <CALL32>
CALL32 MACRO Selector,Offset
DB 9ah ;操作码
DD Offset
DW Selector ;段值或段选择子
ENDM
<CALL32>
;-------------------------------------------------
CALL32 MACRO Selector,Offset
DB 9ah ;操作码
DW Offset
DW 0
DW Selector ;段值或段选择子
ENDM
;----------------------------------------------------------------------------
;存储段描述符结构类型定义
;----------------------------------------------------------------------------
Desc STRUC
LimitL DW 0 ;段界限(BIT0-15)
BaseL DW 0 ;段基地址(BIT0-15)
BaseM DB 0 ;段基地址(BIT16-23)
Attributes DB 0 ;段属性
LimitH DB 0 ;段界限(BIT16-19)(含段属性的高4位)
BaseH DB 0 ;段基地址(BIT24-31)
Desc ENDS
;----------------------------------------------------------------------------
;门描述符结构类型定义
;----------------------------------------------------------------------------
Gate STRUC
OffsetL DW 0 ;32位偏移的低16位
Selector DW 0 ;选择子
DCount DB 0 ;双字计数
GType DB 0 ;类型
OffsetH DW 0 ;32位偏移的高16位
Gate ENDS
;----------------------------------------------------------------------------
;伪描述符结构类型定义(用于装入全局或中断描述符表寄存器)
;----------------------------------------------------------------------------
PDesc STRUC
Limit DW 0 ;16位界限
Base DD 0 ;32位基地址
PDesc ENDS
;----------------------------------------------------------------------------
;任务状态段结构类型定义
;----------------------------------------------------------------------------
TSS STRUC
TRLink DW 0 ;链接字段
DW 0 ;不使用,置为0
TRESP0 DD 0 ;0级堆栈指针
TRSS0 DW 0 ;0级堆栈段寄存器
DW 0 ;不使用,置为0
TRESP1 DD 0 ;1级堆栈指针
TRSS1 DW 0 ;1级堆栈段寄存器
DW 0 ;不使用,置为0
TRESP2 DD 0 ;2级堆栈指针
TRSS2 DW 0 ;2级堆栈段寄存器
DW 0 ;不使用,置为0
TRCR3 DD 0 ;CR3
TREIP DD 0 ;EIP
TREFlag DD 0 ;EFLAGS
TREAX DD 0 ;EAX
TRECX DD 0 ;ECX
TREDX DD 0 ;EDX
TREBX DD 0 ;EBX
TRESP DD 0 ;ESP
TREBP DD 0 ;EBP
TRESI DD 0 ;ESI
TREDI DD 0 ;EDI
TRES DW 0 ;ES
DW 0 ;不使用,置为0
TRCS DW 0 ;CS
DW 0 ;不使用,置为0
TRSS DW 0 ;SS
DW 0 ;不使用,置为0
TRDS DW 0 ;DS
DW 0 ;不使用,置为0
TRFS DW 0 ;FS
DW 0 ;不使用,置为0
TRGS DW 0 ;GS
DW 0 ;不使用,置为0
TRLDTR DW 0 ;LDTR
DW 0 ;不使用,置为0
TRTrip DW 0 ;调试陷阱标志(只用位0)
TRIOMap DW ___FCKpd___52 ;指向I/O许可位图区的段内偏移
TSS ENDS
;----------------------------------------------------------------------------
;存储段描述符类型值说明
;----------------------------------------------------------------------------
ATDR EQU 90h ;存在的只读数据段类型值
ATDW EQU 92h ;存在的可读写数据段属性值
ATDWA EQU 93h ;存在的已访问可读写数据段类型值
ATCE EQU 98h ;存在的只执行代码段属性值
ATCER EQU 9ah ;存在的可执行可读代码段属性值
ATCCO EQU 9ch ;存在的只执行一致代码段属性值
ATCCOR EQU 9eh ;存在的可执行可读一致代码段属性值
;----------------------------------------------------------------------------
;系统段描述符类型值说明
;----------------------------------------------------------------------------
ATLDT EQU 82h ;局部描述符表段类型值
ATTaskGate EQU 85h ;任务门类型值
AT386TSS EQU 89h ;可用386任务状态段类型值
AT386CGate EQU 8ch ;386调用门类型值
AT386IGate EQU 8eh ;386中断门类型值
AT386TGate EQU 8fh ;386陷阱门类型值
;----------------------------------------------------------------------------
;DPL值说明
;----------------------------------------------------------------------------
DPL0 EQU 00h ;DPL=0
DPL1 EQU 20h ;DPL=1
DPL2 EQU 40h ;DPL=2
DPL3 EQU 60h ;DPL=3
;----------------------------------------------------------------------------
;RPL值说明
;----------------------------------------------------------------------------
RPL0 EQU 00h ;RPL=0
RPL1 EQU 01h ;RPL=1
RPL2 EQU 02h ;RPL=2
RPL3 EQU 03h ;RPL=3
;----------------------------------------------------------------------------
;IOPL值说明
;----------------------------------------------------------------------------
IOPL0 EQU 0000h ;IOPL=0
IOPL1 EQU 1000h ;IOPL=1
IOPL2 EQU 2000h ;IOPL=2
IOPL3 EQU 3000h ;IOPL=3
;----------------------------------------------------------------------------
;其它常量值说明
;----------------------------------------------------------------------------
D32 EQU 40h ;32位代码段标志
GL EQU 80h ;段界限以4K为单位标志
TIL EQU 04h ;TI=1(局部描述符表标志)
VMFL EQU 00020000h ;VMF=1
VMFLW EQU 0002h
IFL EQU 00000200h ;IF=1
RFL EQU 00010000h ;RF=1(重启动标志,为1表示忽略调试故障)
RFLW EQU 0001h
NTL EQU 00004000h ;NT=1
;----------------------------------------------------------------------------
;分页机制使用的常量说明
;----------------------------------------------------------------------------
PL EQU 1 ;页存在属性位
RWR EQU 0 ;R/W属性位值,读/执行
RWW EQU 2 ;R/W属性位值,读/写/执行
USS EQU 0 ;U/S属性位值,系统级
USU EQU 4 ;U/S属性位值,用户级
;----------------------------------------------------------------------------
;ENDIF
2.实例源程序
实例一的源程序如下所示：
;名称:ASM1.ASM
;功能:演示实方式和保护方式切换(切换到16位代码段)
;----------------------------------------------------------------------------
INCLUDE 386SCD.INC
;----------------------------------------------------------------------------
;字符显示宏指令的定义
;----------------------------------------------------------------------------
EchoCh MACRO ascii
mov ah,2
mov dl,ascii
int 21h
ENDM
;----------------------------------------------------------------------------
DSEG SEGMENT USE16 ;16位数据段
;----------------------------------------------------------------------------
GDT LABEL BYTE ;全局描述符表
DUMMY Desc <> ;空描述符
Code Desc <0ffffh,,,ATCE,,> ;代码段描述符
DataS Desc <0ffffh,0,11h,ATDW,,> ;源数据段描述符
DataD Desc <0ffffh,,,ATDW,,> ;目标数据段描述符
;----------------------------------------------------------------------------
GDTLen = $-GDT ;全局描述符表长度
VGDTR PDesc <GDTLen-1,> ;伪描述符
;----------------------------------------------------------------------------
Code_Sel = Code-GDT ;代码段选择子
DataS_Sel = Datas-GDT ;源数据段选择子
DataD_Sel = DataD-GDT ;目标数据段选择子
;----------------------------------------------------------------------------
BufLen = 256 ;缓冲区字节长度
Buffer DB BufLen DUP(0) ;缓冲区
;----------------------------------------------------------------------------
DSEG ENDS ;数据段定义结束
;----------------------------------------------------------------------------
CSEG SEGMENT USE16 ;16位代码段
ASSUME CS:CSEG,DS:DSEG
;----------------------------------------------------------------------------
Start PROC
mov ax,DSEG
mov ds,ax
;准备要加载到GDTR的伪描述符
mov bx,16
mul bx
add ax,OFFSET GDT ;计算并设置基地址
adc dx,0 ;界限已在定义时设置好
mov WORD PTR VGDTR.Base,ax
mov WORD PTR VGDTR.Base+2,dx
;设置代码段描述符
mov ax,cs
mul bx
mov WORD PTR Code.BaseL,ax ;代码段开始偏移为0
mov BYTE PTR Code.BaseM,dl ;代码段界限已在定义时设置好
mov BYTE PTR Code.BaseH,dh
;设置目标数据段描述符
mov ax,ds
mul bx ;计算并设置目标数据段基址
add ax,OFFSET Buffer
adc dx,0
mov WORD PTR DataD.BaseL,ax
mov BYTE PTR DataD.BaseM,dl
mov BYTE PTR DataD.BaseH,dh
;加载GDTR
lgdt QWORD PTR VGDTR
cli ;关中断
EnableA20 ;打开地址线A20
;切换到保护方式
mov eax,cr0
or eax,1
mov cr0,eax
;清指令预取队列,并真正进入保护方式
JUMP16 Code_Sel,<OFFSET Virtual>
Virtual: ;现在开始在保护方式下运行
mov ax,DataS_Sel
mov ds,ax ;加载源数据段描述符
mov ax,DataD_Sel
mov es,ax ;加载目标数据段描述符
cld
xor si,si
xor di,di ;设置指针初值
mov cx,BufLen/4 ;设置4字节为单位的缓冲区长度
repz movsd ;传送
;切换回实模式
mov eax,cr0
and al,11111110b
mov cr0,eax
;清指令预取队列,进入实方式
JUMP16 <SEG Real>,<OFFSET Real>
Real: ;现在又回到实方式
DisableA20
sti
mov ax,DSEG
mov ds,ax
mov si,OFFSET Buffer
cld
mov bp,BufLen/16
NextLine: mov cx,16
NextCh: lodsb
push ax
shr al,1
call ToASCII
EchoCh al
pop ax
call ToASCII
EchoCh al
EchoCh ' '
loop NextCh
EchoCh 0dh
EchoCh 0ah
dec bp
jnz NextLine
mov ax,4c00h
int 21h
Start ENDP
;----------------------------------------------------------------------------
ToASCII PROC
and al,0fh
add al,90h
daa
adc al,40h
daa
ret
ToASCII ENDP
;----------------------------------------------------------------------------
CSEG ENDS ;代码段定义结束
;----------------------------------------------------------------------------
END Start
3.关于实例步骤的注释
在源程序的开头首先包含了文件“386SCD.INC”，在此包含文件中定义了保护模式程序设计要用到的一些结构、宏及常量。下面对各实现步骤作些说明。
(1)切换到保护方式的准备工作
在从实模式切换到保护模式之前，必须作必要的准备。准备工作的内容根据实际而定。最起码的准备工作是建立合适的全局描述符表，并使用GDTR指向该GDT。因为在切换到保护方式时，至少要把代码段的选择子装载到CS，所以GDT中至少含有代码段的描述符。
从本实例源程序可见，全局描述符表GDT仅有四个描述符：第一个是空描述符；第二个是代码段描述符；第三个和第四个分别为源数据段及目标数据段描述符。本实例各描述符中的段界限是在定义时设置的，并且除伪描述符VGDTR中的界限按GDT的实际长度设置外，各使用的存储段描述符的界限都规定为0FFFFH。另外，描述符中的段属性也根据所描述段的类型被预置，各属性的定义在包含文件386SCD.INC中均有说明。从属性值可知，这三个段都是16位段。
由于在切换到保护方式后就要引用GDT，所以在切换到保护方式前必须装载GDTR。实例中使用如下指令装载GDTR：
LGDT QWORD PTR VGDTR
该指令的功能是把存储器中的伪描述符VGDTR装入到全局描述符表寄存器GDTR中。伪描述符VGDTR的结构如前所述结构类型PDESC所示，低字是以字节位单位的全局描述符表段的界限，高双字为描述符表段的线性基地址(本实例不启用分页机制，所以线性地址等同于物理地址)。本实例中未涉及到局部描述符表及中断描述符表，后面的文章将作详细说明。
(2)由实模式切换到保护模式
在做好准备后，从实模式切换到保护模式并不难。原则上只要把控制寄存器CR0中的PE位置1即可。本实例采用如下三条指令设置PE位：
mov eax,cr0
or eax,1
mov cr0,eax
实际情况要比这复杂些。执行上面的三条指令后，处理器转入保护模式，但CS中的内容还是实模式下代码段的段值，而不是保护模式下代码段的选择子，所以在取指令之前得把代码段的选择子装入CS。为此，紧接着这三条指令，安排一条如下所示的段间转移指令：
JUMP16 Code_Sel,<OFFSET Virtual>
这条段间转移指令 在实模式下被预取并在保护方式下被执行。利用这条段间转移指令可把保护模式下代码段的选择子装入CS，同时也刷新指令预取队列。从此真正进入保护模式。
(3)由保护模式切换到实模式
在80386上，从保护模式切换到实模式的过程类似于从实模式切换到保护模式。原则上只要把控制寄存器CR0中的PE位清0即可。实际上，在此之后也要安排一条段间转移指令，一方面清指令预取队列，另一方面把实模式下代码段的段值送CS。 这条段间转移指令在保护方式下被预取并在实模式下被执行。
(4)保护模式下的数据传送
首先，把源数据段和目标数据段的选择子装入DS和ES寄存器，这两个描述符已在实模式下设置好，把选择子装入段寄存器就意味着把包括基地址在内的段信息装入到了段描述符高速缓冲寄存器。然后设置指针寄存器SI和DI的初值，也设置计数器CX的初值。根据预置的段属性，在保护方式下，代码段也仅是16位段，串操作指令只使用16位的SI、DI和CX等寄存器。最后利用串操作指令实施传送。
(5)显示缓冲区中的内容
由于缓冲区在常规内存中，所以在实模式下根据要求按十六进制显示其内容是很容易理解的，这里就不再多说。
4.内存映象
在源程序中没有把GDT作为一个单独的段对待，但在进入保护方式后，它是一个独立的段。从对代码段和源数据段描述符所赋的基地址和段界限值可见，代码段和数据段有部分覆盖。尽管这样做不利于代码和数据的安全，但如果需要，这样做是可行的。本实例运行时的内存映象如下图所示。
5.特别说明
作为第一个实模式和保护模式切换的例子，本实例作了大量的简化处理。
通常，由实模式切换到保护模式的准备工作还应包含建立中断描述符表。但本实例没有建立中断描述符表。为此，要求整个过程在关中断的情况下进行；要求不使用软中断指令；假设不发生任何异常。否则会导致系统崩溃。
本实例未使用局部描述符表，所以在进入保护模式后没有设置局部描述符表寄存器LDTR。为此，在保护模式下使用的段选择子都指定GDT中的描述符。
本实例未定义保护模式下的堆栈段，GDT中没有堆栈段描述符，在保护模式下没有设置SS，所以在保护方式下没有涉及堆栈操作的指令。
本实例各描述符特权级DPL和各选择子的请求特权级RPL均为0，在保护方式下运行时的当前特权级CPL也是0。
本实例没有采用分页管理机制，也即CR0中的PG位为0，线性地址就是存储单元的物理地址。
6.打开和关闭地址线A20
PC及其兼容机的第21根地址线(A20)较特殊，计算机系统中一般安排一个 “门”控制该地址线是否有效。为了访问地址在1M以上的存储单元，应先打开控制地址线A20的“门”。这种设置与实模式下只使用最低端的1M字节存储空间有关，与处理器是否工作在实模式或保护方式无关，即使在关闭地址线A20时，也可进入保护模式。
如何打开和关闭地址线A20与计算机系统的具体设置有关。在本文中介绍的包含文件386SCD.INC中定义了两个宏，打开地址线A20的宏EnableA20和关闭地址线A20的宏DisableA20，此两个宏指令在一般的PC兼容机上都是可行的。
<二>演示32位代码段和16位代码段切换的实例(实例二)
实例二的逻辑功能是，以十六进制数和ASCII字符两种形式显示从内存地址100000H开始的16个字节的内容。
从功能上看，本实例类似于实例一，但在实现方法上却有了改变，它更能反映出实模式和保护模式切换的情况。具体实现步骤是：(1)作切换到保护方式的准备；(2)切换到保护方式的一个32位代码段；(3)把指定内存区域的内容以字节为单位，转换成对应的十六进制数的ASCII码，并直接填入显示缓冲区实现显示；(4)再变换到保护方式下的一个16位代码段；(5)把指定内存区域的内容直接作为ASCII码填入显示缓冲区中实现显示；(6)切换回实模式。
1.实例二源程序
实例二的源程序如下所示：
;名称:ASM2.ASM
;功能:演示实方式和保护方式切换(切换到32位代码段)
;----------------------------------------------------------------------------
INCLUDE 386SCD.INC
;----------------------------------------------------------------------------
DSEG SEGMENT USE16 ;16位数据段
;----------------------------------------------------------------------------
GDT LABEL BYTE ;全局描述符表
DUMMY Desc <> ;空描述符
Normal Desc <0ffffh,,,ATDW,,> ;规范段描述符
Code32 Desc <C32Len-1,,,ATCE,D32,> ;32位代码段描述符
Code16 Desc <0ffffh,,,ATCE,,> ;16位代码段描述符
DataS Desc <DataLen-1,0,10h,ATDR,,> ;源数据段描述符
DataD Desc <3999,8000h,0bh,ATDW,,> ;显示缓冲区描述符
Stacks Desc <StackLen-1,,,ATDW,,> ;堆栈段描述符
;----------------------------------------------------------------------------
GDTLen = $-GDT ;全局描述符表长度
VGDTR PDesc <GDTLen-1,> ;伪描述符
;----------------------------------------------------------------------------
SaveSP DW ? ;用于保存SP寄存器
SaveSS DW ? ;用于保存SS寄存器
;----------------------------------------------------------------------------
Normal_Sel = Normal-GDT ;规范段描述符选择子
Code32_Sel = Code32-GDT ;32位代码段选择子
Code16_Sel = Code16-GDT ;16位代码段选择子
DataS_Sel = Datas-GDT ;源数据段选择子
DataD_Sel = DataD-GDT ;目标数据段选择子
Stacks_Sel = Stacks-GDT ;堆栈段描述符选择子
;----------------------------------------------------------------------------
DataLen = 16
;----------------------------------------------------------------------------
DSEG ENDS ;数据段定义结束
;----------------------------------------------------------------------------
StackSeg SEGMENT PARA STACK USE16
StackLen = 256
DB StackLen DUP(0)
StackSeg ENDS
;----------------------------------------------------------------------------
CSEG1 SEGMENT USE16 'REAL' ;16位代码段
ASSUME CS:CSEG1,DS:DSEG
;----------------------------------------------------------------------------
Start PROC
mov ax,DSEG
mov ds,ax
;准备要加载到GDTR的伪描述符
mov bx,16
mul bx
add ax,OFFSET GDT ;计算并设置基地址
adc dx,0 ;界限已在定义时设置好
mov WORD PTR VGDTR.Base,ax
mov WORD PTR VGDTR.Base+2,dx
;设置32位代码段描述符
mov ax,CSEG2
mul bx
mov WORD PTR Code32.BaseL,ax
mov BYTE PTR Code32.BaseM,dl
mov BYTE PTR Code32.BaseH,dh
;设置16位代码段描述符
mov ax,CSEG3
mul bx
mov WORD PTR Code16.BaseL,ax ;代码段开始偏移为0
mov BYTE PTR Code16.BaseM,dl ;代码段界限已在定义时设置好
mov BYTE PTR Code16.BaseH,dh
;设置堆栈段描述符
mov ax,ss
mov WORD PTR SaveSS,ax
mov WORD PTR SaveSP,sp
mov ax,StackSeg
mul bx
mov WORD PTR Stacks.BaseL,ax
mov BYTE PTR Stacks.BaseM,dl
mov BYTE PTR Stacks.BaseH,dh
;加载GDTR
lgdt QWORD PTR VGDTR
cli ;关中断
EnableA20 ;打开地址线A20
;切换到保护方式
mov eax,cr0
or al,1
mov cr0,eax
;清指令预取队列,并真正进入保护方式
JUMP16 Code32_Sel,<OFFSET SPM32>
ToReal: ;现在又回到实方式
mov ax,DSEG
mov ds,ax
mov sp,SaveSP
mov ss,SaveSS
DisableA20
sti
mov ax,4c00h
int 21h
Start ENDP
;----------------------------------------------------------------------------
CSEG1 ENDS ;代码段定义结束
;----------------------------------------------------------------------------
CSEG2 SEGMENT USE32 'PM32'
ASSUME CS:CSEG2
;----------------------------------------------------------------------------
SPM32 PROC
mov ax,Stacks_Sel
mov ss,ax
mov esp,StackLen
mov ax,DataS_Sel
mov ds,ax
mov ax,DataD_Sel
mov es,ax
xor esi,esi
xor edi,edi
mov ecx,DataLen
cld
Next: lodsb
push ax
CALL ToASCII
mov ah,7
shl eax,16
pop ax
shr al,4
CALL ToASCII
mov ah,7
stosd
mov al,20h
stosw
loop Next
JUMP32 Code16_Sel,<OFFSET SPM16>
SPM32 ENDP
;----------------------------------------------------------------------------
ToASCII PROC
and al,00001111b
add al,30h
cmp al,39h
jbe Isdig
add al,7
IsDig: ret
ToASCII ENDP
;----------------------------------------------------------------------------
C32Len = $
;----------------------------------------------------------------------------
CSEG2 ENDS
;----------------------------------------------------------------------------
CSEG3 SEGMENT USE16 'PM16'
ASSUME CS:CSEG3
;----------------------------------------------------------------------------
SPM16 PROC
xor si,si
mov di,DataLen*3*2
mov ah,7
mov cx,DataLen
AGain: lodsb
stosw
loop AGain
mov ax,Normal_sel
mov ds,ax
mov es,ax
mov ss,ax
mov eax,cr0
and al,11111110b
mov cr0,eax
jmp FAR PTR ToReal
SPM16 ENDP
;----------------------------------------------------------------------------
CSEG3 ENDS
;----------------------------------------------------------------------------
END Start
2.关于实现步骤的注释
(1)切换到保护模式的准备工作
建立全局描述符表，这里的全局描述符表含有两个16位数据段的描述符、一个16位代码段的描述符和一个16位的堆栈段描述符。此外，GDT中还有一个32位的代码段描述符，描述32位代码段，该描述符的属性字段中的D位为1。
(2)由实模式切换到保护模式
由实模式切换到保护模式32位代码段的方法与切换到16位代码段的方法相同。由保护模式16位代码段切换回实模式的方法与实例一相似。
在保护模式下，通过如下直接段间转移指令从32位代码段切换到16位代码段：
JUMP32 Code16_Sel,<OFFSET SPM16>
从该宏指令的定义可知，该转移指令含48位指针，其高16位是16位代码段的选择子，低32位是16位代码段的入口偏移。 该指令在32位方式下预取并执行。由于在32位方式下执行，所以要使用48位指针。
(3)显示指定内存区域的内容
在本实例中，采用直接写显示缓冲区的方法实现显示。假设显示缓冲区的开始物理地址是0B8000H， 3号文本显示模式，在屏幕的第一行进行显示。
3.特别说明
本实例在保护方式下使用了涉及堆栈操作的指令，因此建立了一个16位的保护模式下的堆栈段。
本实例仍作了大量的简化处理。如：没有建立IDT和LDT等，各特权级均是0。也没有采用分页管理机制。
从本实例的GDT中可见，两个数据段的界限都是根据实际大小而设置的。从源程序代码段CSEG3可见，在切换到实模式之前，把一个指向似乎没有用的数据段的描述符Normal的选择子装载到DS和ES。这是为什么呢?
| 实模 式下 段描 述符 高速 缓冲 寄存 器的 内容 |
段寄存器 | 段基地址 | 段界限(固定) | 段属性(固定) | |||||||||
| 存在性 | 特权级 | 已存取 | 粒度 | 扩展方向 | 可读性 | 可写性 | 可执行 | 堆栈大小 | 一致特权 | ||||
| CS | 当前CS*16 | 0000FFFFH | Y | 0 | Y | B | U | Y | Y | Y | - | N | |
| SS | 当前SS*16 | 0000FFFFH | Y | 0 | Y | B | U | Y | Y | N | W | - | |
| DS | 当前DS*16 | 0000FFFFH | Y | 0 | Y | B | U | Y | Y | N | - | - | |
| ES | 当前ES*16 | 0000FFFFH | Y | 0 | Y | B | U | Y | Y | N | - | - | |
| FS | 当前FS*16 | 0000FFFFH | Y | 0 | Y | B | U | Y | Y | N | - | - | |
| GS | 当前GS*16 | 0000FFFFH | Y | 0 | Y | B | U | Y | Y | N | - | - | |
在分段管理机制一文中已介绍过，每个段寄存器都配有段描述符高速缓冲寄存器，这些高速缓冲寄存器在实方式下仍发挥作用，只是内容上与保护模式下有所不同。如上表所示，其中“Y”表示“是”； “N”表示“否”；“B”表示字节；“U”表示向上扩展，“W”表示以字方式操作堆栈。段基地址仍是 32位，其值是相应段寄存器值(段值)乘以16，在把段值装载到段寄存器时刷新。由于其值是16位段值乘上16，所以在实模式下基地址实际上有效位只有20位。每个段的32位段界限都固定为0FFFFH，段属性的许多位也是固定的。所谓固定是指在实方式下不可设置这些属性值，只能继续沿用保护方式下所设置的值。因此，在准备结束保护模式回到实模式之前，要通过加载一个合适的描述符选择子到有关段寄存器，以使得对应段描述符高速缓冲寄存器中含有合适的段界限和属性。本实例GDT中的描述符Normal就是这样一个描述符，在返回实模式之前把对应选择子Normal_Sel加载到DS和ES就是此目的。由于SS段描述符中的内容已符合实模式的需要，所以尽管也改变了SS，但不需要重新加载SS(本实例中重新加载了SS，这除了稍增加运行时间外，并没有什么坏处)。16位代码段描述符中的内容也符合实模式的需要，所以在通过16位代码段返回实模式时，CS段描述符中的内容也符合实模式的要求。需要注意的是，不能从32位代码段返回实模式，这是因为无法实现从32位代码段返回时CS高速缓冲寄存器中的属性符合实模式的要求(实模式不能改变段属性)。顺便说以下，实例一中的描述符都是符合实模式要求的。段描述符高速缓冲寄存器中含有合适的段界限
4.关于32位代码段程序设计的说明
在32位代码段中，缺省的操作数大小是32位，缺省的存储单元地址大小是32位。由于串操作指令使用的指针寄存器是ESI和EDI，LOOP指令使用的计数器是ECX，所以，在代码段CSEG2中，为了使用串操作指令，对ESI和EDI等寄存器赋初值。请比较代码段CSEG3中的相关片段和实例一中的相关片段，它们是16位代码段。
五.任务状态段和控制门
每个任务有一个任务状态段TSS，用于保存任务的有关信息，在任务内变换特权级和任务切换时，要用到这些信息。为了控制任务内发生特权级变换的转移，为了控制任务切换，一般要通过控制门进行这些转移。本文将介绍任务状态段和控制门。
<一>系统段描述符
系统段是为了实现存储管理机制所使用的一种特别的段。在80386中，有两种系统段：任务状态段TSS和局部描述符表LDT段。用于描述系统段的描述符称为系统段描述符。
1.系统段描述符的格式
系统段描述符的一般格式如下表所示。
| 系统段 描述符 |
m+7 | m+6 | m+5 | m+4 | m+3 | m+2 | m+1 | m+0 |
| Base(31...24) | Attributes | Segment Base(23...0) | Segment Limite(15...0) | |||||
| 系统段 描述符 的属性 |
Byte m+6 | Byte m+5 | ||||||||||||||
| BIT7 | BIT6 | BIT5 | BIT4 | BIT3 | BIT2 | BIT1 | BIT0 | BIT7 | BIT6 | BIT5 | BIT4 | BIT3 | BIT2 | BIT1 | BIT0 | |
| G | X | 0 | AVL | Limit(19...16) | P | DPL | DT0 | TYPE | ||||||||
与存储段描述符相比，它们很相似，区分的标志是属性字节中的描述符类型位DT的值。DT=1表示存储段，DT=0表示系统段。系统段描述符中的段基地址和段界限字段与存储段描述符中的意义完全相同；属性中的G位、AVL位、P位和DPL字段的作用也完全相同。存储段描述符属性中的D位在系统段描述符中不使用，现用符号X表示。系统段描述符的类型字段TYPE仍是4位，其编码及表示的类型列于下表，其含义与存储段描述符的类型却完全不同。
|
|
从上表可见，只有类型编码为2、1、3、9和B的描述符才是真正的系统段描述符，它们用于描述系统段LDT和任务状态段TSS，其它类型的描述符是门描述符。
利用前文定义的存储段描述符结构类型DESC仍能方便地在程序中说明系统段描述符。需要注意的是，系统段描述符的选择子不能用来读写系统段，要想读写系统段，必须使用别名技术。
2.LDT段描述符
LDT段描述符描述任务的局部描述符表段。例如：下面的描述符LDTABLE描述一个局部描述符表段，基地址是654321H，以字节为单位的界限是1FH，描述符特权级是0。
LDTABLE DESC <1FH,4321H,65H,82H,,>
LDT段描述符必须安排在全局描述符表中才有效。在装载LDTR寄存器时，描述符中的LDT段基地址和段界限等信息被装入LDT段描述符高速缓冲寄存器中。
3.任务状态段描述符
任务状态段TSS用于保存任务的各种状态信息。任务状态段描述符描述某个任务状态段TSS描述符分为286TSS和386TSS两类。TSS描述符规定了任务状态段的基地址和任务状态段的大小等信息。例如，下面的描述符TempTask描述一个可用的386任务状态段，基地址是123456H，以字节为单位的界限是104，描述符特权级是0。
TempTask DESC <104,3456H,12H,89H,,>
在装载任务状态段寄存器TR时，描述符中的段基地址和段界限等信息被装入到TR的高速缓冲寄存器中。在任务切换或执行LTR指令时，要装载TR寄存器。
TSS描述符中的类型规定：TSS要么为“忙”，要么为“可用”。如果一个任务是当前正执行的任务，或者是用TSS中的链接字段沿挂起任务链接到当前任务上的任务，那么该任务是“忙”的任务；否则该任务为“可用”任务。
利用段间转移指令JMP和段间调用指令CALL，直接通过TSS描述符或通过任务门可实现任务切换。
<二>门描述符
除存储段描述符和系统段描述符外，还有一类门描述符。门描述符并不描述某种内存段，而是描述控制转移的入口点。这种描述符好比一个同向另一代码段的门。通过这种门，可实现任务内特权级的变换和任务间的切换。所以，这种门描述符也称为控制门。
1.门描述符的一般格式
门描述符的一般格式如下图所示。门描述符只有位于描述符内偏移5的类型字节与系统段保持一致，也由该字节标示门描述符和系统段描述符。该字节内的P和DPL的意义与其它描述符种中的意义相同。其它字节主要用于存放一个48位的全指针(16位的选择子和32位的偏移量)。
| 门描述符 | m+7 | m+6 | m+5 | m+4 | m+3 | m+2 | m+1 | m+0 |
| Offset(31...16) | Attributes | Selector | Offset(15...0) | |||||
| 门描述 符属性 |
Byte m+5 | Byte m+4 | ||||||||||||||
| BIT7 | BIT6 | BIT5 | BIT4 | BIT3 | BIT2 | BIT1 | BIT0 | BIT7 | BIT6 | BIT5 | BIT4 | BIT3 | BIT2 | BIT1 | BIT0 | |
| P | DPL | DT0 | TYPE | 000 | Dword Count | |||||||||||
根据上图给出的门描述符的结构，可定义如下的门描述符结构类型：
GATE STRUC ;门结构类型定义 OFFSETL DW 0 ;32位偏移的低16位 SELECTOR DW 0 ;选择子 DCOUNT DB 0 ;双字计数字段 GTYPE DB 0 ;类型 OFFSETH DW 0 ;32位偏移的高16位 GATE ENDS
利用门描述符结构类型GATE能方便地在程序中说明门描述符。
例如，下面的门描述符SUBRG描述一个386调用门，门内的选择子是10H，入口偏移是123456H，门描述符特权级是3，双字计数是0。
SUBRG GATE <3456,10H,,8CH+60H,12H>
从上述描述符类型的列表中可见，门描述符又可分为：任务门、调用门、中断门和陷阱门，并且除任务门外，其它描述符还各分成286和386两种。
2.调用门
调用门描述某个子程序的入口。调用门内的选择子必须实现代码段描述符，调用门内的偏移是对应代码段内的偏移。利用段间调用指令CALL，通过调用门可实现任务内从外层特权级变换到内层特权级。
在上图所示的门描述符内偏移4字节的位0至位4是双字计数字段，该字段只在调用门描述符中有效，在其它门描述符中无效。主程序通过堆栈把入口参数传递给子程序，如果在利用调用门调用子程序时引起特权级的转换和堆栈的改变，那么就需要将外层堆栈中的参数复制到内层堆栈。该双字计数字段就是用于说明这种情况发生时，要复制的双字参数的数量。
3.任务门
任务门指示任务。任务门内的选择子必须指示GDT中的任务状态段TSS描述符，门中的偏移无意义。任务的入口点保存在TSS中。利用段间转移指令JMP和段间调用指令CALL，通过任务门可实现任务切换。
4.中断门和陷阱门
中断门和陷阱门描述中断/异常处理程序的人口点。中断门和陷阱门内的选择子必须指向代码段描述符，门内的偏移就是对应代码段的人口点的偏移。中断门和陷阱门只有在中断描述符表IDT中才有效。关于中断门和陷阱门的区别将在以后的文章中论述。
<三>任务状态段
任务状态段(Task State Segment)是保存一个任务重要信息的特殊段。任务状态段描述符用于描述这样的系统段。任务状态段寄存器TR的可见部分含有当前任务的任务状态段描述符的选择子，TR的不可见的高速缓冲寄存器部分含有当前任务状态段的段基地址和段界限等信息。
TSS在任务切换过程中起着重要作用，通过它实现任务的挂起和恢复。所谓任务切换是指，挂起当前正在执行的任务，恢复或启动另一任务的执行。在任务切换过程中，首先，处理器中各寄存器的当前值被自动保存到TR所指定的TSS中；然后，下一任务的TSS的选择子被装入TR；最后，从TR所指定的TSS中取出各寄存器的值送到处理器的各寄存器中。由此可见，通过在TSS中保存任务现场各寄存器状态的完整映象，实现任务的切换。
任务状态段TSS的基本格式如下图所示。
| 任 务 状 态 段 基 本 部 分 的 格 式 |
BIT31—BIT16 | BIT15—BIT1 | BIT0 | Offset |
| 0000000000000000 | 链接字段 | 0 | ||
| ESP0 | 4 | |||
| 0000000000000000 | SS0 | 8 | ||
| ESP1 | 0CH | |||
| 0000000000000000 | SS1 | 10H | ||
| ESP2 | 14H | |||
| 0000000000000000 | SS2 | 18H | ||
| CR3 | 1CH | |||
| EIP | 20H | |||
| EFLAGS | 24H | |||
| EAX | 28H | |||
| ECX | 2CH | |||
| EDX | 30H | |||
| EBX | 34H | |||
| ESP | 38H | |||
| EBP | 3CH | |||
| ESI | 40H | |||
| EDI | 44H | |||
| 0000000000000000 | ES | 48H | ||
| 0000000000000000 | CS | 4CH | ||
| 0000000000000000 | SS | 50H | ||
| 0000000000000000 | DS | 54H | ||
| 0000000000000000 | FS | 58H | ||
| 0000000000000000 | GS | 5CH | ||
| 0000000000000000 | LDTR | 60H | ||
| I/O许可位图偏移 | 000000000000000 | T | 64H | |
从图中可见，TSS的基本格式由104字节组成。这104字节的基本格式是不可改变的，但在此之外系统软件还可定义若干附加信息。基本的104字节可分为链接字段区域、内层堆栈指针区域、地址映射寄存器区域、寄存器保存区域和其它字段等五个区域。
1.寄存器保存区域
寄存器保存区域位于TSS内偏移20H至5FH处，用于保存通用寄存器、段寄存器、指令指针和标志寄存器。当TSS对应的任务正在执行时，保存区域是未定义的；在当前任务被切换出时，这些寄存器的当前值就保存在该区域。当下次切换回原任务时，再从保存区域恢复出这些寄存器的值，从而，使处理器恢复成该任务换出前的状态，最终使任务能够恢复执行。
从上图可见，各通用寄存器对应一个32位的双字，指令指针和标志寄存器各对应一个32位的双字；各段寄存器也对应一个32位的双字，段寄存器中的选择子只有16位，安排再双字的低16位，高16位未用，一般应填为0。
2.内层堆栈指针区域
为了有效地实现保护，同一个任务在不同的特权级下使用不同的堆栈。例如，当从外层特权级3变换到内层特权级0时，任务使用的堆栈也同时从3级变换到0级堆栈；当从内层特权级0变换到外层特权级3时，任务使用的堆栈也同时从0级堆栈变换到3级堆栈。所以，一个任务可能具有四个堆栈，对应四个特权级。四个堆栈需要四个堆栈指针。
TSS的内层堆栈指针区域中有三个堆栈指针，它们都是48位的全指针(16位的选择子和32位的偏移)，分别指向0级、1级和2级堆栈的栈顶，依次存放在TSS中偏移为4、12及20开始的位置。当发生向内层转移时，把适当的堆栈指针装入SS及ESP寄存器以变换到内层堆栈，外层堆栈的指针保存在内层堆栈中。没有指向3级堆栈的指针，因为3级是最外层，所以任何一个向内层的转移都不可能转移到3级。
但是，当特权级由内层向外层变换时，并不把内层堆栈的指针保存到TSS的内层堆栈指针区域。实际上，处理器从不向该区域进行写入，除非程序设计者认为改变该区域的值。这表明向内层转移时，总是把内层堆栈认为是一个空栈。因此，不允许发生同级内层转移的递归，一旦发生向某级内层的转移，那么返回到外层的正常途径是相匹配的向外层返回。
3.地址映射寄存器区域
从虚拟地址空间到线性地址空间的映射由GDT和LDT确定，与特定任务相关的部分由LDT确定，而LDT又由LDTR确定。如果采用分页机制，那么由线性地址空间到物理地址空间的映射由包含页目录表起始物理地址的控制寄存器CR3确定。所以，与特定任务相关的虚拟地址空间到物理地址空间的映射由LDTR和CR3确定。显然，随着任务的切换，地址映射关系也要切换。
TSS的地址映射寄存器区域由位于偏移1CH处的双字字段(CR3)和位于偏移60H处的字字段(LDTR)组成。在任务切换时，处理器自动从要执行任务的TSS中取出这两个字段，分别装入到寄存器CR3和LDTR。这样就改变了虚拟地址空间到物理地址空间的映射。
但是，在任务切换时，处理器并不把换出任务但是的寄存器CR3和LDTR的内容保存到TSS中的地址映射寄存器区域。事实上，处理器也从来不向该区域自动写入。因此，如果程序改变了LDTR或CR3，那么必须把新值人为地保存到TSS中的地址映射寄存器区域相应字段中。可以通过别名技术实现此功能。
4.链接字段
链接字段安排在TSS内偏移0开始的双字中，其高16位未用。在起链接作用时，地16位保存前一任务的TSS描述符的选择子。
如果当前的任务由段间调用指令CALL或中断/异常而激活，那么链接字段保存被挂起任务的 TSS的选择子，并且标志寄存器EFLAGS中的NT位被置1，使链接字段有效。在返回时，由于NT标志位为1，返回指令RET或中断返回指令IRET将使得控制沿链接字段所指恢复到链上的前一个任务。
5.其它字段
为了实现输入/输出保护，要使用I/O许可位图。任务使用的I/O许可位图也存放在TSS中，作为TSS的扩展部分。在TSS内偏移66H处的字用于存放I/O许可位图在TSS内的偏移(从TSS开头开始计算)。关于I/O许可位图的作用，以后的文章中将会详细介绍。
在TSS内偏移64H处的字是为任务提供的特别属性。在80386中，只定义了一种属性，即调试陷阱。该属性是字的最低位，用T表示。该字的其它位置被保留，必须被置为0。在发生任务切换时，如果进入任务的T位为1，那么在任务切换完成之后，新任务的第一条指令执行之前产生调试陷阱。
6.用结构类型定义TSS
根据上图给出的任务状态段TSS的结构，可定义如下的TSS结构类型：
;---------------------------------------------------------------------------- ;任务状态段结构类型定义 ;---------------------------------------------------------------------------- TSS STRUC TRLink DW 0 ;链接字段 DW 0 ;不使用,置为0 TRESP0 DD 0 ;0级堆栈指针 TRSS0 DW 0 ;0级堆栈段寄存器 DW 0 ;不使用,置为0 TRESP1 DD 0 ;1级堆栈指针 TRSS1 DW 0 ;1级堆栈段寄存器 DW 0 ;不使用,置为0 TRESP2 DD 0 ;2级堆栈指针 TRSS2 DW 0 ;2级堆栈段寄存器 DW 0 ;不使用,置为0 TRCR3 DD 0 ;CR3 TREIP DD 0 ;EIP TREFlag DD 0 ;EFLAGS TREAX DD 0 ;EAX TRECX DD 0 ;ECX TREDX DD 0 ;EDX TREBX DD 0 ;EBX TRESP DD 0 ;ESP TREBP DD 0 ;EBP TRESI DD 0 ;ESI TREDI DD 0 ;EDI TRES DW 0 ;ES DW 0 ;不使用,置为0 TRCS DW 0 ;CS DW 0 ;不使用,置为0 TRSS DW 0 ;SS DW 0 ;不使用,置为0 TRDS DW 0 ;DS DW 0 ;不使用,置为0 TRFS DW 0 ;FS DW 0 ;不使用,置为0 TRGS DW 0 ;GS DW 0 ;不使用,置为0 TRLDTR DW 0 ;LDTR DW 0 ;不使用,置为0 TRTrip DW 0 ;调试陷阱标志(只用位0) TRIOMap DW ___FCKpd___162 ;指向I/O许可位图区的段内偏移 TSS ENDS