《一个操作系统的实现》读书笔记--第三章--中断机制

1、中断产生的原因
2、如何将中断向量与中断服务程序关联起来
3、外部中断

一、中断

中断产生的原因有两种：一是外部中断，就是由硬件产生的中断；另一种是由指令int n产生的中断。

二、如何将中断向量与中断服务程序关联起来

1、实模式下：

这个过程很简单，就是通过int n中的n，去中断向量表中获取该中断的中断服务程序的CS和IP，然后加载CS和IP，跳转到中断服务程序。
其中(n*4)(n*4+1)中保存着中断服务程序入口地址的偏移量IP
(n*4+2)(n*4+3)中保存着中断服务程序入口地址的段地址CS

2、保护模式下：

在保护模式下，不存在中断向量表，而是使用中断描述符表--IDT(Interrupt Descriptor Table)。
中断描述符表，类似于GDT、LDT，实际上就是一个描述符表。
IDT中的描述符可以是下面三种之一：中断门描述符、陷阱门描述符、任务门描述符
IDT的作用是将每一个中断向量和一个描述符对应起来，而描述符中保存的是中断服务程序的基地址和偏移量。

三、外部中断

外部中断的情况有些复杂，因为需要建立硬件中断与向量号之间的对应关系。外部中断分为不可屏蔽中断(NMI)和可屏蔽中断两种，分别由CPU的两根引脚NMI和INTR来接受。

8259A是可编程中断控制器，对它的设置并不复杂，是通过向相应的端口地址写入特定的ICW(Initialization Command Word)来实现的。主8259A对应的端口地址是20h和21h，从8259A对应的端口地址是A0h和A1h。ICW共有4个，每一个都是具有特定格式的字节。8259A初始化过程为：
(1)往端口20h(主片)或A0h(从片)写入ICW1
(2)往端口21h(主片)或A1h(从片)写入ICW2
(3)往端口21h(主片)或A1h(从片)写入ICW3
(4)往端口21h(主片)或A1h(从片)写入ICW4

下面结合pmtest9.asm 中的Init8259A的函数，来讲述初始化8259A的过程。

; Init8259A ---------------------------------------------------------------------------------------------
Init8259A:
	mov	al, 011h
	out	020h, al	; 主8259, ICW1.
	call	io_delay

	out	0A0h, al	; 从8259, ICW1.
	call	io_delay

	mov	al, 020h	; IRQ0 对应中断向量 0x20
	out	021h, al	; 主8259, ICW2.
	call	io_delay

	mov	al, 028h	; IRQ8 对应中断向量 0x28
	out	0A1h, al	; 从8259, ICW2.
	call	io_delay

	mov	al, 004h	; IR2 对应从8259
	out	021h, al	; 主8259, ICW3.
	call	io_delay

	mov	al, 002h	; 对应主8259的 IR2
	out	0A1h, al	; 从8259, ICW3.
	call	io_delay

	mov	al, 001h
	out	021h, al	; 主8259, ICW4.
	call	io_delay

	out	0A1h, al	; 从8259, ICW4.
	call	io_delay

	mov	al, 11111110b	; 仅仅开启定时器中断
	;mov	al, 11111111b	; 屏蔽主8259所有中断
	out	021h, al	; 主8259, OCW1.
	call	io_delay

	mov	al, 11111111b	; 屏蔽从8259所有中断
	out	0A1h, al	; 从8259, OCW1.
	call	io_delay

	ret
; Init8259A ---------------------------------------------------------------------------------------------

0001 0001 主8259A, ICW1
需要ICW4，级联8259,8字节中断向量，edge triggered模式，PC系统

0001 0001 从8259A, ICW1
需要ICW4，级联8259,8字节中断向量，edge triggered模式，PC系统

0010 0000 主8259A，ICW2
80x86系统，IR0对应中断向量Ox20

0010 1000 从8259A，ICW2
80x86系统，IR8对应中断向量Ox28

0000 0100 主8259A，ICW3
IR0，IR1，IR3，IR4，IR5，IR6，IR7，无从片；IR2有级联从片

0000 0010 从8259A，ICW3
级联于主8259的IR2

0000 0001 主8259A，ICW4
0000 0001 从8259A，ICW4

1111 1111 主8259，OCW1
屏蔽主8259所有中断

1111 1111 从8259，OCW1
屏蔽从8259所有中断