Linux代码阅读之header.S（一）

以下源代码来源于linux2.6.26.5的arch/x86/boot/header.S

1. /*
2.  *  header.S
3.  *
4.  *  Copyright (C) 1991, 1992 Linus Torvalds
5.  *
6.  *  Based on bootsect.S and setup.S
7.  *  modified by more people than can be counted
8.  *
9.  *  Rewritten as a common file by H. Peter Anvin (Apr 2007)
10.  *
11.  * BIG FAT NOTE: We're in real mode using 64k segments.  Therefore segment
12.  * addresses must be multiplied by 16 to obtain their respective linear
13.  * addresses. To avoid confusion, linear addresses are written using leading
14.  * hex while segment addresses are written as segment:offset.
15.  *
16.  */
18. #include <asm/segment.h>
19. #include <linux/utsrelease.h>
20. #include <asm/boot.h>
21. #include <asm/e820.h>
22. #include <asm/page.h>
23. #include <asm/setup.h>
24. #include "boot.h"
25. #include "offsets.h"
27. SETUPSECTS  = 4         /* default nr of setup-sectors */
28. BOOTSEG     = 0x07C0        /* original address of boot-sector */
29. SYSSEG      = DEF_SYSSEG        /* system loaded at 0x10000 (65536) */
30. SYSSIZE     = DEF_SYSSIZE       /* system size: # of 16-byte clicks */
31.                     /* to be loaded */
32. ROOT_DEV    = 0         /* ROOT_DEV is now written by "build" */
33. SWAP_DEV    = 0         /* SWAP_DEV is now written by "build" */
35. #ifndef SVGA_MODE
36. #define SVGA_MODE ASK_VGA
37. #endif
39. #ifndef RAMDISK
40. #define RAMDISK 0
41. #endif
43. #ifndef ROOT_RDONLY
44. #define ROOT_RDONLY 1
45. #endif
47. #从2.6内核开始linux不再支持从软盘引导系统，因此如果从这里开始引导系统
48. #必然会出错，以下注释仅供学习之用，我会尽量努力把内核启动部分代码都加
49. #上注释，但不保证正确性。
51.     .code16
52.     .section ".bstext", "ax"
54.     .global bootsect_start
55. bootsect_start:             
57.     # Normalize the start address
58.     ljmp    $BOOTSEG, $start2 #跳转到start2，这个是一个远跳转，注意其语法为:ljmp $段,$段内偏移
60. start2:
61.     movw    %cs, %ax    #%cs内容为0x07c0
62.     movw    %ax, %ds
63.     movw    %ax, %es
64.     movw    %ax, %ss
65.     xorw    %sp, %sp    #%sp清零
66.     sti             #开中断
67.     cld             #清除eflags方向位，为msg_loop后的语句做准备
69.     movw    $bugger_off_msg, %si #将bugger_of_msg标示所在内存地址放入%si
71. msg_loop:
72.     lodsb           #从%ds:%si处加载1字节到%al
73.     andb    %al, %al    #连同下一条语句判断%al是否为0
74.     jz  bs_die      #若%al为0则跳转到bs_die处
75.     movb    $0xe, %ah   #若%al不为0，则调用bios中断程序显示%al中的字节，0xe是功能码
76.     movw    $7, %bx     #%bh=0x00 则为page 0，%bl=0x07指明字体颜色   
77.     int $0x10       #中断号0x10为显示字符中断
78.     jmp msg_loop    #跳转到msg_loop处循环显示，每次显示一个字节
80. bs_die:
81.     # Allow the user to press a key, then reboot
82.     xorw    %ax, %ax    #清零%ax
83.     int $0x16       #调用0x16号bios中断，该中断在%ax为零的时候等待用户按任意键
84.     int $0x19       #调用0x19号bios中断重启计算机
86.     # int 0x19 should never return.  In case it does anyway,
87.     # invoke the BIOS reset code...
88.     ljmp    $0xf000,$0xfff0 #这条语句应当不会执行，若执行到这里，则这条语句会模拟用户按下reset建
90.     .section ".bsdata", "a"
91. bugger_off_msg:
92.     .ascii  "Direct booting from floppy is no longer supported./r/n"
93.     .ascii  "Please use a boot loader program instead./r/n"
94.     .ascii  "/n"
95.     .ascii  "Remove disk and press any key to reboot . . ./r/n"
96.     .byte   0