VB远程访问与删除特定文件读取XML备忘

<package>
<job id="DoneInVBS">
<script language="VBScript">
'=====================================設定部分 start===================================
'本番 FLVフォルダ
CONST HONBAN_FOLDER_PATH_1 = "\\xx.xx.xx.xxx\d\apache-tomcat-6.0.26-mm\webapps\s2blazeds-server-blank"
CONST HONBAN_FOLDER_PATH_2 = "\\xx.xx.xx.xxx\d\apache-tomcat-6.0.26-mm\webapps\s2blazeds-server-blank"
'STG FLVフォルダ
CONST STG_FOLDER_PATH = "D:\apache-tomcat-6.0.26-mm\webapps\s2blazeds-server-blank"
' net use conn string 本番1
CONST HONBAN_FOLDER_PATH_GET_1="cmd /c net use \\xx.xx.xx.xxx password /user:xx.xx.xx.xxx\username"
CONST HONBAN_FOLDER_PATH_DEL_1="cmd /c net use /delete \\xx.xx.xx.xxx"

' net use conn string 本番2
CONST HONBAN_FOLDER_PATH_GET_2="cmd /c net use \\xx.xx.xx.xxx password /user:xx.xx.xx.xxx\username"
CONST HONBAN_FOLDER_PATH_DEL_2="cmd /c net use /delete \\xx.xx.xx.xxx"
'====================================設定部分 end======================================
Dim fso
Dim folder
Dim objXML
Dim objList
Dim obshell

Set objXML = CreateObject("MSXML2.DOMDocument")
set fso=CreateObject("scripting.filesystemobject")

call GetConn(HONBAN_FOLDER_PATH_GET_1)
call GetConn(HONBAN_FOLDER_PATH_GET_2)

Call DeleteFLV(STG_FOLDER_PATH)
Call DeleteFLV(HONBAN_FOLDER_PATH_1)
Call DeleteFLV(HONBAN_FOLDER_PATH_2)

call DeleteConn(HONBAN_FOLDER_PATH_DEL_1)
call DeleteConn(HONBAN_FOLDER_PATH_DEL_2)

Sub DeleteFLV(folderPath)
	Set folder = fso.getfolder(folderPath)
	objXML.Load(folderPath & "\stream.xml")
	Set objList = objXML.getElementsByTagName("flvurl")

	For Each file In folder.Files                     
	
		If right(file.name,3)="flv" Then
			flg=0
			For i=0 To objList.length - 1
				If file.name=objList.Item(i).text Then
					
					flg=1
					Exit For
				End If
			Next
		
			If flg =0 Then
				WScript.Echo file.name & "が削除されました。"
				file.delete
			End If	
		
		End If
	Next
	
	set folder = fso.getfolder(folderPath & "\BACKUP")
	
	For Each file In folder.Files
		If fso.FileExists(file) then
			WScript.Echo file.name & "が削除されました(バックアプ)。"
			file.delete
		End If
	Next
	
End Sub

'#============================
'#  Get Connection
'#============================
Sub GetConn(connStr)
 
     Set obshell = CreateObject("wscript.shell")    
             obshell.run connStr,0,true 
 End Sub
'#============================
'#  Close Connection
'#============================
 Sub DeleteConn(connStr)
 
     Set obshell = CreateObject("wscript.shell")    
             obshell.run connStr,0,true
 End Sub 
 
set folder = nothing
set objList = nothing
set obshell=nothing
set objXML = nothing
set fso = nothing   
</script>
</job>
</package>