JZOJ 3126. 大LCP

Description

LCP——最长公共前缀。
首先，求LCP就要有字符串。既然那么需要它们，那就给出n个字符串好了。
于是你需要回答询问大LCP，询问给出一个k,你需要求出前k个字符串中两两的LCP最大值是多少，这就是传说中的大LCP。

Input

第一行一个整数N,Q,分别表示字符串个数和询问次数。
接下来N行，每行一个字符串。
再Q行，每行一个正整数k。

Output

Q行，依次分别表示对Q个询问的答案。

Sample Input

3 3
a
b
ab
1
2
3

Sample Output

0
0
1

Hint

对于30%的数据,字符串总长度不超过10^4,1<=N<=10^3,1<=Q<=10.
对于60%的数据,字符串总长度不超过10^4,1<=N<=10^3,1<=Q<=1000.
对于100%的数据,字符串总长度不超过10^6，1<=N,Q<=10^5.

Solution

我们可以构造一棵字典树，比如有dda,dsl,asl,asd四个字符串，则他们构造出来的字典树为

下面我来说一下字典树的构造过程：
构造一个ch数组ch[i,j]=k ([1<=i<=totalstrlen,1<=j<=26]) 表示总的第i个字符(字母j)的儿子是第k个字符。依次输入字符串，如果某字符没有儿子节点则创建，否则将现在的指针移向子节点。
附构造字典树过程代码：

k:=1;
for j:=1 to n do
begin
    readln(s);
    now:=1;//now是指针
    for i:=1 to length(s) do
    begin
        if ch[now,ord(s[i])-96]<>0 then now:=ch[now,ord(s[i])-96]
        else
        begin//此处无儿子节点则创建
            inc(k);
            ch[now,ord(s[i])-96]:=k;
            now:=k;
        end;
    end;
end;

我再给出一张图片让你们理解得更加透彻—>

//红色数字表示这个字符是被读入的第几个字符
则asl与asd的LCP的长度为它在哪里分岔的那一位-1.
图上asl与asd是从l和d分开的，故LCP的长度为3（l和d分别为asl、asd的第3位）-1=2。
由于他是要输出前K个数的最大LCA，所以我们可以离线操作。枚举每一个k（1≤k≤N）对应的答案。
用max更新答案。
下面附上AC代码：

var ch:array[0..1000001,1..26] of longint;
    ans:array[0..100001] of longint;
    i,j,k,l,n,m,t,_,now,q:longint;
    s:ansistring;
function max(a,b:longint):longint;
begin
    if a>b then exit(a) else exit(b);
end;
function min(a,b:longint):longint;
begin
    if a<b then exit(a) else exit(b);
end;
begin
    readln(n,m);
    k:=1;
    for j:=1 to n do
    begin
        readln(s);
        now:=1;
        l:=length(s);
        for i:=1 to length(s) do
        begin
            if ch[now,ord(s[i])-96]<>0 then now:=ch[now,ord(s[i])-96]
            else
            begin
                inc(k);
                ch[now,ord(s[i])-96]:=k;
                now:=k;
                l:=min(l,i-1);
            end;
        end;
        ans[j]:=max(ans[j-1],l);
    end;
    for i:=1 to m do
    begin
        readln(q);
        writeln(ans[q]);
    end;
end.

Special

这道题目是我学习字典树的一个启蒙。
——2016.2.14 By Wzy