NOIP2012提高组 开车旅行 题解+代码

题目描述

小 A 和小 B 决定利用假期外出旅行，他们将想去的城市从 1 到 N 编号，且编号较小的 城市在编号较大的城市的西边，已知各个城市的海拔高度互不相同，记城市 i 的海拔高度为 Hi，城市 i 和城市 j 之间的距离 d[i,j]恰好是这两个城市海拔高度之差的绝对值，即 d[i,j] = |h[i]-h[j]|。

小 A 和小 B 轮流开车，第一天小 A 开车，之后每天轮换一次。他们计划 选择一个城市 S 作为起点，一直向东行驶，并且最多行驶 X 公里就结束旅行。小 A 和小 B 的驾驶风格不同，小 B 总是沿着前进方向选择一个最近的城市作为目的地，而小 A 总是沿 着前进方向选择第二近的城市作为目的地（注意：本题中如果当前城市到两个城市的距离 相同，则认为离海拔低的那个城市更近）。 如果其中任何一人无法按照自己的原则选择目的 城市，或者到达目的地会使行驶的总距离超出 X 公里，他们就会结束旅行。

在启程之前，小 A 想知道两个问题：
1. 对于一个给定的 X=X0，从哪一个城市出发，小 A 开车行驶的路程总数与小 B 行驶 的路程总数的比值最小（如果小 B 的行驶路程为 0，此时的比值可视为无穷大，且两个无穷大视为相等）。如果从多个城市出发，小 A 开车行驶的路程总数与小 B 行驶的路程总数的比 值都最小，则输出海拔最高的那个城市。
2. 对任意给定的 X=Xi和出发城市 Si，小 A 开车行驶的路程总数以及小 B 行驶的路程 总数。

输入

输入文件为drive.in。
第一行包含一个整数 N，表示城市的数目。
第二行有 N 个整数，每两个整数之间用一个空格隔开，依次表示城市 1 到城市 N 的海拔高度，即H1，H2，……，Hn，且每个Hi都是不同的。
第三行包含一个整数 X0。
第四行为一个整数 M，表示给定M组Si和 Xi。
接下来的M行，每行包含2个整数Si和Xi，表示从城市 Si出发，最多行驶Xi公里。

输出

输出文件为drive.out。
输出共M+1 行。
第一行包含一个整数S0，表示对于给定的X0，从编号为S0的城市出发，小A开车行驶
的路程总数与小B行驶的路程总数的比值最小。
接下来的 M 行，每行包含 2 个整数，之间用一个空格隔开，依次表示在给定的 Si和
Xi下小A行驶的里程总数和小B 行驶的里程总数。

样例及解释

输入
4
2 3 1 4
3
4
1 3
2 3
3 3
4 3

输出
1
1 1
2 0
0 0
0 0

解释
如果从城市 1 出发，可以到达的城市为 2,3,4，这几个城市与城市 1 的距离分别为 1,1,2， 但是由于城市 3 的海拔高度低于城市 2，所以我们认为城市 3 离城市 1 最近，城市 2 离城市 1 第二近，所以小 A 会走到城市 2。到达城市 2 后，前面可以到达的城市为 3,4，这两个城 市与城市 2 的距离分别为 2,1，所以城市 4 离城市 2 最近，因此小 B 会走到城市 4。到达城 市 4 后，前面已没有可到达的城市，所以旅行结束。

如果从城市 2 出发，可以到达的城市为 3,4，这两个城市与城市 2 的距离分别为 2,1，由 于城市 3 离城市 2 第二近，所以小 A 会走到城市 3。到达城市 3 后，前面尚未旅行的城市为 4，所以城市 4 离城市 3 最近，但是如果要到达城市 4，则总路程为 2+3=5>3，所以小 B 会 直接在城市 3 结束旅行。

如果从城市 3 出发，可以到达的城市为 4，由于没有离城市 3 第二近的城市，因此旅行 还未开始就结束了。
如果从城市 4 出发，没有可以到达的城市，因此旅行还未开始就结束了。

数据范围

对于30%的数据，有1≤N≤20，1≤M≤20；
对于40%的数据，有1≤N≤100，1≤M≤100；
对于50%的数据，有1≤N≤100，1≤M≤1,000；
对于70%的数据，有1≤N≤1,000，1≤M≤10,000；
对于100%的数据，有1≤N≤100,000， 1≤M≤10,000， -1,000,000,000≤Hi≤1,000,000,000，
0≤X0≤1,000,000,000，1≤Si≤N，0≤Xi≤1,000,000,000，数据保证 Hi互不相同。

题解

第一问，枚举出发点S。第二问直接做。
可以想到把每个点右边最近和次近的点用pr[0..1,1..n]预处理出来。
预处理有很多种解法，比如线段树，平衡树之类的。我用的是链表。
首先按照城市高度排个序，把原来排序后的城市序号链起来。对于第i个城市（必须从1到n做），与它最近和次近的城市便是这个链中左边两个和右边两个的城市中的两个。找完后，把第i个城市在链表中删掉就行了。
接着可以想到一个一个点往右模拟，那么时间复杂度为O(n)。第一问为O(n^2)，第二位为O(mn)，超时。
一定要一个一个点模拟吗？显然不是。可以用倍增来解决。
我把A往右走一步之后B再往右走一步称为走一组。
F[i,j]表示从i点出发，走了2^i组后到达的店。
G[i,j,0..1]表示A和B分别从i出发走了2^i组走过的路程。
F和G的预处理用类似RMQ的做法就行了。
枚举一次j，就可以走完了。log2(n)大约为17，所以时间复杂度为O(17)，第一问为O(17n)，第二位为O(17m)。就可以解决了。

代码

var
    x,i,j,k,l,n,t,mx,mx2,m,s,ans2:longint;
    ans:double;
    aa,bb:int64;
    h1:array[1..101000,1..2] of longint;
    b:array[1..101000] of longint;
    h:array[0..101000] of int64;
    pre:array[0..101000] of record
                             up,next,data:longint;
                             end;
    pr:array[0..1,1..101000] of int64;
    p:array[1..4] of longint;
    f:array[1..101000,0..20] of longint;
    g:array[1..101000,0..20,0..2] of int64;
procedure px(i,j:longint);
var
    l,r,m:longint;
    t:array[1..2] of longint;
begin
    l:=i;r:=j;m:=h1[(i+j)div 2,1];
    repeat
        while h1[i,1]<m do inc(i);
        while h1[j,1]>m do dec(j);
        if i<=j then
        begin
            t:=h1[i];h1[i]:=h1[j];h1[j]:=t;
            inc(i);dec(j);
        end;
    until i>j;
    if l<j then px(l,j);
    if i<r then px(i,r);
end;
procedure doit;
var
    j:longint;
begin
    for j:=trunc(ln(n)/ln(2)) downto 0 do
    if (f[i,j]<=n)and(f[i,j]<>0) then
    begin
        if aa+bb+g[i,j,0]+g[i,j,1]<=x then
        begin
            aa:=aa+g[i,j,0];bb:=bb+g[i,j,1];
            i:=f[i,j];
        end;
    end;
    if (pr[0,i]<=n)and(pr[0,i]<>0) then
    begin
        if aa+bb+g[i,0,0]<=x then
        begin
            aa:=aa+g[i,0,0];
        end;
    end;
end;
begin
    assign(input,'drive.in'); reset(input);
    assign(output,'drive.out'); rewrite(output);
    read(n);
    for i:=1 to n do begin read(h1[i,1]);h[i]:=h1[i,1];h1[i,2]:=i;end;
    h[0]:=maxlongint;h[n+1]:=maxlongint;h[n+2]:=-maxlongint;
    px(1,n);
    for i:=1 to n do
    begin
        if i<>1 then pre[i].up:=i-1;
        if i<>n then pre[i].next:=i+1;
        pre[i].data:=h1[i,2];
        b[h1[i,2]]:=i;
    end;
    for i:=1 to n do
    begin
        mx:=n+1;mx2:=n+1;
        j:=b[i];
        pre[0].up:=0;pre[0].next:=0;
        p[3]:=pre[pre[j].up].data;p[1]:=pre[pre[j].next].data;
        p[2]:=pre[pre[pre[j].next].next].data;p[4]:=pre[pre[pre[j].up].up].data;
        for k:=1 to 4 do
        if p[k]>i then
        begin
            if abs(h[p[k]]-h[i])<=abs(h[mx]-h[i])then begin mx2:=mx;mx:=p[k];end
            else if abs(h[p[k]]-h[i])<=abs(h[mx2]-h[i])then mx2:=p[k];
        end;
        pr[1,i]:=mx;pr[0,i]:=mx2;
        pre[pre[j].up].next:=pre[j].next;
        pre[pre[j].next].up:=pre[j].up;
    end;
    for j:=0 to trunc(ln(n)/ln(2)) do
    begin
        for i:=1 to n-1<<j do
        begin
            if j=0 then
            begin
                f[i,j]:=pr[1,pr[0,i]];
                g[i,j,0]:=abs(h[pr[0,i]]-h[i]);
                g[i,j,1]:=abs(h[pr[1,pr[0,i]]]-h[pr[0,i]]);
            end
            else
            begin
                f[i,j]:=f[f[i,j-1],j-1];
                g[i,j,0]:=g[f[i,j-1],j-1,0]+g[i,j-1,0];
                g[i,j,1]:=g[f[i,j-1],j-1,1]+g[i,j-1,1];
            end;
        end;
    end;
    //-----------pre
    read(x);ans:=maxlongint;ans2:=n+2;
    for s:=1 to n do
    begin
        i:=s;aa:=0;bb:=0;
        doit;
        if (bb<>0)and(aa/bb<ans) then begin ans:=aa/bb;ans2:=s;end
        else if(bb<>0)and(aa/bb=ans)and(h[s]>h[ans2]) then ans2:=s ;
    end;
    writeln(ans2);
    read(m);
    while m>0 do
    begin
        dec(m);
        read(i,x);
        aa:=0;bb:=0;
        doit;
        writeln(aa,' ',bb);
    end;
    close(input);close(output);
end.