[转]cursor 与refcursor及sys_refcursor的区别

转自：http://blog.csdn.net/Phoenix_99/article/details/5825926

 

今天简单的总结一下PL/SQL中cursor(光标/游标)的用法。

相信不少做开发或维护的DBA在找工作的时候，遇到过类似的面视问题：请简单的描述一下光标的类型，说一下普通光标和REF光标之间的区别，以及什么时候该正确应用哪一个?　

这 个题目，我着实难住了不少人，其实他们在具体开发的时候，也还是比较能够把握正确的光标的使用的，但就是说不出来，当然了，这与大家自身的沟流交通能力是 有关系的。有的人不善于说，但做的却很好。扯的扯就走远了，最后唠叨一下：做技术这条路，能干不能说，或者说会干不会包装，路是走不"远"的。


一、显式cursor

显式是相对与隐式cursor而言的，就是有一个明确的声明的cursor。显式游标的声明类似如下（详细的语法参加plsql ref doc ）：

cursor cursor_name (parameter list) is select ...

游 标从declare、open、fetch、close是一个完整的生命旅程。当然了一个这样的游标是可以被多次open进行使用的，显式cursor是 静态cursor，她的作用域是全局的，但也必须明白，静态cursor也只有pl/sql代码才可以使用她。下面看一个简单的静态显式cursor的示 例：

declare
          cursor get_gsmno_cur (p_nettype in varchar2) is
             select gsmno
                from gsm_resource
                where nettype=p_nettype and status='0';
           v_gsmno gsm_resource.gsmno%type;
        begin
           open get_gsmno_cur('139');
           loop
                fetch get_gsmno_cur into v_gsmno;
                exit when get_gsmno_cur%notfound;       
                dbms_output.put_line(v_gsmno);
           end loop;
           close emp_cur;
          
           open get_gsmno_cur('138');
           loop
                fetch get_gsmno_cur into v_gsmno;
                exit when get_gsmno_cur%notfound;       
                dbms_output.put_line(v_gsmno);
           end loop;
           close get_gsmno_cur;
        end;
        /

上面这段匿名块用来实现选号的功能，我们显式的定义了一个get_gsmno_cur，然后根据不同的号段输出当前系统中该号短对应的可用手机号码。当然了，实际应用中没人这么用的，我只是用来说应一个显式cursor的用法。

二、隐式cursor

隐式cursor当然是相对于显式而言的，就是没有明确的cursor的declare。在Oracle的PL/SQL中，所有的DML操作都被Oracle内部解析为一个cursor名为SQL的隐式游标，只是对我们透明罢了。

另外，我们前面提到的一些循环操作中的指针for 循环，都是隐式cursor。　

隐式cursor示例一：

CREATE TABLE zrp (str VARCHAR2(10));
        insert into zrp values ('ABCDEFG');
        insert into zrp values ('ABCXEFG');
        insert into zrp values ('ABCYEFG');
        insert into zrp values ('ABCDEFG');
        insert into zrp values ('ABCZEFG');
        COMMIT;
       
        SQL> begin
          2    update zrp SET str = 'updateD' where str like '%D%';
          3    ifSQL%ROWCOUNT= 0 then
          4      insert into zrp values ('1111111');
          5    end if;
          6 end;
          7 /
       
        PL/SQL procedure successfully completed
       
        SQL> select * from zrp;
       
        STR
        ----------
        updateD
        ABCXEFG
        ABCYEFG
        updateD
        ABCZEFG
       
        SQL>
        SQL> begin
          2    update zrp SET str = 'updateD' where str like '%S%';
          3    ifSQL%ROWCOUNT= 0 THEN
          4      insert into zrp values ('0000000');
          5    end if;
          6 end;
          7 /
       
        PL/SQL procedure successfully completed
       
        SQL> select * from zrp;
       
        STR
        ----------
        updateD
        ABCXEFG
        ABCYEFG
        updateD
        ABCZEFG
        0000000
       6 rows selected
       
        SQL>

隐式cursor示例二：

begin
          for rec in (select gsmno,status from gsm_resource) loop
              dbms_output.put_line(rec.gsmno||'--'||rec.status);
          end loop;
        end;
        /

三、REFcursor

Ref cursor属于动态cursor(直到运行时才知道这条查询)。

从 技术上讲，在最基本的层次静态cursor和ref cursor是相同的。一个典型的PL/SQL光标按定义是静态的。Ref光标正好相反，可以动态地打开，或者利用一组SQL静态语句来打开，选择哪种方 法由逻辑确定（一个IF/THEN/ELSE代码块将打开一个或其它的查询）。例如，下面的代码块显示一个典型的静态SQL光标，光标C。此外，还显示了 如何通过使用动态SQL或静态SQL来用ref光标（在本例中为L_CURSOR）来打开一个查询：

Declare
      type rc is ref cursor;
      cursor c is select * from dual;
     
      l_cursor rc;
    begin
      if (to_char(sysdate,'dd') = 30) then
          -- ref cursor with dynamic sql
          open l_cursor for 'select * from emp';
      elsif (to_char(sysdate,'dd') = 29) then
          -- ref cursor with static sql
          open l_cursor for select * from dept;
      else
           -- with ref cursor with static sql
           open l_cursor for select * from dual;
      end if;
      -- the "normal" static cursor
      open c;
    end;
    /

在这段代码块中，可以看到了最显而易见的区别：无论运行多少次该代码块，光标C总是select * from dual。相反，ref光标可以是任何结果集，因为"select * from emp"字符串可以用实际上包含任何查询的变量来代替。

在上面的代码中，声明了一个弱类型的REF cursor，下面再看一个强类型（受限）的REF cursor，这种类型的REF cursor在实际的应用系统中用的也是比较多的。

create table gsm_resource
    (
      gsmno varchar2(11),
      status varchar2(1),
      price number(8,2),
      store_id varchar2(32)
    );
    insert into gsm_resource values('13905310001','0',200.00,'SD.JN.01');
    insert into gsm_resource values('13905312002','0',800.00,'SD.JN.02');
    insert into gsm_resource values('13905315005','1',500.00,'SD.JN.01');
    insert into gsm_resource values('13905316006','0',900.00,'SD.JN.03');
    commit;
   
    SQL> declare
      2     type gsm_rec is record(
      3          gsmno varchar2(11),
      4          status varchar2(1),
      5          price number(8,2));
      6
      7     type app_ref_cur_type is ref cursor return gsm_rec;
      8     my_cur app_ref_cur_type;
      9     my_rec gsm_rec;
     10
     11 begin
     12     open my_cur for select gsmno,status,price
     13          from gsm_resource
     14          where store_id='SD.JN.01';
     15     fetch my_cur into my_rec;
     16     while my_cur%found loop
     17           dbms_output.put_line(my_rec.gsmno||'#'||my_rec.status||'#'||my_rec.price);
     18           fetch my_cur into my_rec;
     19     end loop;
     20     close my_cur;
     21 end;
     22 /
   
    13905310001#0#200
    13905315005#1#500
   
    PL/SQL procedure successfully completed
   
    SQL>

普通cursor与REF cursor还有一些大家应该都熟悉的区别，我再浪费点唾沫。

1）PL/SQL静态光标不能返回到客户端，只有PL/SQL才能利用它。ref光标能够被返回到客户端，这就是从Oracle的存储过程返回结果集的方式。

2）PL/SQL静态光标可以是全局的，而ref光标则不是。 也就是说，不能在包说明或包体中的过程或函数之外定义ref光标。 只能在定义ref光标的过程中处理它，或返回到客户端应用程序。

3）ref光标可以从子例程传递到子例程，而光标则不能。 为了共享静态光标，必须在包说明或包体中把它定义为全局光标。 因为使用全局变量通常不是一种很好的编码习惯，因此可以用ref光标来共享PL/SQL中的光标，无需混合使用全局变量。

最后，使用静态光标--通过静态SQL（但不用ref光标）--比使用ref光标效率高，而ref光标的使用仅限于以下几种情况：

把结果集返回给客户端；
在多个子例程之间共享光标（实际上与上面提到的一点非常类似）；
没有其他有效的方法来达到你的目标时，则使用ref光标，正如必须用动态SQL时那样；

简言之，首先考虑使用静态SQL，只有绝对必须使用ref光标时才使用ref光标，也有人建议尽量使用隐式游标，避免编写附加的游标控制代码（声明，打开，获取，关闭），也不需要声明变量来保存从游标中获取的数据。这个就因人因具体的case大家去酌定吧。

四、游标属性

%FOUND： bool - TRUE if >1 row returned
%NOTFOUND：bool - TRUE if 0 rows returned
%ISOPEN： bool - TRUE if cursor still open
%ROWCOUNT：int - number of rows affected by last SQL statement

注：NO_DATA_FOUND和%NOTFOUND的用法是有区别的，小结如下：
1）SELECT . . . INTO 语句触发 NO_DATA_FOUND；
2）当一个显式光标的 where 子句未找到时触发 %NOTFOUND；
3）当UPDATE或DELETE 语句的where 子句未找到时触发 SQL%NOTFOUND；
4）在光标的提取(Fetch)循环中要用 %NOTFOUND 或%FOUND 来确定循环的退出条件，不要用NO_DATA_FOUND。

 

五、sys_refcursor

 sys_refcursor是oracle9i以后系统定义的一个refcursor,主要用在过程中返回结果集。

 

例：

SQL> conn scott/tiger@vongates
connected.
SQL> create or replace procedure getEmpByDept(in_deptNo in emp.deptno%type,
2 out_curEmp out SYS_REFCURSOR ) as
3
4 begin
5 open out_curEmp for
6 SELECT * FROM emp WHERE deptno = in_deptNo ;
7 EXCEPTION
8 WHEN OTHERS THEN
9 RAISE_APPLICATION_ERROR(-20101,
10 'Error in getEmpByDept' || SQLCODE );
12 end getEmpByDept;
13 /

已建立程序.

SQL> var rset refcursor;
SQL> exec getEmpByDept(10,:rset);

PL/SQL 程序順利完成.

SQL> print rset;