VBA-JC第7节|过程与函数

最近更新:'2019-05-14'

子过程与模块化程序设计

函数设计、自定义公式

1. 子过程与模块化程序设计

1. 1案例1:计算每张成绩表的C2单元格数字

将工作表张三,李四,王五,赵六各科的成绩求和分别汇总到对应工作表的C2单元格

1. 2案例2:导入总分榜

将张三,李四,王五,赵六的工作表的C2,B2单元格分别汇总到总分榜工作表,具体如下截图

1. 3案例1和案例2的合并:计算每张成绩表的C2单元格数字,导入总分榜

以下是使用不同的方法,但是结果是一样的

1. 3.1方案1

Sub allscore()
    
    Dim i, k, j, s
    Dim wPerson As Worksheet, wAll As Worksheet
    
    Set wAll = Worksheets("总分榜")
    k = 2
    
    For i = 1 To Worksheets.Count
        Set wPerson = Worksheets(i)
        s = 0
        For j = 2 To 10
            s = s + wPerson.Cells(j, 2)
        Next j
        wPerson.Cells(2, 3) = s
        If wPerson.name <> "总分榜" Then
            wAll.Cells(k, 1) = wPerson.Cells(1, 2)
            wAll.Cells(k, 2) = wPerson.Cells(2, 3)
                
            k = k + 1
        End If
    
    Next i
    
End Sub

1. 3.2方案2

使用call调用函数

Sub sumAll()
    Dim i, j, s
    Dim w1 As Worksheet
    For i = 1 To Worksheets.Count
        Set w1 = Worksheets(i)
        s = 0
        For j = 2 To 10
            s = s + w1.Cells(j, 2)
        Next j
        w1.Cells(2, 3) = s
    Next i
    
End Sub

Sub allscore()
    Dim wPerson As Worksheet, wAll As Worksheet, i, k
    
    Call sumAll
    
    Set wAll = Worksheets("总分榜")
    k = 2
    For i = 1 To Worksheets.Count
        Set wPerson = Worksheets(i)
        If wPerson.name <> "总分榜" Then
            wAll.Cells(k, 1) = wPerson.Cells(1, 2)
            wAll.Cells(k, 2) = wPerson.Cells(2, 3)
            k = k + 1
        End If
    Next i
End Sub

call调用函数的使用,具体可以参见如下截图:

1. 3.3方案3

Option Explicit
Sub 汇总及登记()

 Call sumAll
 Call allscore
 
End Sub

Sub sumAll()
    Dim i, j, s
    Dim w1 As Worksheet
    For i = 1 To Worksheets.Count
        Set w1 = Worksheets(i)
        s = 0
        For j = 2 To 10
            s = s + w1.Cells(j, 2)
        Next j
        w1.Cells(2, 3) = s
    Next i
    
End Sub

Sub allscore()
    Dim wPerson As Worksheet, wAll As Worksheet, i, k
    
    Set wAll = Worksheets("总分榜")
    k = 2
    For i = 1 To Worksheets.Count
        Set wPerson = Worksheets(i)
        If wPerson.name <> "总分榜" Then
            wAll.Cells(k, 1) = wPerson.Cells(1, 2)
            wAll.Cells(k, 2) = wPerson.Cells(2, 3)
            k = k + 1
        End If
    Next i
End Sub

1.4过程调用

1.4.1过程概念

什么叫过程呢?是一段代码,有开头和结尾并且有自己的名字.

一般会任务sub...end sub叫做宏,但是从代码的角度看，宏就是用VBA编写的一个过程。

1.4.2使用过程的优点

如果程序比较复杂的话,使用宏会非常的方便,具体优点如下:
1.代码清晰,易于维护
2.灵活扩展，轻松修改

运用了子过程调用，可以灵活的修改功能。
没有使用子过程，只能笨拙的复制粘贴，没有灵活性！

代码重用，提高效率
把可能被多次使用的代码，写成过程供其他程序调用！

注意事项:
1.调用过程的时候,可以把call忽略,直接写过程的名称即可.

2.函数设计、自定义公式

函数：过程的一种在执行结束后能将运行结果返回给调用者

2.1 案例1:根据特征指数,进行分类

Function 客户分类(score)
    
    Dim level

    If score < 30 Then
        level = "甲型"
    ElseIf score < 60 Then
        level = "乙型"
    ElseIf score < 90 Then
        level = "丙型"
    Else
        level = "丁型"
    End If
    
    客户分类 = level
    
End Function

Sub 暴力倾向分析()

    Dim i, score, level
    
    i = 3
    
    Do While Cells(i, 3)
    
        score = Cells(i, 3)
        
        level = 客户分类(score)
        
        Cells(i, 4) = level
        
        i = i + 1
        
    Loop
  
End Sub

2.2案例2:函数开发表格公式

通过函数开发自己的表格公式,比如,在D3单元格中直接写"=客户分类(C3)",就会根据C3单元格的分数直接显示"乙型"

注意事项:
1.不同过程中定义的变量，即使同名也互相无关
2.子程序（Sub）也可以使用参数，用法与函数完全相同。
3.参数可以有多个，每个之间用逗号隔开。