Unity Shader 实现模型描边

模型描边是一种比较常用的功能，通常用来表示选择的对象或者凸显角色。

QQ截图20170728110736.png

实现原理

shader使用两个pass渲染对象，第一个pass渲染模型背面，并且把顶点向法线方向移动，实现变大描边。另外一个pass按照普通的方式渲染正面。

实现方式

1 定义描边属性,定义描边的颜色和宽度

  Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        
        _OutLine ("OutLine ",Range(0,0.05))=0.01
        _OutLineColor("OutLineColor",Color)=(0,0,0,1)
    }

2 输入和输出的结构体只需要 顶点和法线

           struct a2v {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            }; 
            
            struct v2f {
                float4 pos : SV_POSITION;
            };

3 顶点函数中，先把顶点转换到摄像机空间，把法线转换到世界空间，然后进行顶点位移，最后才转换到裁切空间。

             v2f vert (a2v v) {
                v2f o;
                
                float4 pos = mul(UNITY_MATRIX_MV, v.vertex); 
                float3 normal = mul((float3x3)UNITY_MATRIX_IT_MV, v.normal);  
                normal.z = -0.5;
                pos = pos + float4(normalize(normal), 0) * _Outline;
                o.pos = mul(UNITY_MATRIX_P, pos);
                
                return o;
            }

4 片元着色器只需要输出颜色就可以了

float4 frag(v2f i) : SV_Target { 
               return float4(_OutlineColor.rgb, 1);               
           }

5 之后就是在另外一个pass 中实现普通的渲染就可以了。第一个pass 只渲染背面，第二个pass 只渲染前面。

完整shader 代码

Shader "Coustom/OutLine"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        
        _OutLine ("OutLine ",Range(0,0.05))=0.01
        _OutLineColor("OutLineColor",Color)=(0,0,0,1)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque"  "Queue"="Geometry"}
        LOD 100
        
        Pass{
            NAME "OUTLINE"
            
            Cull Front
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            
            float _OutLine;
            fixed4 _OutLineColor;
            
            struct a2v{
                 float4 vertex: POSITION;
                 float3 normal : NORMAL;
            };
            struct v2f{
                 float4 pos : SV_POSITION;
            };
            
            v2f vert(a2v v)
            {
                 v2f o;
                 float4 pos = mul(UNITY_MATRIX_MV, v.vertex);
                 float3 normal = mul( (float3x3)UNITY_MATRIX_IT_MV,v.normal);
                 //normal.z = -0.5f;
                 pos = pos+ float4( normalize(normal),0) * _OutLine;
                 
                 o.pos = mul(UNITY_MATRIX_P,pos);
                 
                 return o;
            }
            
            float4 frag(v2f i) : SV_Target {
                return float4(_OutLineColor.rgb,1);
            }
            
            ENDCG
        
        }

        Pass
        {
           
          // CULL Back
        
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);               
                return col;
            }
            ENDCG
        }
    }
}