核心公式
- （纹理采样）漫反射光 = 入射光线强度 * 纹素值 * 材质的漫反射系数 * 取值为正数 ( 表面法线方向 · 光源方向 ) ;
- （切线空间纹理映射）漫反射光 = 入射光线强度 * 纹素值 * 材质的漫反射系数 * 取值为正数 ( 切线光源方向 · 切线法线方向 ) ;
- （世界空间纹理映射）漫反射光 = 入射光线强度 * 纹素值 * 材质的漫反射系数 * 取值为正数 ( 世界光源方向 · 世界法线方向 ) ;
效果展示
纹理采样，切线空间纹理映射，世界空间纹理映射
纹理采样
Shader "Unlit/011"
{
Properties
{
_MainTex ("MainTex", 2D )= "white" {}
_Diffuse("Diffuse",Color) = (1,1,1,1)
_Specular("Specular",Color) = (1,1,1,1)
_Gloss("Gloss",Range(1,256)) = 5
}
SubShader
{
Tags { "RenderType"="Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
sampler2D _MainTex;
float4 _MainTex_ST;
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct v2f
{
float4 vertex :SV_POSITION;
fixed3 worldNormal: TEXCOORD0;
float3 worldPos : TEXCOORD1;
float2 uv : TEXCOORD2;
};
v2f vert (appdata_base v)
{
v2f o;
//顶点位置
o.vertex = UnityObjectToClipPos(v.vertex);
//法线方向
fixed3 worldNormal =UnityObjectToWorldNormal( v.normal);
o.worldNormal=worldNormal;
o.worldPos = mul(unity_ObjectToWorld, v.vertex);
//UV =顶点纹理坐标进行缩放+偏移
o.uv =TRANSFORM_TEX(v.texcoord, _MainTex);//v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
return o;
}
fixed4 frag (v2f i) : SV_Target
{
//纹素值=对纹理进行采样（采样纹理，float2纹理坐标）
fixed3 albedo = tex2D(_MainTex,i.uv).rgb;
//光源方向
fixed3 worldLightDir = UnityWorldSpaceLightDir(i.worldPos);
//漫反射光=入射光线强度*纹素值*材质的漫反射系数*取值为正数(表面法线方向 · 光源方向)
fixed3 diffuse = _LightColor0.rgb * albedo * _Diffuse.rgb * (dot(worldLightDir,i.worldNormal)*0.5+0.5);
//环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
//视角方向
fixed3 viewDir = normalize( UnityWorldSpaceViewDir(i.worldPos));
//半角方向
fixed3 halfDir =normalize(worldLightDir + viewDir);
//BlinnPhong高光反射=入射光线颜色强度*材质的高光反射系数*n次平方(取值为正数(法线方向 · 半角方向)，n）；
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(i.worldNormal,halfDir)),_Gloss);
fixed3 color = ambient + diffuse + specular;
return fixed4(color,1);
}
ENDCG
}
}
}
切线空间纹理映射
Shader "Unlit/012"
{
Properties
{
_MainTex ("MainTex", 2D )= "white" {}
_BumpMap ("normal Map", 2D) = "bump"{}
_BumpScale("Bump Scale",float) = 1
_Diffuse("Diffuse",Color) = (1,1,1,1)
_Specular("Specular",Color) = (1,1,1,1)
_Gloss("Gloss",Range(1,256)) = 5
}
SubShader
{
Tags { "RenderType"="Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct v2f
{
float4 vertex :SV_POSITION;
fixed3 lightDir: TEXCOORD0;
float3 viewDir: TEXCOORD1;
float2 uv : TEXCOORD2;
float2 normalUv: TEXCOORD3;
};
v2f vert (appdata_tan v)
{
v2f o;
//顶点位置
o.vertex = UnityObjectToClipPos(v.vertex);
//UV =顶点纹理坐标进行缩放+偏移
o.uv =TRANSFORM_TEX(v.texcoord, _MainTex);
//法线贴图UV =顶点纹理坐标进行缩放+偏移
o.normalUv =TRANSFORM_TEX(v.texcoord, _BumpMap);
////求副切线向量=叉乘（法线的模，切线的模）* 切线的W方向
//float3 binormal = cross(normalize(v.normal),normalize(v.tangent.xyz))*v.tangent.w;
////求模型空间到切线空间的变换矩阵
//float3x3 roatiton = float3(normalize(v.tangent.xyz,binormal,v.normal));
//内置宏，用于得到模型空间到切线空间的变换矩阵rotation
TANGENT_SPACE_ROTATION;
//求切线空间光源方向=矩阵乘积（变换矩阵，模型空间下光照方向）.xyz；
o.lightDir = mul(rotation,ObjSpaceLightDir (v.vertex)).xyz;
//求切线空间视角方向=矩阵乘积（变换矩阵，模型空间下视角方向）.xyz；
o.viewDir = mul(rotation,ObjSpaceViewDir (v.vertex)).xyz;
return o;
}
fixed4 frag (v2f i) : SV_Target
{
//切线空间光源方向
fixed3 tangentLightDir = normalize(i.lightDir);
//切线空间中视角方向
fixed3 tangentViewDir = normalize(i.viewDir);
//采样
fixed4 packedNormal = tex2D(_BumpMap,i.normalUv);
//切线中法线方向，没有设置成normalMap的
//fixed3 tangentNormal;
//tangentNormal.xy = ( packedNormal.xy * 2 - 1 ) * _BumpScale;
//tangentNormal.z = sqrt (1 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
//切线中法线方向，设置成normalMap的
fixed3 tangentNormal = UnpackNormal(packedNormal);
tangentNormal.xy *= _BumpScale;
//纹素值=对纹理进行采样（采样纹理，float2纹理坐标）
fixed3 albedo = tex2D(_MainTex,i.uv).rgb;
//漫反射光=入射光线强度*纹素值*材质的漫反射系数*取值为正数(切线光源方向 · 切线法线方向)
fixed3 diffuse = _LightColor0.rgb * albedo * _Diffuse.rgb * (dot(tangentLightDir,tangentNormal)*0.5+0.5);
//环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
//半角方向
fixed3 halfDir =normalize(tangentLightDir + tangentViewDir);
//BlinnPhong高光反射=入射光线颜色强度*材质的高光反射系数*n次平方(取值为正数(切线法线方向 · 半角方向)，n）；
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(tangentNormal,halfDir)),_Gloss);
fixed3 color = ambient + diffuse + specular;
return fixed4(color,1);
}
ENDCG
}
}
}
世界空间纹理映射
Shader "Unlit/013"
{
Properties
{
_MainTex ("MainTex", 2D )= "white" {}
_BumpMap ("normal Map", 2D) = "bump"{}
_BumpScale("Bump Scale",float) = 1
_Diffuse("Diffuse",Color) = (1,1,1,1)
_Specular("Specular",Color) = (1,1,1,1)
_Gloss("Gloss",Range(1,256)) = 5
}
SubShader
{
Tags { "RenderType"="Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct v2f
{
float4 vertex :SV_POSITION;
float4 uv : TEXCOORD0;
float4 TtiW0 : TEXCOORD1;
float4 TtiW1 : TEXCOORD2;
float4 TtiW2 : TEXCOORD3;
};
v2f vert (appdata_tan v)
{
v2f o;
//顶点位置
o.vertex = UnityObjectToClipPos(v.vertex);
//UV =顶点纹理坐标进行缩放+偏移
o.uv.xy =TRANSFORM_TEX(v.texcoord, _MainTex);
//法线贴图UV =顶点纹理坐标进行缩放+偏移
o.uv.zw =TRANSFORM_TEX(v.texcoord, _BumpMap);
//计算世界坐标下的顶点，法线，切线，副法线
float3 worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 worldBinormal = cross(worldNormal,worldTangent) * v.tangent.w;
//按列摆放得到从切线转世界空间的变换矩阵
o.TtiW0 = float4(worldTangent.x,worldBinormal.x,worldNormal.x,worldPos.x);
o.TtiW1 = float4(worldTangent.y,worldBinormal.y,worldNormal.y,worldPos.y);
o.TtiW2 = float4(worldTangent.z,worldBinormal.z,worldNormal.z,worldPos.z);
return o;
}
fixed4 frag (v2f i) : SV_Target
{
//求世界坐标
float3 worldPos = float3(i.TtiW0.w,i.TtiW1.w,i.TtiW2.w);
//计算世界空间下的光照方向和视角
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
//采样获得法线纹理
fixed4 packedNormal = tex2D(_BumpMap,i.uv.zw);
//切线中法线方向，设置成normalMap的
fixed3 tangentNormal = UnpackNormal(packedNormal);
tangentNormal.xy *= _BumpScale;
//切线空间法线转换到世界坐标
fixed3 worldNormal = normalize(float3(dot(i.TtiW0.xyz,tangentNormal),dot(i.TtiW1.xyz,tangentNormal),dot(i.TtiW2.xyz,tangentNormal)));
//纹素值=对纹理进行采样（采样纹理，float2纹理坐标）
fixed3 albedo = tex2D(_MainTex,i.uv.xy).rgb;
//漫反射光=入射光线强度*纹素值*材质的漫反射系数*取值为正数(世界光源方向 · 世界法线方向)
fixed3 diffuse = _LightColor0.rgb * albedo * _Diffuse.rgb * (dot(lightDir,worldNormal)*0.5+0.5);
//环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
//半角方向
fixed3 halfDir =normalize(lightDir + viewDir);
//BlinnPhong高光反射=入射光线颜色强度*材质的高光反射系数*n次平方(取值为正数(世界法线方向 · 半角方向)，n）；
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal,halfDir)),_Gloss);
fixed3 color = ambient + diffuse + specular;
return fixed4(color,1);
}
ENDCG
}
}
}