(二)命令行与QtCreator

Qt的编译方式之命令行编译

条件:Qt源代码文件

步骤:

启动Qt命令行Command prompt

进入源代码文件所在目录

输入命令

         (1)qmake–project   根据源码生成工程文件(.pro)

         (2)qmake                 根据工程文件生成makefile文件

         (3)make                      根据makefile进行编译

 

使用QtCreator开发环境编译

条件:Qt工程文件

步骤: 点击构建即可编译

 

Qt工程中的文件:
.pro  项目描述文件(Qt中与平台无关的Makefile文件，在不同平台生成不同的makefile)

.pro.user 用户配置描述文件(需要在不同计算机间移动源码时，应该删除此文件)

.h      头文件

.cpp 源文件

.ui 界面描述文件

资源文件(图片、音频等)

Qt工程文件(.pro)简介

QT += core gui						#声明会用到qt的核心模块、gui模块

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets		#如果qt的主版本大于4，还需要使用到widgets模块

TARGET = HelloWorld					#要生成的可执行文件名叫HelloWorld
TEMPLATE = app						#声明生成应用程序app类的makefile

INCLUDEPATH += E:/BCC/include \				#指明头文件搜索路径
               E:/VC/include

SOURCES += Main.cpp \					#源文件声明
           HelloWorld.cpp

HEADERS += HelloWorld.h					#头文件声明

FORMS   += HelloWorld.ui				#工程中包含的.ui界面描述文件

RC_FILE += MyIco.rc					#资源文件，此处是图标

LIBS    += -LE:/vlc-1.11/sdk/lib			#外部库所在路径

CONFIG  += warn_on debug				#设置配置信息与编译选项 此处是设置输出所有警告信息并构建可调式程序

#
# if 'debug' option is set for CONFIG
#
CONFIG(debug) {						#如果CONFIG文件设置了构建可调试程序会执行接下来的语句
    DEFINES += DEBUG_LOG				#定义一个宏DEBUG_LOG
    SOURCES += DebugLog.cpp				#编译时多加上两个文件DebugLog.cpp DebugLog.h
    HEADERS += DebugLog.h
}

基本部分

# 注释起始符

QT 模块声明

TARGET 可执行文件名

TEMPLATE 程序模板声明

SOURCES 源文件声明

HEADERS 头文件声明

FORMS 界面文件声明

RC_FILE 资源文件声明

高级变量

INCLUDEPATH 头文件搜索路径

CONFIG 设定项目的配置和编译选项

LIBS 添加第三方库文件

DEFINES 定义编译宏

 

注：项目文件中的描述都使用相对路径，且相对路径是相对于项目文件而言

 

 

 

 声明:

此文根据 狄泰学院唐老师的《QT实验分析教程》创作