课程设计2：编写一个可以自行启动计算机，不需要在现有操作系统环境中运行的程序
- （1）列出功能选项
1） reset pc ；重新启动计算机
2） start system ；引导现有的操作系统
3） clock ；进入时钟程序
4） set clock ；设置时间
- （2）用户输入“1”后重新启动计算机；
- （3）用户输入“2”后引导现有的操作系统；
- （4）用户输入“3”后，执行动态显示当前日期、时间的程序。
显示格式如下： 年/月/日 时:分:秒
进入此项功能后，一直动态显示当前的时间，在屏幕上将出现时间按秒变化的效果
当按下F1键后，改变显示颜色；按下ESC键后，返回到主选单；
- （5）用户输入“4”后可更改当前的日期、时间，更改后返回到主选单；
测试运行
![[094][汇编语言]课程设计2：（9）(完整源码)编写一个可以自行启动计算机，不需要在现有操作系统环境中运行的程序（完全版）_第1张图片](http://img.e-com-net.com/image/info10/552eba47a9f34dfdb6ba04c54b068c9c.jpg)
1、 开机后，看到主选单.PNG
![[094][汇编语言]课程设计2：（9）(完整源码)编写一个可以自行启动计算机，不需要在现有操作系统环境中运行的程序（完全版）_第2张图片](http://img.e-com-net.com/image/info10/1960d8b2d31c460fab1d8954ee4fa4ab.jpg)
2、按下按键3 进入选项3） 动态时钟.PNG
![[094][汇编语言]课程设计2：（9）(完整源码)编写一个可以自行启动计算机，不需要在现有操作系统环境中运行的程序（完全版）_第3张图片](http://img.e-com-net.com/image/info10/7f972c7e943a47668ce647b025b77b85.jpg)
3、动态时钟 F1键修改显示颜色 ESC键返回.PNG
![[094][汇编语言]课程设计2：（9）(完整源码)编写一个可以自行启动计算机，不需要在现有操作系统环境中运行的程序（完全版）_第4张图片](http://img.e-com-net.com/image/info10/683c67d8d06e4380a88443d707dda516.jpg)
4、 在主选单 按下按键4 进入选项4 通过键盘输入系统时间 按下 Enter 键 确认并返回主选单.PNG
![[094][汇编语言]课程设计2：（9）(完整源码)编写一个可以自行启动计算机，不需要在现有操作系统环境中运行的程序（完全版）_第5张图片](http://img.e-com-net.com/image/info10/ac6c134e994e4cc4b6791e967d92eef9.jpg)
5、再次进入动态时钟 查看最新的系统时间 时间已被修改.PNG
![[094][汇编语言]课程设计2：（9）(完整源码)编写一个可以自行启动计算机，不需要在现有操作系统环境中运行的程序（完全版）_第6张图片](http://img.e-com-net.com/image/info10/b620aac7bbba4442a485d3abf95b7f21.png)
6、在主选单 按下 按键1 VMware 重新启动 实现计算机的重启.png
![[094][汇编语言]课程设计2：（9）(完整源码)编写一个可以自行启动计算机，不需要在现有操作系统环境中运行的程序（完全版）_第7张图片](http://img.e-com-net.com/image/info10/24c1dba83ae44753a89e64ef5b6ad92e.jpg)
7、在主选单 按下 按键2 对现有的操作系统进行引导 进入现有的操作系统XP.PNG
完整源码
bootcode.asm 文件
assume cs:code
data segment
db 512 dup (0)
data ends
code segment
start: mov ax,cs
mov ds,ax
mov si, offset boot
mov ax,data
mov es,ax
mov di,0
mov cx,offset bootend - offset boot
cld
rep movsb
jmp short write
boot: jmp short bootstart
db 10 dup(0)
; 引导程序 boot 将被安装到内存data开始
; 引导程序的功能: 1.读扇区 将 任务程序task 0面0道2扇区 写到内存 0000:7E00H;
; 2.将CS:IP指向 0000:7E00H
bootstart:
mov ax,cs
mov ss,ax
mov sp,10
mov ax,0
mov es,ax
mov bx,7E00H
mov al,3 ; 扇区数
mov ch,0
mov cl,2
mov dl,0
mov dh,0
mov ah,2
int 13h
mov bx,0
push bx
mov bx,7E00H
push bx
retf
bootend: nop
write:
; 利用 int 13H 中断
; 将内存 data 处的引导程序 boot
; 写入 软盘A 0面 0道 1扇区
mov ax,data
mov es,ax
mov bx,0
mov al,1 ; 引导扇区固定只占用1个扇区
mov ch,0
mov cl,1
mov dl,0
mov dh,0
mov ah,3
int 13h
mov ax,4c00H
int 21H
code ends
end start
taskcode.asm 文件
assume cs:code
data segment
db 1536 dup (0)
data ends
code segment
start:
call setup
call write
mov ax,4c00h
int 21H
setup:
; 任务程序 安装步骤
; 将任务程序机器码安装到data段开辟的内存空间
mov ax,cs
mov ds,ax
mov si, offset task
mov ax,data
mov es,ax
mov di,0
mov cx,offset taskend - offset task
cld
rep movsb
ret
write:
; 利用 int 13H 中断
; 将内存 data 处的任务程序
; 写入 软盘A 0面 0道 2扇区
mov ax,data
mov es,ax
mov bx,0
mov al,3 ; 扇区数
mov ch,0
mov cl,2
mov dl,0
mov dh,0
mov ah,3
int 13h
ret
;--------------------------------------------------------------
; 任务程序 开始
; 任务程序 从 标号 task 开始 到 标号 taskend 结束
;--------------------------------------------------------------
task: jmp short taskstart
menu_1 db '1) reset pc',0
menu_2 db '2) start system',0
menu_3 db '3) clock',0
menu_4 db '4) set clock',0
menu_address dw offset menu_1 - offset task + 7E00H
dw offset menu_2 - offset task + 7E00H
dw offset menu_3 - offset task + 7E00H
dw offset menu_4 - offset task + 7E00H
;stack db 50 dup(0)
time db 9,8,7,4,2,0
blank db '// ::'
adddata dw 0,0
aESC db 0
taskstart:
call init_reg
call clear_screen
call toppage
call helptop
jmp short key_toppage
mov ax,4c00h
int 21H
;--------------------------------------------------------------
; 选项控制: key_toppage
; 功能: 针对首页 toppage 的键盘操作
; 实现： 使用 BIOS int 16h 0号功能，读取一个键盘输入
; 返回值 (ah) = 扫描码 , (al) = ASCII码
; 键 1 2 3 4
; 扫描码 02 03 04 05
;--------------------------------------------------------------
key_toppage: mov ah,0
int 16h
cmp ah,02H
je key1
cmp ah,03h
je key2
cmp ah,04h
je key3
cmp ah,05h
je key4
; 本意是，这时候读取的输入，如果不是1234就忽略，再读取一个
jmp short key_toppage
key1: jmp short resetpc
;jmp short taskstart
key2: jmp short startsystem
;jmp short taskstart
key3: call clock
jmp short taskstart
key4: call setclock
jmp short taskstart
;--------------------------------------------------------------
; 选项 1)
;--------------------------------------------------------------
; 子程序：resetpc
; 功能： 重新启动计算机
;--------------------------------------------------------------
resetpc: ; jmp ffff:0000h
mov ax,0FFFFH
push ax
mov ax,0
push ax
retf ; pop IP pop cs
;--------------------------------------------------------------
; 选项 2)
;--------------------------------------------------------------
; 子程序：startsystem
; 功能： 引导现有的操作系统
; 实现: 1. 读取硬盘C盘 0面0道1扇区的内容到 0000:7C00H
; 2. 将CS:IP 指向0000:7C00H
;--------------------------------------------------------------
startsystem: call clear_screen
mov bx,0
mov es,bx
mov bx,7C00H
mov al,1 ; 扇区数
mov ch,0 ; 磁道 0
mov cl,1 ; 扇区 1
mov dl,80H ; 硬盘C: 80H
mov dh,0 ; 面 0
mov ah,2 ; 读扇区
int 13H
; jmp 0000:7C00H
mov bx,0
push bx
mov bx,7C00H
push bx
retf ; POP IP POP CS
;--------------------------------------------------------------
; 选项 3)
;--------------------------------------------------------------
; 子程序：clock
; 功能： 循环显示当前时间
; F1键-改变显示颜色
; ESC键-返回到主选单
;--------------------------------------------------------------
clock: call clear_screen
call help3
call clockstart
ret
;--------------------------------------------------------------
; 子程序：clockstart
; 功能： 循环显示当前时间
;--------------------------------------------------------------
clockstart: ;ds = 0
push bx
push ax
; (int 9H)1、将原始的int 9H 入口地址保存到新开辟的 adddata 表中，
; 以便日后模拟指令的调用和还原；
mov bx,offset adddata - offset task + 7E00H
push ds:[9*4]
pop ds:[bx]
push ds:[9*4+2]
pop ds:[bx+2]
; (int 9H)2、设置新的int 9H 的入口地址；
cli ; TF = 0
mov word ptr ds:[9*4],offset int9 - offset task + 7E00H
mov word ptr ds:[9*4+2],cs
sti ; TF = 1
mov bx,offset aESC - offset task + 7E00H
mov byte ptr ds:[bx],0
mov ah,'a'
dateloop: call date
mov al,ds:[bx]
cmp al,01H
je clockend
call delay
cmp ah,'z'
jna dateloop
clockend: ; (int 9H)5、还原原始的int 9H 入口地址；
mov bx,offset adddata - offset task + 7E00H
cli ; TF = 0
push ds:[bx]
pop ds:[9*4]
push ds:[bx+2]
pop ds:[9*4+2]
sti ; TF = 1
pop ax
pop bx
ret
;--------------------------------------------------------------
delay: push ax
push dx
mov dx,0003H
mov ax,0
s1: sub ax,1
sbb dx,0
cmp ax,0
jne s1
cmp dx,0
jne s1
pop dx
pop ax
ret
;--------------------------------------------------------------
int9: push bx
in al,60H
pushf
pushf
pop bx
and bh,11111100B
push bx
popf
; (int 9H)3、模拟对原始 int 9H 指令的调用；
mov bx,offset adddata - offset task + 7E00H
call dword ptr ds:[bx]
; (int 9H)4、编写代码，实现指定按键的功能；
cmp al,01H ; ESC
jne maybeF1
mov bx,offset aESC - offset task + 7E00H
mov ds:[bx],al
maybeF1: cmp al,3BH ; F1
jne int9ret
call changcolor
int9ret: pop bx
iret
;--------------------------------------------------------------
; 子程序：changcolor
; 功能： 改变显示颜色
;--------------------------------------------------------------
changcolor: push cx
push bx
mov bx,1
mov cx,2000
colors: inc byte ptr es:[bx]
add bx,2
loop colors
pop bx
pop cx
ret
;--------------------------------------------------------------
; 子程序：date
; 功能： 显示当前时间
;--------------------------------------------------------------
date:
push di
push si
push cx
push ax
mov di,160*10+20*2
mov si,offset time - offset task + 7E00H
mov cx,6
showdate: push cx
mov al,[si]
out 70H,al
in al,71H
mov ah,al
mov cl,4
shr ah,cl
and al,00001111B
add ah,30H
add al,30H
mov byte ptr es:[di],ah
mov byte ptr es:[di+2],al
add di,6
inc si
pop cx
loop showdate
mov di,160*10+20*2
mov si,offset blank - offset task + 7E00H
mov cx,5
showblank: push cx
mov al,[si]
mov byte ptr es:[di+4],al
add di,6
inc si
pop cx
loop showblank
dateend: pop ax
pop cx
pop si
pop di
ret
;--------------------------------------------------------------
; 选项 4）
;--------------------------------------------------------------
; 子程序：setclock
; 功能： 选项 4）的入口
;--------------------------------------------------------------
setclock: call clear_screen
call clear_stack
call blankdraw
call help4
call getstr
call changeclock
ret
;--------------------------------------------------------------
; 子程序： clear_stack
; 功能： 每一次重新进入选项4)，就清空一次时间数据栈
; 实现: 通过将栈顶偏移量置为0实现，“清空栈”
;--------------------------------------------------------------
clear_stack: push di
push bx
mov di,offset top - offset task + 7E00H
mov bx,0
mov ds:[di],bx
pop di
pop bx
ret
;--------------------------------------------------------------
; 子程序：blankdraw
; 功能： 在屏幕上画出' / / : : '
; 提示用户输入时间
;--------------------------------------------------------------
; '123456789012'
timeblank db ' / / : : '
format db 'yymmddhhmmss'
blankdraw: push bx
push di
push ax
push cx
push bp
; 闪烁的图标确定输入位置
mov di,160*10+20*2
mov byte ptr es:[di],'_'
mov al,11110000B
mov es:[di+1],al
mov bx,offset timeblank - offset task + 7E00H
mov bp,offset format - offset task + 7E00H
mov cx,12
blankdrawloop: mov al,ds:[bx]
mov es:[di+2],al
mov al,03H
mov es:[di+3],al
mov al,ds:[bp]
mov byte ptr es:[di-160],al
mov al,04H
mov byte ptr es:[di-160+1],al
inc bx
inc bp
add di,4
loop blankdrawloop
pop bp
pop cx
pop ax
pop di
pop bx
ret
;--------------------------------------------------------------
;--------------------------------------------------------------
; 子程序：changeclock
; 功能： 修改系统时间
; 实现： 利用CMOS RAM端口70H、71H向对应单元送入时间数据
;--------------------------------------------------------------
changeclock: jmp short clockon
unit db 9,8,7,4,2,0
;timestack db 13 dup(0) ; 年月日 时分秒 + 0（最后压入）
clockon: push si
push bx
push cx
push ax
mov si,offset timestack - offset task + 7E00H
mov bx,offset unit - offset task + 7E00H
mov cx,6
clockonloop: push cx
mov al,ds:[si]
sub al,30H
mov cl,4
shl al,cl
mov ah,ds:[si+1]
sub ah,30H
add ah,al
mov al,ds:[bx] ; 取单元号
out 70H,al
mov al,ah ; 将单元号送入 CMOS RAM
out 71H,al ; 向指定单元号写入数据
inc bx
add si,2
pop cx
loop clockonloop
pop ax
pop cx
pop bx
pop si
ret
;--------------------------------------------------------------
;--------------------------------------------------------------
; 子程序： 字符串输入
;（1）、调用16H读取键盘输入
;（2）、如果是字符，进入字符栈，显示字符栈中的所有字符；继续执行 （1）
;（3）、如果是退格键，从字符栈中弹出一个字符，显示字符栈中的所有字符来，继续执行（1）
;（4）、如果是enter键，向字符栈中压入一个0，返回。
;--------------------------------------------------------------
getstr: push ax
getstrs: mov ah,0
int 16H
cmp al,20H
jb nochar ; ASCII码小于20H，说明不是字符
mov ah,0
call charstack ;字符入栈
mov ah,2
call charstack ;显示栈中的字符
jmp getstrs
nochar: cmp ah,0eh ;退格键的扫描码
je backspace
cmp ah,1ch ;Enter键的扫描码
je enter2
jmp getstrs
backspace: mov ah,1
call charstack ;字符出栈
mov ah,2
call charstack ;显示栈中的字符
jmp getstrs
enter2: mov al,0
mov ah,0
call charstack ;0 入栈
mov ah,2
call charstack ;显示栈中的字符
pop ax
ret
;--------------------------------------------------------------
; 字符栈的入栈、出栈和显示
; 参数： （ah）=功能号，0表示入栈，1表示出栈，2表示显示
; ds:si 指向字符栈空间
; 对于0号功能，（al）=入栈字符
; 对于1号功能，（al）=返回字符串
; 对于2号功能，（dh）、（dl）=字符串在屏幕上显示的行、列位置
;--------------------------------------------------------------
charstack: jmp short charstart
table dw offset charpush - offset task + 7E00H,offset charpop - offset task + 7E00H,offset charshow - offset task + 7E00H
top dw 0 ;栈顶
timestack db 13 dup(0) ; 年月日 时分秒 + 0（最后压入）
charstart: push bx
push dx
push di
push es
push bp
cmp ah,2
ja sret
mov bl,ah
mov bh,0
add bx,bx
mov di,offset table - offset task + 7E00H
jmp word ptr ds:[di+bx]
;--------------------------------------------------------------
charpush: mov di,offset top - offset task + 7E00H
mov bx,ds:[di]
mov si,offset timestack - offset task + 7E00H
mov ds:[si][bx],al
inc bx
mov ds:[di],bx
jmp sret
;--------------------------------------------------------------
charpop: mov di,offset top - offset task + 7E00H
mov bx,ds:[di]
cmp bx,0
je sret
dec bx
mov ds:[di],bx
mov bx,ds:[di]
mov si,offset timestack - offset task + 7E00H
mov al,ds:[si][bx]
jmp sret
;--------------------------------------------------------------
charshow: mov di,160*10+20*2
mov bx,0
charshows: mov bp,offset top - offset task + 7E00H
cmp bx,ds:[bp]
jne noempty
mov byte ptr es:[di],' '
jmp sret
noempty: mov si,offset timestack - offset task + 7E00H
mov al,ds:[si][bx] ; bx = 0 表示栈底
mov es:[di],al
mov al,02H
mov es:[di+1],al ; 设置颜色属性 为绿色
mov byte ptr es:[di+4],'_'
mov al,11110000B
mov byte ptr es:[di+5],al
inc bx
add di,4
jmp charshows
;--------------------------------------------------------------
sret: pop bp
pop es
pop di
pop dx
pop bx
ret
;--------------------------------------------------------------
; 选项4） 结束
;--------------------------------------------------------------
;--------------------------------------------------------------
; 主选单列出
;--------------------------------------------------------------
; 子程序: toppage
; 功能： 在首页列出4个选项
;--------------------------------------------------------------
toppage: push bx
push di
push cx
push ax
push ds
push es
push si
mov bx, offset menu_address - offset task + 7E00H
mov di,160*8+25*2
mov cx,4 ; 主页显示 4行 功能选项
mov ax,0
mov ds,ax
mov ax,0B800H
mov es,ax
showtoppage: mov si,ds:[bx]
call oneline
add bx,2
add di,160
loop showtoppage
pop si
pop es
pop ds
pop ax
pop cx
pop di
pop bx
ret
oneline: push cx
push di
push si
onelines: mov cl,ds:[si]
mov ch,0
jcxz onelineok
mov byte ptr es:[di],cl
mov ch,02H
mov byte ptr es:[di+1],ch
inc si
add di,2
jmp short onelines
onelineok: pop si
pop di
pop cx
ret
;--------------------------------------------------------------
;--------------------------------------------------------------
; 常用子程序集合 开始
;--------------------------------------------------------------
; 子程序: clear_screen
; 功能: 清屏，将显存中当前屏幕中的字符设为空格符
;--------------------------------------------------------------
clear_screen: push bx
push cx
push es
push ax
mov bx,0B800H
mov es,bx
mov bx,0
mov cx,2000
mov ah,' '
mov al,00000111B ;黑底白字
clear_screens: mov byte ptr es:[bx],ah
mov byte ptr es:[bx+1],al
add bx,2
loop clear_screens
pop ax
pop es
pop cx
pop bx
ret
;--------------------------------------------------------------
; 子程序：init_reg
; 功能： 寄存器设置
;--------------------------------------------------------------
init_reg: mov ax,0
mov ds,ax
mov ax,0B800H
mov es,ax
ret
;--------------------------------------------------------------
; 帮助信息
;--------------------------------------------------------------
; 子程序: helptop
; 功能： 提供主选单的帮助信息
; 按对应数字按键进入对应选项
;--------------------------------------------------------------
helptop: push di
push bx
push ax
push cx
jmp helptopshow
;db '12345678901234567890123456789012'
helptopmss db 'PRESS A NUM KEY : ENTER THE MENU'
helptopshow: mov di,160*15+20*2
mov bx,offset helptopmss - offset task + 7E00H
mov ah,0FH
mov cx,32
helptoploop: mov al,ds:[bx]
mov es:[di],al
mov es:[di+1],ah
inc bx
add di,2
loop helptoploop
pop cx
pop ax
pop bx
pop di
ret
;--------------------------------------------------------------
; 子程序： help3
; 功能： 提供选项3的帮助信息
; F1键 修改显示颜色 ； ESC键 范湖主选单
;--------------------------------------------------------------
help3: push di
push bx
push ax
push cx
jmp short help3draw
;db '1234567890123456789012345678901234567890123'
help3mss db '[F1] CHNAGE COLOR ; [ESC] BACK TO MAIN MENU'
help3draw:
mov di,160*15+10*2
mov bx,offset help3mss - offset task + 7e00H
mov ah,0FH
mov cx,43
help3loop: mov al,ds:[bx]
mov es:[di],al
mov es:[di+1],ah
inc bx
add di,2
loop help3loop
pop cx
pop ax
pop bx
pop di
ret
;--------------------------------------------------------------
; 子程序： help4
; 功能： 提供选项4的帮助信息
;--------------------------------------------------------------
help4: push di
push bx
push ax
push cx
jmp short help4draw
;db '12345678901234567890123456789012345'
help4mss db '[Enter] ENTER AND BACK TO MAIN MENU'
help4draw:
mov di,160*15+20*2
mov bx,offset help4mss - offset task + 7e00H
mov ah,0FH
mov cx,35
help4loop: mov al,ds:[bx]
mov es:[di],al
mov es:[di+1],ah
inc bx
add di,2
loop help4loop
pop cx
pop ax
pop bx
pop di
ret
;--------------------------------------------------------------
; 常用子程序集合 结束
;--------------------------------------------------------------
taskend: nop
;--------------------------------------------------------------
; 任务程序结束
;--------------------------------------------------------------
code ends
end start
代码说明
- 完整源码 里提供的就是最终版的全部代码
taskcode.asm 由于增加了很多帮助代码
首先，使用的内存扩充到
data segment
db 1536 dup (0)
data ends
其次，task部分的机器码（ offset taskend - offset task）
会被写入 0面0道2扇区、3扇区以及4扇区，一共三个扇区
因此，bootcode.asm 文件 以及 taskcode.asm文件 写扇区的
参数 al ，全部需要修改成
mov al,3 ; 扇区数
源码使用方法
https://www.jianshu.com/p/2c8ace0ee240
代码参考
[085][汇编语言]课程设计2 ：（1）从软盘启动，开机后主界面，列出选项
https://www.jianshu.com/p/0a99d34113c0
[086][汇编语言]课程设计2 ：（2）从软盘启动，功能化选项按键 "1"（测试版）
https://www.jianshu.com/p/bfe3c83359e8
[087][汇编语言]课程设计2 ：（3）从软盘启动，功能化选项按键 "3"，F1键改显示颜色、ESC键返回主选单（测试版）
https://www.jianshu.com/p/6adb66c62b81
[088][汇编语言]课程设计2 ：（4）动态显示当前时间（动态时钟） F1键改显示颜色 ESC键返回（测试版）
https://www.jianshu.com/p/f470d973de1e
[090][汇编语言]课程设计2 ：（5）进入选项4，输入字符串，同步显示（测试版）
https://www.jianshu.com/p/f9df61506e7b
[091][汇编语言]课程设计2 ：（6）完成选项4功能，可以对系统时间进行修改（测试版）
https://www.jianshu.com/p/ec89cb845fcf
[092][汇编语言]课程设计2 ：（7）选项4），对时间输入增加提示符（测试版）
https://www.jianshu.com/p/8b88f6dcfe72
[093][汇编语言]课程设计2 ：（8）选项全部功能化，选项1） 重启计算机、选项2）引导现有操作系统（测试版）
https://www.jianshu.com/p/045094145960