前文
[085][汇编语言]课程设计2 ：（1）从软盘启动，开机后主界面，列出选项
https://www.jianshu.com/p/0a99d34113c0
[086][汇编语言]课程设计2 ：（2）从软盘启动，功能化选项按键 "1"（测试版）
https://www.jianshu.com/p/bfe3c83359e8
[087][汇编语言]课程设计2 ：（3）从软盘启动，功能化选项按键 "3"，F1键改显示颜色、ESC键返回主选单（测试版）
https://www.jianshu.com/p/6adb66c62b81
课程设计2 ：（4）动态显示当前时间 F1键改显示颜色 ESC键返回（测试版）
- 新增：实现选项3的功能，代码结构进行了大修改
1、动态显示当前时间（一个动态的时钟）
2、F1键改显示颜色
3、ESC键返回
运行测试
![[088][汇编语言]课程设计2 ：（4）动态显示当前时间（动态时钟） F1键改显示颜色 ESC键返回（测试版）_第1张图片](http://img.e-com-net.com/image/info10/29cf948034374a2cbd4939a15e4d1ca0.jpg)
18/05/13 23:14:04
![[088][汇编语言]课程设计2 ：（4）动态显示当前时间（动态时钟） F1键改显示颜色 ESC键返回（测试版）_第2张图片](http://img.e-com-net.com/image/info10/c93e4857ac934707bdd89dd71852a481.jpg)
18/05/13 23:14:19
代码修改
taskcode.asm
- 增加 两张表，位于标号 task 那一堆表
adddata dw 0,0
aESC db 0
- 子程序：clock (完全功能化：动态时钟、F1键改显示颜色、ESC键返回主选单）
;--------------------------------------------------------------
; 子程序：clock
; 功能： 循环显示当前时间
; F1键-改变显示颜色
; ESC键-返回到主选单
;--------------------------------------------------------------
clock: call clear_screen
call clockstart
ret
;--------------------------------------------------------------
; 子程序：clockstart
; 功能： 循环显示当前时间
;--------------------------------------------------------------
clockstart: ;ds = 0
push bx
push ax
; (int 9H)1、将原始的int 9H 入口地址保存到新开辟的 adddata 表中，
; 以便日后模拟指令的调用和还原；
mov bx,offset adddata - offset task + 7E00H
push ds:[9*4]
pop ds:[bx]
push ds:[9*4+2]
pop ds:[bx+2]
; (int 9H)2、设置新的int 9H 的入口地址；
cli ; TF = 0
mov word ptr ds:[9*4],offset int9 - offset task + 7E00H
mov word ptr ds:[9*4+2],cs
sti ; TF = 1
mov bx,offset aESC - offset task + 7E00H
mov byte ptr ds:[bx],0
mov ah,'a'
dateloop: call date
mov al,ds:[bx]
cmp al,01H
je clockend
call delay
cmp ah,'z'
jna dateloop
clockend: ; (int 9H)5、还原原始的int 9H 入口地址；
mov bx,offset adddata - offset task + 7E00H
cli ; TF = 0
push ds:[bx]
pop ds:[9*4]
push ds:[bx+2]
pop ds:[9*4+2]
sti ; TF = 1
pop ax
pop bx
ret
;--------------------------------------------------------------
delay: push ax
push dx
mov dx,0003H
mov ax,0
s1: sub ax,1
sbb dx,0
cmp ax,0
jne s1
cmp dx,0
jne s1
pop dx
pop ax
ret
;--------------------------------------------------------------
int9: push bx
in al,60H
pushf
pushf
pop bx
and bh,11111100B
push bx
popf
; (int 9H)3、模拟对原始 int 9H 指令的调用；
mov bx,offset adddata - offset task + 7E00H
call dword ptr ds:[bx]
; (int 9H)4、编写代码，实现指定按键的功能；
cmp al,01H ; ESC
jne maybeF1
mov bx,offset aESC - offset task + 7E00H
mov ds:[bx],al
maybeF1: cmp al,3BH ; F1
jne int9ret
call changcolor
int9ret: pop bx
iret
完整源码
bootcode.asm 不做修改
https://www.jianshu.com/p/6adb66c62b81
taskcode.asm
assume cs:code
data segment
db 1024 dup (0)
data ends
code segment
start:
call setup
call write
mov ax,4c00h
int 21H
setup:
; 任务程序 安装步骤
; 将任务程序机器码安装到data段开辟的内存空间
mov ax,cs
mov ds,ax
mov si, offset task
mov ax,data
mov es,ax
mov di,0
mov cx,offset taskend - offset task
cld
rep movsb
ret
write:
; 利用 int 13H 中断
; 将内存 data 处的任务程序
; 写入 软盘A 0面 0道 2扇区
mov ax,data
mov es,ax
mov bx,0
mov al,2 ; 扇区数
mov ch,0
mov cl,2
mov dl,0
mov dh,0
mov ah,3
int 13h
ret
;--------------------------------------------------------------
; 任务程序 开始
; 任务程序 从 标号 task 开始 到 标号 taskend 结束
;--------------------------------------------------------------
task: jmp short taskstart
menu_1 db '1) reset pc',0
menu_2 db '2) start system',0
menu_3 db '3) clock',0
menu_4 db '4) set clock',0
menu_address dw offset menu_1 - offset task + 7E00H
dw offset menu_2 - offset task + 7E00H
dw offset menu_3 - offset task + 7E00H
dw offset menu_4 - offset task + 7E00H
;stack db 50 dup(0)
time db 9,8,7,4,2,0
blank db '// ::'
adddata dw 0,0
aESC db 0
taskstart:
call init_reg
call clear_screen
call toppage
jmp short key_toppage
mov ax,4c00h
int 21H
;--------------------------------------------------------------
; 选项控制: key_toppage
; 功能: 针对首页 toppage 的键盘操作
; 实现： 使用 BIOS int 16h 0号功能，读取一个键盘输入
; 返回值 (ah) = 扫描码 , (al) = ASCII码
; 键 1 2 3 4
; 扫描码 02 03 04 05
;--------------------------------------------------------------
key_toppage: mov ah,0
int 16h
cmp ah,02H
je key1
cmp ah,03h
je key2
cmp ah,04h
je key3
cmp ah,05h
je key4
; 本意是，这时候读取的输入，如果不是1234就忽略，再读取一个
jmp short key_toppage
key1: call test1
jmp short taskstart
key2:
key3: call clock
jmp short taskstart
key4:
;--------------------------------------------------------------
test1: call clear_screen
mov di,160*12+40*2
mov al,03H
mov byte ptr es:[di],'t'
mov byte ptr es:[di+1],al
mywait: mov ah,0
int 16H
cmp ah,3BH ; 3BH : F1键扫描码
je ok
jmp short mywait
ok: ret
;--------------------------------------------------------------
; 子程序：clock
; 功能： 循环显示当前时间
; F1键-改变显示颜色
; ESC键-返回到主选单
;--------------------------------------------------------------
clock: call clear_screen
call clockstart
ret
;--------------------------------------------------------------
; 子程序：clockstart
; 功能： 循环显示当前时间
;--------------------------------------------------------------
clockstart: ;ds = 0
push bx
push ax
; (int 9H)1、将原始的int 9H 入口地址保存到新开辟的 adddata 表中，
; 以便日后模拟指令的调用和还原；
mov bx,offset adddata - offset task + 7E00H
push ds:[9*4]
pop ds:[bx]
push ds:[9*4+2]
pop ds:[bx+2]
; (int 9H)2、设置新的int 9H 的入口地址；
cli ; TF = 0
mov word ptr ds:[9*4],offset int9 - offset task + 7E00H
mov word ptr ds:[9*4+2],cs
sti ; TF = 1
mov bx,offset aESC - offset task + 7E00H
mov byte ptr ds:[bx],0
mov ah,'a'
dateloop: call date
mov al,ds:[bx]
cmp al,01H
je clockend
call delay
cmp ah,'z'
jna dateloop
clockend: ; (int 9H)5、还原原始的int 9H 入口地址；
mov bx,offset adddata - offset task + 7E00H
cli ; TF = 0
push ds:[bx]
pop ds:[9*4]
push ds:[bx+2]
pop ds:[9*4+2]
sti ; TF = 1
pop ax
pop bx
ret
;--------------------------------------------------------------
delay: push ax
push dx
mov dx,0003H
mov ax,0
s1: sub ax,1
sbb dx,0
cmp ax,0
jne s1
cmp dx,0
jne s1
pop dx
pop ax
ret
;--------------------------------------------------------------
int9: push bx
in al,60H
pushf
pushf
pop bx
and bh,11111100B
push bx
popf
; (int 9H)3、模拟对原始 int 9H 指令的调用；
mov bx,offset adddata - offset task + 7E00H
call dword ptr ds:[bx]
; (int 9H)4、编写代码，实现指定按键的功能；
cmp al,01H ; ESC
jne maybeF1
mov bx,offset aESC - offset task + 7E00H
mov ds:[bx],al
maybeF1: cmp al,3BH ; F1
jne int9ret
call changcolor
int9ret: pop bx
iret
;--------------------------------------------------------------
; 子程序：changcolor
; 功能： 改变显示颜色
;--------------------------------------------------------------
changcolor: push cx
push bx
mov bx,1
mov cx,2000
colors: inc byte ptr es:[bx]
add bx,2
loop colors
pop bx
pop cx
ret
;--------------------------------------------------------------
; 子程序：date
; 功能： 显示当前时间
;--------------------------------------------------------------
date:
push di
push si
push cx
push ax
mov di,160*12+40*2
mov si,offset time - offset task + 7E00H
mov cx,6
showdate: push cx
mov al,[si]
out 70H,al
in al,71H
mov ah,al
mov cl,4
shr ah,cl
and al,00001111B
add ah,30H
add al,30H
mov byte ptr es:[di],ah
mov byte ptr es:[di+2],al
add di,6
inc si
pop cx
loop showdate
mov di,160*12+40*2
mov si,offset blank - offset task + 7E00H
mov cx,5
showblank: push cx
mov al,[si]
mov byte ptr es:[di+4],al
add di,6
inc si
pop cx
loop showblank
dateend: pop ax
pop cx
pop si
pop di
ret
;--------------------------------------------------------------
;--------------------------------------------------------------
; 子程序: toppage
; 功能： 在首页列出4个选项
;--------------------------------------------------------------
toppage: push bx
push di
push cx
push ax
push ds
push es
push si
mov bx, offset menu_address - offset task + 7E00H
mov di,160*8+25*2
mov cx,4 ; 主页显示 4行 功能选项
mov ax,0
mov ds,ax
mov ax,0B800H
mov es,ax
showtoppage: mov si,ds:[bx]
call oneline
add bx,2
add di,160
loop showtoppage
pop si
pop es
pop ds
pop ax
pop cx
pop di
pop bx
ret
oneline: push cx
push di
push si
onelines: mov cl,ds:[si]
mov ch,0
jcxz onelineok
mov byte ptr es:[di],cl
mov ch,02H
mov byte ptr es:[di+1],ch
inc si
add di,2
jmp short onelines
onelineok: pop si
pop di
pop cx
ret
;--------------------------------------------------------------
;--------------------------------------------------------------
; 常用子程序集合 开始
;--------------------------------------------------------------
; 子程序: clear_screen
; 功能: 清屏，将显存中当前屏幕中的字符设为空格符
;--------------------------------------------------------------
clear_screen: push bx
push cx
push es
push ax
mov bx,0B800H
mov es,bx
mov bx,0
mov cx,2000
mov ah,'a'
mov al,00000111B ;黑底白字
clear_screens: mov byte ptr es:[bx],ah
mov byte ptr es:[bx+1],al
add bx,2
loop clear_screens
pop ax
pop es
pop cx
pop bx
ret
;--------------------------------------------------------------
; 子程序：init_reg
; 功能： 寄存器设置
;--------------------------------------------------------------
init_reg: mov ax,0
mov ds,ax
mov ax,0B800H
mov es,ax
ret
;--------------------------------------------------------------
;--------------------------------------------------------------
; 常用子程序集合 结束
;--------------------------------------------------------------
taskend: nop
;--------------------------------------------------------------
; 任务程序结束
;--------------------------------------------------------------
code ends
end start
代码说明
如何实现动态时钟、并能同时接受F1键、ESC键的输入
- 代码结构参考
https://www.jianshu.com/p/b7244b7742b8
- 具体实现原理
以前，面对主选单的4个选项 1）2）3）4）的按键输入，
是用 BIOS int 16H 中断例程，从键盘缓冲区读出一个字符，判断并进行操作；
然而，功能选项3) 却要求 动态时钟 与 F1键、ESC键并存，
如果继续使用 BIOS int 16H 中断接受按键输入，时钟是"动不起来的"!
《汇编语言（第三版）》这本书，提到动态显示的章节，是15.4 编写 int 9H 中断，
在这个章节里面，实现了一个动态显示字母 a~z的小程序【见上方代码结构参考下的引用连接】
这个小程序的实现原理就是，在一个无限的循环里面 搭配 自己写的 int 9H中断，
这样既使得程序看上去动起来，也可以通过int 9H 中断接受键盘输入；
正好可以拿来实现 动态时间，无非是把显示的内容从 a~z这样单个的字母变成显示时间，
从代码实现的角度来说，就是循环调用一个 显示时间的子程序；
显示时间的子程序是静态的， 调用一次显示一瞬间的时间，名字是 date；
动态时钟，动的是对这个子程序date的调用，按照一定的时间间隔（延迟delay一下），
通过调delay的循环次数来控制间隔长短；
看上去时钟就像动了一样。
-
选项3) 代码结构图：循环调用 时间显示子程序 date
![[088][汇编语言]课程设计2 ：（4）动态显示当前时间（动态时钟） F1键改显示颜色 ESC键返回（测试版）_第3张图片](http://img.e-com-net.com/image/info10/126a9a73537a4fe4b6e9af45439168e7.png)
选项3) 代码结构图 如何写自己的 int 9H ？
本质上包括 5个方面：
1、将原始的int 9H 入口地址保存到新开辟的 adddata 表中，以便日后模拟指令的调用和还原；
2、设置新的int 9H 的入口地址；
3、模拟对原始 int 9H 指令的调用；
4、编写代码，实现指定按键的功能；
5、还原原始的int 9H 入口地址；
- 新的int 9H 中断例程要做哪些事情？
0 、在新的int 9H 里面模拟 int 指令，调用原始的int 9H中断；
原始的入口地址存在了表 adddata 里面 ，所以从这里去取出来：
mov bx,offset adddata - offset task + 7E00H
call dword ptr ds:[bx]
※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※
1、 无论是 F1键、ESC键 或者 是其他键，都会触发 int 9H 中断，都需要来到 iret ，
实现中断例程的正确返回；
※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※
2、 F1键 要实现，改变显示颜色，通过调用 子程序 changecolor ，
然后来到 iret，正确返回；
※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※
3、 ESC键 要实现 返回到主选单，但不是直接 jmp 到 taskstart，
而是先把 ESC键 的扫描码存到表 adddata 里面，
然后来到iret ，正确返回；
※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※
所有int 9H中断例程的返回其实都是，返回到 clockstart 循环里，
通过判断本次 int 9H 中断得到的键是不是ESC，
如果是ESC就结束 clock 子程序，再通过jmp 返回到主选单。