虽然我们经常说这些均线啊、MACD啊或KD线等都是庄家忽悠散户的，根本信不了，可我想说的是，你真的把它们做成固定的程序了吗，照着这些程序化做过一段时间实盘吗？当然，最好的还是先照着程序化来做一段时间模拟盘，了解这个程序的优缺点，盈亏比，操作风格等全面了解了，才能真的照着程序来执行。要不然，刚好碰到一段时间的亏损，心里就开始对这些程序产生怀疑，随之弃掉，返回自己的经验做了。
好了，也不废话了，我们还是来先看看KD指标需要用到的函数吧，咱先对各个函数做个正确认知。
HighestFC求最高的函数代码：
Params
NumericSeries Price(1);//声明数值型序列参数，价格为Price，赋值为1。//
Numeric Length(10);//声明数值型参数为Length，赋值为10。//
Vars
Numeric HighestValue;//声明变量为HighestValue。//
Numeric ExtremesBar;//声明变量为ExtremesBar。//
Begin
HighestValue = Extremes(Price, Length, True, ExtremesBar);//Extremes求极值函数，语句意思是这样的：计算10周期以来价格的极大值和极大值出现的回溯周期索引 。//
Return HighestValue;//把得到的数值返回给主函数。//
End
LowestFC的源代码如下，解释基本同求最大值：
Params
NumericSeries Price(1);
Numeric Length(10);
Vars
Numeric LowestValue;
Numeric ExtremesBar;
Begin
LowestValue = Extremes(Price, Length, False, ExtremesBar); //计算10周期以来价格的极小值和极小值出现的回溯周期索引。//
Return LowestValue;
End
还用到了这个函数SummationFC，代码如下：
Params
NumericSeries Price(1);//声明数值型序列参数，价格为Price，赋值为1。//
Numeric Length(10);//声明数值型参数为Length，赋值为10。//
Vars
NumericSeries SumValue(0);//声明数值型序列变量为Sumvalue，赋值为0。//
Numeric i;//声明变量 i 。//
Begin
If(CurrentBar < Length)//CurrentBar，直白意思就是当前的K线数位，我们声明参数Length初始值为10，这语句意思就是说假如当前的K线数位小于10的，执行下列的语句。//
{
SumValue = 0;//这边再次赋值给SumValue为0。//
for i = 0 to Length - 1 //这是循环语句，变量i从赋值为0，开始执行，直到数值为10-1=9，结束循环。//
{
SumValue = SumValue + Price[i];//其实从if开始到现在的语句，整体表达的意思是这样的，前10根k线价格是这样求的，SumValue=P0+P1+P2+P3+...+P9，前10根k线价格累加起来。//
}
}Else //从第11根k线开始，执行下列的语句来求和。//
{
SumValue = SumValue[1] + Price - Price[Length];//我们记住一个规则是这样的，价格为当前K线的价格，所以Price[10],意思告诉你减去最前一根。比如，第11根k线，前10根总价，加上第11根的价格，减去第一根k线的价格，得到了一个新总价S1；第12根，则是新总价S1，加上当前12根价格，再减去第2根的价格，得到一个新的总价S2。反正就是这么来回的求10根k线的总价了。//
}
Return SumValue;//把这总价数值返回给主函数了。//
End
接下来为正餐，就是KD指标的真正代码了：
Params
Numeric Length(14);//声明数值型参数Length,初始值为14.//
Numeric SlowLength(3); //声明数值型参数SlowLength，初始值为3.//
Numeric SmoothLength(3);//声明数值型参数SmoothLength，初始值为3.//
Vars
NumericSeries HighestValue; //声明数值型序列变量HighestValue。//
NumericSeries LowestValue;//声明数值型序列变量LowestValue。//
NumericSeries KValue;//声明数值型序列变量KValue。//
Numeric SumHLValue;//声明数值型变量SumHLValue。//
Numeric SumCLValue;//声明数值型变量SumCLValue。//
Numeric DValue;//声明数值型变量DValue。//
Begin
HighestValue = HighestFC(High, Length);//把高价和周期实参数返回函数HighestFC去求值，再把最高值返回来给这个主函数。//
LowestValue = LowestFC(Low, Length); //同理的，求出最低值来。//
SumHLValue = SummationFC(HighestValue-LowestValue,SlowLength);//返回函数SummationFC去求值，这个咱也可以一个个对应上去的，把最高 - 最低得到的值替代Price，SlowLength的值3替代Length的值10，最后求出总价。//
SumCLValue = SummationFC(Close - LowestValue,SlowLength);//同理，求出收盘价减去最低价的3个周期总价。//
If(SumHLValue <> 0)//假如最高减去最低的3个周期的总价不等于0，执行下列语句。//
{
KValue = SumCLValue/SumHLValue*100;//看表达式就直白翻译了，最高减去最低的总价除以收盘价减去最低价的总价，再乘以100.//
}Else//否则就是等于0了。//
{
KValue = 0;//这个也等于0了。//
}
DValue = AverageFC(KValue,SmoothLength);//这个函数AverageFC在系列2说过了，反正也就是把相应的值跟周期返回去求解出新的值来了，再把这新值，返回来给这个DValue。//
PlotNumeric("K",KValue);//画线了，线k代表KValue值。//
PlotNumeric("D",DValue);//线D代表DValue值。//
PlotNumeric("Ref1",20);//这是界限20，辅助我们判断是否超买卖的。//
PlotNumeric("Ref2",80);//这是界限80，同上。//
End
同理，最后我能附上的，也就是添加一个用它做成的程序化交易系统了。至于这结果如何，我只能说真是很不尽如人意，关键就是在买卖的点位上了，这能不能改进？该如何改进，我还真是想不出办法的。只能说，这是一个辅助判断系统，当成程序化进行买卖，结果肯定很不理想的。
程序化代码如下：
Params
Numeric Length(14);
Numeric SlowLength(3);
Numeric SmoothLength(3);
Vars
NumericSeries HighestValue;
NumericSeries LowestValue;
NumericSeries KValue;
Numeric SumHLValue;
Numeric SumCLValue;
NumericSeries DValue;
Begin
HighestValue = HighestFC(High, Length);
LowestValue = LowestFC(Low, Length);
SumHLValue = SummationFC(HighestValue-LowestValue,SlowLength);
SumCLValue = SummationFC(Close - LowestValue,SlowLength);
If(SumHLValue <> 0)
{
KValue = SumCLValue/SumHLValue*100;
}Else
{
KValue = 0;
}
DValue = AverageFC(KValue,SmoothLength);
If(!CallAuctionFilter()) Return;
If(MarketPosition <>1 && KValue[1] > DValue[1] && DValue < 30)
{
Buy(1,Open);
}
If(MarketPosition ==1 && KValue[1] < DValue[1] || DValue >95)
{
Sell(1,Open);
}
If(MarketPosition <>-1 && KValue[1] < DValue[1] && DValue > 70)
{
SellShort(1,Open);
}
If(MarketPosition ==-1 && KValue[1] > DValue[1] || DValue <5)
{
BuyToCover(1,open);
}
End
