RF-自定义关键字和关键字参数

用户自定义关键字

• 关键字表通过将现有关键字组合在一起来创建新的更高级别关键字

  这些关键字称为用户关键字，区别于测试库中实现的最低级别库关键字

  创建用户关键字语法与创建测试用例语法非常接近，易于学习

用户关键字语法

• 用户关键字在关键字表中创建
  关键字表与测试用例表的区别仅在用于标识它们的名称
  用户关键字名称在第一列中与测试用例名称相似

• 用户关键字根据已有关键字创建
  可以是测试库中关键字，也可以是其他用户关键字
  关键字名称通常在第二列中
  如果关键字有返回值，在随后列中

*** Settings ***
Library    SeleniumLibrary
    
*** KeyWords ***
百度搜索京东
    Open Browser    http://wwww.jd.com    chrome
    Input Text    id=kw    京东
    Click Button    id=su
    Close Browser    
    
*** Test Cases ***
case01
    百度搜索京东  

关键字表的设置

• [Documentation]
• [Tags]
• [Arguments]
• [Return]
• [Teardown]
• [Timeout]

*** Settings ***
Library    SeleniumLibrary

*** KeyWords ***
百度搜索京东
    [Documentation]    doc
    [Arguments]    ${url}    ${browser}
    [Tags]    mytag
    [Teardown]    Log    kw teardowm
    [Timeout]    10
    Open Browser    ${url}    ${browser}
    Input Text    id=kw    京东
    Click Button    id=su
    Close Browser 
    [Return]    搜索成功！
        
*** Test Cases ***
case01
    ${result}    百度搜索京东    http://www.baidu.com    chrome
    Log    ${result}

关键字参数

分类：

• 参数和系统关键字一样，有位置参数、默认参数、可变参数、关键字参数等

用户关键字参数

• 位置参数
• 默认参数
• 可变参数
• 关键字参数

*** Settings ***
Library    SeleniumLibrary
Suite Teardown    Close Browser

*** Keywords ***
位置参数
    [Arguments]    ${url}    ${browser}
    Open Browser    ${url}    ${browser}
默认参数
    [Arguments]    ${url}=http://www.baidu.com    ${browser}=chrome
    Open Browser    ${url}    ${browser}
可变参数
    [Arguments]    @{args}
    Open Browser    @{args}
关键字参数
    [Arguments]    &{kwargs}
    Open Browser    &{kwargs}
        
*** Test Cases ***
case01
    位置参数    http://www.baidu.com    chrome
case02 
    默认参数    
case03
    可变参数    http://www.baidu.com    chrome
case04
    关键字参数    url=http://www.baidu.com    browser=chrome