初识Inno Setup使用心得

一.Inno Setup 是什么？

 InnoSetup 是一个免费的 Windows 安装程序制作软件.俗话说的就是制作软件的安装程序(.exe文件).

二、Inno Setup 能干什么？

 1.支持现在所有正在使用的 Windows 版本: 7, 2008 R2, Vista, XP, 2008,2003, 2000, Me, 98, 95,和 NT 4.0 (不需要服务包)。

  2.广泛支持在 64 位 的 Windows XP and Windows Server2003 版本的操作系统中的 64 位应用程序安装。支持 x64 和 Itanium 两个结构。(在 Itanium 结构中，必须在 64 位模式安装 Service Pack 1。)

  3.支持创建单个EXE 格式的安装程序，使你的程序可以很方便地在网络上发表。同时也支持磁盘延伸。

  4.标准的Windows 2000/XP 样式向导界面。

。。。。。。。。。。可自行百度查看

三.Inno Setup下载地址

http://soft.onlinedown.net/soft/4693.htm(借用别人的链接地址)

四.图示拙劣见解(说的不对,请留言,在此感谢)

五.粘贴一下我的脚本文件

六.上图脚本文件

 

; 脚本由 Inno Setup 脚本向导 生成！
; 有关创建 Inno Setup 脚本文件的详细资料请查阅帮助文档！

#define MyAppName "soft"
#define MyAppVersion "1.0"
#define MyAppPublisher "XXXXX有限公司"
#define MyAppURL "http://XXXXXX/data"
#define MyAppExeName "startup.bat"

[Setup]
; 注: AppId的值为单独标识该应用程序。
; 不要为其他安装程序使用相同的AppId值。
; (生成新的GUID，点击 工具|在IDE中生成GUID。)
AppId={{70751EF0-6C17-48DE-86EC-400357433A93}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
;AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultDirName={pf}\{#MyAppName}
DefaultGroupName={#MyAppName}
;安装包压缩完成后,放入的目录
OutputDir=C:\Users\nihao\Desktop
;安装程序的名字
OutputBaseFilename=XXXX程序
;安装程序的图标
SetupIconFile=C:\XXXXXX\dove.ico
Compression=lzma
SolidCompression=yes

[Languages]
;语言类型
Name: "chinesesimp"; MessagesFile: "compiler:Default.isl"

[Tasks]
;询问是否创建开始菜单和桌面快捷方式
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked; OnlyBelowVersion: 0,8.1
Name: "quicklaunchicon"; Description: "{cm:CreateQuickLaunchIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: checkablealone

[Files]
;快捷方式启动程序(我的测试是点击快捷方式,启动tomcat)
Source: "E:\exambody\tomcat\bin\startup.bat"; DestDir: "{app}"; Flags: ignoreversion
;拷贝tomcat,   DestDir:安装成功后,这个文件夹名字叫什么  {app}放入目录文件夹中
Source: "E:\exambody\tomcat\*"; DestDir: "{app}\tomcat7"; Flags: ignoreversion recursesubdirs createallsubdirs
;拷贝jdk
Source:"E:\exambody\java\*";DestDir:"{app}\jdk1.7";Flags:igNoreversion recursesubdirs createallsubdirs
;拷贝ffmpeg
Source:"E:\exambody\ffmpeg\*";DestDir:"{app}\ffmpeg";Flags:igNoreversion recursesubdirs createallsubdirs
;拷贝数据目录
Source:"E:\exambody\data\*";DestDir:"{app}\data";Flags:igNoreversion recursesubdirs createallsubdirs
;拷贝动态库                 {win}系统的Windows目录，一般为“C:"WINDOWS”
Source:"E:\exambody\dll\*";DestDir:"{win}\";CopyMode: alwaysskipifsameorolder; Flags: restartreplace sharedfile;  
;拷贝bat
Source:"E:\exambody\*";DestDir:"{app}\";

[Icons]
;快捷方式启动程序目标文件
Name: "{group}\XXX控制台启动"; Filename: "{app}\tomcat7\bin\{#MyAppExeName}"
Name: "{group}\{cm:ProgramOnTheWeb,XXX控制台}"; Filename: "{#MyAppURL}"
;卸载程序
Name: "{group}\{cm:UninstallProgram,XXX控制台}"; Filename: "{uninstallexe}"
;快捷方式启动目标文件,已经桌面快捷方式的图标,   .ioc文件
Name: "{commondesktop}\XXX控制台启动"; Filename: "{app}\tomcat7\bin\{#MyAppExeName}"; Tasks: desktopicon;IconFilename:"{app}\logo_desk.ico"

[INI]
;修改服务器配置文件
Filename:"{userdesktop}\XXX网页数据";Section:"InternetShortcut";Key:"URL"; String:"http://127.0.0.1:55555/data"
;修改数据配置文件 这是在安装完成后,写入tomcat   artery.properties的文件配置
Filename:"{app}\tomcat7\webapps\ROOT\WEB-INF\classes\artery.properties";Section:"#datadir";Key:"temp"; String:"{app}\temp\"
Filename:"{app}\tomcat7\webapps\ROOT\WEB-INF\classes\artery.properties";Section:"#datadir";Key:"videofile"; String:"{app}\data\"
Filename:"{app}\tomcat7\webapps\ROOT\WEB-INF\classes\artery.properties";Section:"#datadir";Key:"ffmpeg"; String:"{app}\ffmpeg\bin\ffmpeg"

[Run]
;安装完成后,执行脚本
Filename: "{app}\loading.bat";AfterInstall:ConfigXml(ExpandConstant('{app}\tomcat7\conf\Catalina\localhost\data.xml'),'/Context','docBase',ExpandConstant('{app}\data'))
Filename: "{app}\install.bat"; Description: "Setup"; Flags: skipifsilent shellexec
;安装完成后,点击完成,自动启动程序
Filename: "{app}\tomcat7\bin\startup.bat"; Description: "{cm:LaunchProgram,{#StringChange('XXX控制台启动', '&', '&&')}}"; Flags: nowait postinstall skipifsilent
[UninstallRun]
;卸载
Filename:"{app}\uninstall.bat";

[UninstallDelete]
;卸载删除tomcat
Type:filesandordirs;Name:"{app}\tomcat7"
Type:filesandordirs;Name:"{app}\ffmpeg"
Type:filesandordirs;Name:"{app}\jdk1.7"
Type:files;Name:"{app}\InstallUtil.InstallLog"

[Code]
procedure ConfigXml(xmlPath:String;xPath:String;attrName:String;attrValue:String);
var
XMLDocument,XMLRoot,XMLNode:Variant;
begin
try
XMLDocument := CreateOleObject('MSXML2.DOMDocument');
XMLDocument.async := False;
XMLDocument.resolveExternals := False;
XMLDocument.load(xmlPath);
XMLRoot := XMLDocument.documentElement;
XMLNode:=XMLRoot.SelectSingleNode(xPath);
XMLNode.Attributes.GetNamedItem(attrName).Value:=attrValue;
XMLDocument.Save(xmlPath);
except
MsgBox('xml error', mbInformation, mb_Ok);
end;
end;

七.我需要压缩的文件

八.生成安装程序

九.安装成功后

快捷方式图标

安装成功后的文件夹