NodeMCU(ESP-12E)+阿里云实现数据上传和控制继电器开锁

源码及工具下载：https://github.com/RL-Y/NodeMCU-aliyun.git

Arduino15：提取码：ythf ；链接：
https://pan.baidu.com/s/1CsIA7LFZ4IElnTA62cozaA

一、软、硬件

1、所用软件：Arduino IDE、ESP8266Flasher
2、所用硬件：NodeMCU、FSR薄膜压力传感器+电压转换模块、5v继电器（低电平触发）、电磁锁

二、给NodeMCU刷固件（.bin）

2.1、生成固件：先填写邮箱，再在下面选择所需的功能模块，最后点击下面的【Start your build】生成固件。
固件生成网址：https://nodemcu-build.com/index.php

2.2、下载固件：打开邮箱会有两封邮件，一封为告知邮件，另一封为固件下载地址。有float和integer，选一个即可。

2.3、烧录固件：把下载好的固件刷入NodeMCU，打开ESP8266Flasher。
ⅰ、点击【Config】选择刚才生产的.bin文件，右边为0x00000。
ⅱ、点击【Operation】选择对应端口，点击【Flash】开始烧录，当左下角会出现一个绿色标志时烧录完成。

三、获取三元组

3.1、登录阿里云—物联网平台。
3.2、创建产品并自定义功能。创建好产品点击【功能定义】>【编辑草稿】>【添加自定义功能】>【属性】（有属性、服务、事件三种）>【发布更新】。△记住标识符
3.3、创建设备。△记住三元组

四、用Arduino IDE把代码烧入NodeMCU

4.1、下载ESP8266开发板（两种方法）。打开Arduino IDE点击【文件】>【首选项】把
（http://arduino.esp8266.com/stable/package_esp8266com_index.json）添加到【附加开发板管理器网站】。
法一：点击【工具】>【开发板】>【开发板管理器】，搜索【ESP8266】进行安装。注：安装过程可能很慢而且会被墙（可能早上安装会快点）。
法二：去【github】下载。把下载得到的【Arduino15】文件夹替换掉原来的【Arduino15】文件夹（路径：C:\Users\XXX\AppData\Local\Arduino15），最后重启即可。

4.2、安装两个依赖库【PubSubClient】和【ArduinoJson】。点击【项目】>【加载库】>【库管理器】，搜索安装即可。
注：用【Everything】或在【此电脑】上搜索【PubSubClient.h】文件修改两个参数（不修改无法连接Mqtt服务器）。

4.3、修改代码。
ⅰ、修改WIFI的SSID和密码。
ⅱ、修改三元组。
ⅲ、修改CLIENT_ID和MQTT_PASSWD。
生成passwd的小工具：
https://files.alicdn.com/tpsservice/471c155376d6a88a29c9ad66784e94f0.zip?spm=a2c4g.11186623.2.17.61f6619bQ80OV1&file=471c155376d6a88a29c9ad66784e94f0.zip
软件解压后，用浏览器打开【sign.html】：填入三元组、timestamp和clientID随意填

ⅳ、注意标识符。

代码：

#include 
#include  
#include 

#define PRESS_MIN 20      //最小量程是20g
#define PRESS_MAX 2000    //最大量程是2kg
#define VOLTAGE_MIN 100   //最小电压0.1v
#define VOLTAGE_MAX 3300  //最大电压3.3v

int relayPin = 2; //继电器引脚（GPIO2对应nodemcu的D4，本继电器为低电平触发（另有高电平触发））
int sensorPin = A0;   //压力传感器的引脚

#define WIFI_SSID         "XXXXX"   //WIFI SSID
#define WIFI_PASSWD       "XXXXX"   //WIFI密码

//三元组
#define PRODUCT_KEY       "XXXXXXX"
#define DEVICE_NAME       "XXXXXXX"
#define DEVICE_SECRET     "XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX"
#define REGION_ID         "cn-shanghai"
 
//线上环境域名和端口号
#define MQTT_SERVER       PRODUCT_KEY ".iot-as-mqtt." REGION_ID ".aliyuncs.com"
#define MQTT_PORT         1883
#define MQTT_USRNAME      DEVICE_NAME "&" PRODUCT_KEY
 
// 生成passwd：加密明文是参数和对应的值（clientId${esp8266}deviceName${deviceName}productKey${productKey}timestamp${1234567890}）按字典顺序拼接,密钥是设备的DeviceSecret
#define CLIENT_ID    "XXXXX|securemode=3,signmethod=hmacsha1,timestamp=XXXXXX|"
#define MQTT_PASSWD       "XXXXXXXXXXXXXXXXXXXXXXXXXXXXXX"

//topic-发布和订阅
#define ALINK_BODY_FORMAT_POST        "{\"id\":\"123\",\"version\":\"1.0\",\"method\":\"thing.event.property.post\",\"params\":%s}"   //消息体字符串格式和method参数
#define ALINK_TOPIC_PROP_POST         "/sys/" PRODUCT_KEY "/" DEVICE_NAME "/thing/event/property/post"   //发布，设备属性上报
#define ALINK_TOPIC_PROP_SET          "/sys/" PRODUCT_KEY "/" DEVICE_NAME "/thing/service/property/set"  //订阅，设备属性设置

unsigned long lastMs = 0;
WiFiClient espClient;     // 创建WiFiClient实例
PubSubClient  client(espClient);  //创建Client实例
 
//监听云端下发的指令及解析订阅的topic
void callback(char *topic, byte *payload, unsigned int length)
{
    if (strstr(topic, ALINK_TOPIC_PROP_SET)){ 
      Serial.print("Message arrived [");
      Serial.print(topic);
      Serial.print("] ");
      payload[length] = '\0';
      Serial.println((char *)payload);
      
      DynamicJsonDocument doc(100);
      DeserializationError error = deserializeJson(doc, payload);
      if (error){
        Serial.println("parse json failed");
        return;
        }
        
        //将字符串payload转换为json格式的对象
        // {"method":"thing.service.property.set","id":"282860794","params":{"jidianqi":1},"version":"1.0.0"}
        JsonObject setAlinkMsgObj = doc.as<JsonObject>();       
        int val = setAlinkMsgObj["params"]["jidianqi"];
        if (val == HIGH){
          digitalWrite(relayPin, HIGH);
          }
          else if (val == LOW){
            digitalWrite(relayPin, LOW);
            delay(2000);
            digitalWrite(relayPin, HIGH);
            }
     }
}
 
//连接Wifi 
void wifiInit()
{
    WiFi.mode(WIFI_STA);
    WiFi.begin(WIFI_SSID, WIFI_PASSWD);
    while (WiFi.status() != WL_CONNECTED)
    {
        delay(1000);
        Serial.println("WiFi not Connect");
    }
 
    Serial.println("Connected to AP");
    Serial.println("IP address: ");
    Serial.println(WiFi.localIP());
    client.setServer(MQTT_SERVER, MQTT_PORT);   //连接WiFi之后，连接MQTT服务器
    client.setCallback(callback);   // 设置回调监听云端下发的指令
}
 
//连接Mqtt 
void mqttCheckConnect()
{
    while (!client.connected())
    {
        Serial.println("Connecting to MQTT Server ...");
        if (client.connect(CLIENT_ID, MQTT_USRNAME, MQTT_PASSWD))
        {
            Serial.println("MQTT Connected!");
            client.subscribe(ALINK_TOPIC_PROP_SET); // 订阅属性设置Topic
            Serial.println("subscribe done");
        }
        else
        {
            Serial.print("MQTT Connect err:");
            Serial.println(client.state());
            delay(5000);
        }
    }
}
 
//上报数据
void mqttIntervalPost()
{
    char param[32];
    char jsonBuf[128];
    long Fdata = getPressValue(sensorPin);
    
    //sprintf是格式化字符串
    sprintf(param, "{\"jidianqi\":%d,\"zhongliang\":%d}",digitalRead(relayPin),Fdata);  //产品标识符,数据上传    
    sprintf(jsonBuf, ALINK_BODY_FORMAT_POST, param);
    
    Serial.println(jsonBuf);
    boolean a_POST = client.publish(ALINK_TOPIC_PROP_POST, jsonBuf);//上报属性Topic数据
    Serial.print("publish:0失败;1成功;");
    Serial.println(a_POST);
}

void setup() 
{
    pinMode(relayPin, OUTPUT);   //继电器输出模式
    digitalWrite(relayPin,HIGH); //初始化继电器高电平
    Serial.begin(115200);
    Serial.println("Demo Start");
    wifiInit();
}

void loop()
{
    if (millis() - lastMs >= 5000)
    {
        lastMs = millis();
        mqttCheckConnect(); // MQTT上云
        mqttIntervalPost();//上报消息心跳周期
    }
    client.loop();
}

//FSR薄膜压力传感器（转换）
long getPressValue(int pin)
{
  long PRESS_AO = 0;            //重量
  int VOLTAGE_AO = 0;           //电压
  int value = analogRead(pin);  //AD

  VOLTAGE_AO = map(value, 0, 1023, 0, 3300);
  if(VOLTAGE_AO < VOLTAGE_MIN)
  {
    PRESS_AO = 0;
  }
  else if(VOLTAGE_AO > VOLTAGE_MAX)
  {
    PRESS_AO = PRESS_MAX;
  }
  else
  {
    PRESS_AO = map(VOLTAGE_AO, VOLTAGE_MIN, VOLTAGE_MAX, PRESS_MIN, PRESS_MAX);
  }
  return PRESS_AO;
}

参考：
1、https://blog.csdn.net/qq_27158179/article/details/90549494
2、https://blog.csdn.net/happyjoey217/article/details/90406015
3、https://blog.csdn.net/q1694222672/article/details/89303425