Fixed Function Shader（固定渲染管线）

一、引言

Fixed Function Shader 属于固定渲染管线 Shader, 基本用于高级Shader在老显卡无法显示时的Fallback（之后有详细介绍）。使用的是ShaderLab语言，语法与微软的FX files 或者NVIDIA的 CgFX类似。

二、语法

shader例子参见附件

1、Pass 表示渲染管线

一个Pass表示一个渲染管线，当存在多个Pass时，即在前一Pass结束后，依据得到的缓存数据和状态开始下一个Pass管线，直到所有Pass管线渲染结束。

2、Pass 内开关控制

（1）Specularhighlights 反射高光

默认情况下primary颜色是漫反射，阴影色和高光颜色（在光线计算中定义）的加和。如果你将通道设置中的SeparateSpecular On，高光色会在混合计算后被加入，而不是之前。

（2）LightingOn

灯光应用打开

............

3、Material信息

Material Block 材质块

这些是为了设置材质如何影响光照。任何这些属性都能被排除，在这种情况下它们被认为默认为黑色（没起到效果）。

Diffuse Color 漫反射颜色

这个是物体最基础的颜色。

Ambient Color 环境色

当物体被环境光影响时候给物体设置颜色，这个取决于在RenderSettings中设置的环境颜色。

Specular Color 反射光

设置物体的高光反射颜色

Shininess Number 清晰度

突出清晰度，值在0和1之间。为0时候，你得到1个巨大的高光看起来像很多漫射光照；为1时候，你得到一个小的斑点。

Emission Color 自发光颜色

当没被其他光线影响时候，物体本身的自发光颜色。

当物体被所有光线照射时候他的颜色的计算公式如下：

Ambient * RenderSettings ambient setting +(LightColor * Diffuse + Light Color * Specular) + Emission

在括号中的那部分光线计算，是计算所有照射到物体上的光线。

通常情况下，你要保持漫反射和环境的颜色相同（所有内建的Unity3dshader 都是这么做的）。

参见附件例2。

       _Color ("Main Color", Color) = (1,1,1,0)

       _SpecColor ("Spec Color", Color) = (1,1,1,1)

       _Emission ("Emmisive Color", Color) = (0,0,0,0)

       _Shininess ("Shininess", Range (0.01, 1)) = 0.7

 Material {

   Diffuse [_Color]//漫反射颜色

   Ambient [_Color]//环境光颜色

   Shininess [_Shininess]//镜面反射系数

   Specular [_SpecColor]//镜面反射颜色

   Emission [_Emission]//自发光颜色

 }

4、SetTexture命令

纹理在基本的顶点光照被计算后被应用。在着色器中通过SetTexture 命令来完成。

SetTexture 命令在片面程序被使用时不会生效；这种模式下像素操作被完全描述在着色器中。

材质贴图可以用来做老风格的混合器效果。你能在一个通道中使用多个SetTexture命令 - 所有纹理被顺序的应用，如同绘画程序中的层一样。SetTexture 命令必须放置在通道的末尾。

SetTexture [TexturePropertyName] { TextureBlock }

分配一个纹理，TextureName必须定义为一个纹理属性。如何应用纹理被定义在TextrueBlock中

5、SetTexture语句块内其他命令

纹理块控制纹理如何被应用。在纹理块中能执行3种命令：合并combine，矩阵matrix和不变色constantColor。

（1）combine命令：

combine src1 * src2 将源1和源2的元素相乘。结果会比单独输出任何一个都要暗

combine src1 + src2将将源1和源2的元素相加。结果会比单独输出任何一个都要亮

combine src1 - src2源1 减去 源2

combine src1 +- src2先相加，然后减去0.5（添加了一个符号）

combine src1 lerp (src2) src3使用源2的透明度通道值在源3和源1中进行差值，注意差值是反向的：当透明度值是1是使用源1，透明度为0时使用源3

combine src1 * src2 + src3源1和源2的透明度相乘，然后加上源3

combine src1 * src2 +- src3源1和源2的透明度相乘，然后和源3做符号加

combine src1 * src2 - src3源1和源2的透明度相乘，然后和源3相减

（2）constantColor纹理块命令

ConstantColor color  定义在combine命令中能被使用的不变颜色

（3）matrix纹理块命令

matrix [MatrixPropertyName] 使用给定矩阵变换纹理坐标

（4）SeparateAlpha & Color computation 分离的透明度和颜色混合

缺省情况下，混合公式被同时用于计算纹理的RGB通道和透明度。同时，你也能指定只针对透明度进行计算，如下：

SetTexture [_MainTex] { combine previous *texture, previous + texture }

如上所述，我们对RGB的颜色做乘然后对透明度相加

所有源属性都可以是previous, constant, primary or texture其中的一个。

Previous 上一次SetTexture的结果

Primary 来自光照计算的颜色或是当它绑定时的顶点颜色

Texture 在SetTexture中被定义的纹理的颜色

Constant 被ConstantColor定义的颜色

 

附件：Examples 示例

1、Alpha Blending Two Textures （Alpha混合两个纹理）

这个小例子使用了两张纹理。首先设置第一个混合器只使用_MainTex,然后使用_BlendTex的Alpha通道来淡入_BlendTex的RGB颜色。

Shader "Examples/2 Alpha Blended Textures" {
    Properties {
        _MainTex ("Base (RGB)", 2D) = "white" {}
        _BlendTex ("Alpha Blended (RGBA) ", 2D) = "white" {}
    }
    SubShader {
        Pass {
            // Apply base texture
		// 应用主纹理
            SetTexture [_MainTex] {
                combine texture
            }
            // Blend in the alpha texture using the lerp operator
		// 使用差值操作混合Alpha纹理
            SetTexture [_BlendTex] {
                combine texture lerp (texture) previous
            }
        }
    }
}

2、Alpha Controlled Self-illumination （Alpha控制自发光）

这个着色器使用_MainTex的Alpha来描述什么地方应用光照。它通过分两个阶段应用纹理来实现；第一个阶段，纹理的Alpha值被用来在顶点颜色和纯白色之间混合。第二阶段，纹理的RGB值被乘入。

Shader "Examples/Self-Illumination" {
    Properties {
        _MainTex ("Base (RGB) Self-Illumination (A)", 2D) = "white" {}
    }
    SubShader {
        Pass {
            // Set up basic white vertex lighting
		//设置白色顶点光照
            Material {
                Diffuse (1,1,1,1)
                Ambient (1,1,1,1)
            }
            Lighting On

            // Use texture alpha to blend up to white (= full illumination)
		// 使用纹理Alpha来混合白色（完全发光）
            SetTexture [_MainTex] {
                constantColor (1,1,1,1)
                combine constant lerp(texture) previous
            }
            // Multiply in texture
		// 和纹理相乘
            SetTexture [_MainTex] {
                combine previous * texture
            }
        }
    }
}

我们能在这里尽可能自由的做些事，除了混合纯白色，我们还能添加一个自发光颜色然后和它混合和。注意ConstantColor的使用能从属性中获取一个纯色并应用到纹理混合中去。

Shader "Examples/Self-Illumination 2" {
    Properties {
        _IlluminCol ("Self-Illumination color (RGB)", Color) = (1,1,1,1)
        _MainTex ("Base (RGB) Self-Illumination (A)", 2D) = "white" {}
    }
    SubShader {
        Pass {
            // Set up basic white vertex lighting
            Material {
                Diffuse (1,1,1,1)
                Ambient (1,1,1,1)
            }
            Lighting On

            // Use texture alpha to blend up to white (= full illumination)
            SetTexture [_MainTex] {
                // Pull the color property into this blender
				// 使颜色属性进入混合器
                constantColor [_IlluminCol]
                // And use the texture's alpha to blend between it and
                // vertex color
		// 使用纹理的alpha通道混合顶点颜色
                combine constant lerp(texture) previous
            }
            // Multiply in texture
            SetTexture [_MainTex] {
                combine previous * texture
            }
        }
    }
}

最后，我们把顶点光照着色器的所有的光照属性放入：

Shader "Examples/Self-Illumination 3" {
    Properties {
        _IlluminCol ("Self-Illumination color (RGB)", Color) = (1,1,1,1)
        _Color ("Main Color", Color) = (1,1,1,0)
        _SpecColor ("Spec Color", Color) = (1,1,1,1)
        _Emission ("Emmisive Color", Color) = (0,0,0,0)
        _Shininess ("Shininess", Range (0.01, 1)) = 0.7
        _MainTex ("Base (RGB)", 2D) = "white" {}
    }

    SubShader {
        Pass {
            // Set up basic vertex lighting
            Material {
                Diffuse [_Color]
                Ambient [_Color]
                Shininess [_Shininess]
                Specular [_SpecColor]
                Emission [_Emission]
            }
            Lighting On

            // Use texture alpha to blend up to white (= full illumination)
            SetTexture [_MainTex] {
                constantColor [_IlluminCol]
                combine constant lerp(texture) previous
            }
            // Multiply in texture
            SetTexture [_MainTex] {
                combine previous * texture
            }
        }
    }
}