uboot之位置无关代码解析（推荐）

我们都知道我们写的代码最后是运行在内存（SDRAM或者SRAM，通常是SDRAM）中的，但是在运行之前他们是保存在诸如nand、flash等非易失存储设备中的，而这些存储设备的地址要映射到CPU能够寻找的地址上（一般映射在0X0地址上，这个后面详细解释），这样才能得到要运行的代码。而代码要运行的内存（这里就假设是SDRAM）也要映射到CPU上（肯定是和nand那些存储器不一样的地址，例如三星的2440的就映射到了0x30000000上），所以说存储在nand或者flash的代码最终得复制到内存上运行的。这里就记住代码存储的地方（加载地址）和代码要运行的地方（运行地址）是不一样的。

　　现在说一下地址映射的问题。在学习ARM时，我们一般会遇到两种启动方式，一个是nand启动，一个是nor启动。这两种启动方式都是映射到0x0地址的，但是映射方式稍有不同。所以先了解一下这两种介质的硬件特性：

　　　nand：由于nand存储器的硬件特性，代码是无法在他上面运行的，他只有存储代码的功能。

　　　nor：他不仅可以存储代码，还可以让代码运行，但是他只能进行读，不能进行写的操作，但毕竟是可以运行代码啦。

　　所以nand启动的话，如果没有进行特殊手段，代码是无法得到的，在ARM中，他是通过硬件自动把nand前面的4K代码复制到一块映射到0x0地址上的SRAM中的，记住这是硬件自动完成的。这样4K代码就在SRAM上了，我们知道SRAM是能运行代码的（可读可写）。但是这个SRAM只有4K大小，要是存储在nand的代码不止4K，只在SRAM上面运行是无法完成代码设定的所有功能的。为了解决这个问题，于是就在这4K的代码中完成一个可以将nand的代码复制到其他更大的内存上（这里是SDRAM），这样就可以运行所有代码了。

　　nor启动的话，由于nor可以运行代码，所以就不用什么SRAM了，直接把nor映射到0x0位置上就可了，如果nor空间够大，甚至可以不用重定位代码，只是nor无法进行写功能，读取的效率又没SDRAM高，加上为了兼容nand启动（不用写两套代码），也就跟nand启动一样只运行前面4K，剩下复制到SDRAM上再继续运行。

　　问题又来了，我们知道代码经过编译，链接后才可以得到可以运行的代码，而这代码只有在链接时指定的位置上才能运行。对于2440，链接文件指定的位置一般是在SDRAM上面的，可是nand启动时，前面的4K代码却在SRAM中运行了。

　　这会有什么问题？我们知道编写好的代码的地址在链接时就已经安排好了。例如2440链接文件指定链接地址是0x30008000，那么所有代码地址就是从0x30008000开始的。而在启动时，代码却是在0x0开始运行的，如果不进行特殊处理，肯定会有问题，比如我们调用一个函数，而这个函数地址是在SDRAM上的（链接时已经确定），并且这时代码还没复制到SDRAM上，也就是说代码还在nand或者在4K的SRAM里面，在SDRAM是找不到要调用的函数的，那样就会无法执行这个函数。

　　如果在还在nand里面肯定是没办法了，这个代码是无法运行的必须废弃，如果在4K的SRAM就有办法了。于是就出现了位置无关指令：

　　位置无关/相关指令：

　　　　B BL ADR MOV ADD等，这些指令都是位置无关指令

　　　　LDR STR等指令是位置有关指令

位置无关什么意思呢？

　　既然这个时候SDRAM还没有代码，那就不去那里找了嘛，我们去别的地方找。别的地方是哪里呢？这个时候代码是运行在SRAM上的，处理器的PC寄存器也是指向这个地方的，有4K代码也是在这个地方的。那我就不用链接指定的地址来寻找想要的代码，我设计一些是与PC寄存器指向的位置有联系的寻址指令来寻址，这样PC寄存器指向哪里，我就在哪里找我想要的代码，而不是去链接指定的地址去找。

　　位置无关指令就是这样的指令，他不去链接指定位置寻找代码，而是在PC寄存器指向的位置相对它前后32M的范围寻找代码，也就是说只要我想要调用的代码在PC指向位置前后的32M范围内，就能找到（这是硬件完成的，我们知道位置无关指令就是这个意思就行）。当然，我们的SRAM只有4K，所以寻找的范围肯定就只能在这4K里面才行了，超过了也是找不到的。所以要求我们的重定位代码必须在这4K里面，必要的硬件初始化代码，内存初始化代码，nand初始化代码等等，必须在4K以内完成，否则就会出问题。所以位置无关指令的寻址是基于当前PC寄存器位置来寻址的。

下面根据uboot的代码进行讲解

1.内存控制器初始化代码

_TEXT_BASE:

  .word     TEXT_BASE   /*根据链接地址得知这是0x30000000*/

.globl lowlevel_init /定义lowlevel_init为全局函数/

lowlevel_init:

  ldr     r0, =SMRDATA  /*链接后，SMRDATA是在SDRAM上某个位置的，但是这时候SDRAM还没任何代码，代码现在还在SRAM上，也就说ldr指令是位置相关指令*/

  ldr   r1, _TEXT_BASE  /*0x30000000*/

  sub  r0, r0, r1          /* SMRDATA减 _TEXT_BASE就是13个寄存器在SRAM上的地址 */

  ldr   r1, =BWSCON   /* R1指向内存控制器的寄存器地址上 */

  add     r2, r0, #13*4 /*有13个寄存器，每个32位宽度*/

0:

  ldr     r3, [r0], #4    /*将13个寄存器的值逐一赋值给对应的寄存器*/

  str     r3, [r1], #4

  cmp     r2, r0

  bne     0b



  /* everything is fine now */

  mov       pc, lr



  .ltorg

/* the literal pools origin */

SMRDATA: /* 下面是13个寄存器的值 */

.word … …

.word … …

… …

2.nor启动的重定位代码

　　adr r0, _start /adr是位置无关指令，因为nor启动，这时第一条指令被映射到nor上的0x0位置，所以R0=0x0，如果是RAM启动，那_start就是存在0x30000000了 /

  ldr   r1, _TEXT_BASE            /* 位置相关指令，R1=0x30000000 */

/* 判断U-Boot是否是下载到RAM中运行，若是，则不用 再复制到RAM中了，这种情况通常在调试U-Boot时才发生 */

  cmp      r0, r1      /*_start等于_TEXT_BASE说明是下载到RAM中运行 */

  beq stack_setup

/* 以下直到nand_boot标号前都是NOR Flash启动的代码 */

  ldr   r2, _armboot_start  /*这里其实就是_start的地址*/

  ldr   r3, _bss_start

  sub  r2, r3, r2              /* 得到代码大小   */

  add r2, r0, r2              /* 得到代码结束地址   */

/* 搬运U-Boot自身到RAM中*/

copy_loop:

  ldmia     r0!, {r3-r10} /* 从地址为[r0]的NOR Flash中读入8个字的数据 */

  stmia      r1!, {r3-r10} /* 将r3至r10寄存器的数据复制给地址为[r1]的内存 */

  cmp       r0, r2                    /* until source end addreee [r2]    */

  ble  copy_loop

  b     stack_setup         /* 跳过NAND Flash启动的代码 */

以上就是位置无关代码的解析了，uboot在运行第二阶段之前，绝大部分的指令都是位置无关指令，这样才能保证代码能够运行。
uboot启动代码分析见：http://www.doc88.com/p-338768273255.html