Fresnel(菲涅尔)

背景: 菲涅耳公式用来描述光在不同折射率的介质之间的行为。菲涅尔公式是光学中的重要公式，用它能解释反射光的强度、折射光的强度、相位与入射光的强度的关系。

1. 反射公式: fresnel = fresnel基础值 + fresnel缩放量*pow( 1 - dot( N, V ), 5 )

Code:菲涅尔反射

Shader "Nina/Shader/Inking/Fresnel Reflection"

{
	//属性
	Properties
	{
		//主纹理
		_MainTex("Main Texture", 2D) = "white" {}
		//菲涅尔基础值
		_FresnelBase("Fresnel Base", Range(0, 1)) = 1
		//菲涅尔缩放
		_FresnelScale("Fresnel Scale", Range(0, 1)) = 1
		//菲涅尔系数
		_FresnelIndensity("Fresnel Indensity", Range(0, 5)) = 5
		//菲涅尔反射颜色
		_FresnelColor("Fresnel Col", Color) = (1,1,1,1)
	}
	//子着色器
	SubShader
	{
		//渲染类型:不透明
		Tags{ "RenderType" = "Opaque" }
		//level of detail
		LOD 100
		//通道
		Pass
		{
			
			//光照模式:forward
			tags{ "lightmode=" = "forward" }
			//开启CG着色器编程语言段
			CGPROGRAM
				//声明：顶点和片段着色函数名称
				#pragma vertex vert
				#pragma fragment frag
				//引入头文件：UnityCG Lighting
				#include "UnityCG.cginc"
				#include "Lighting.cginc"
				//指定Shader Model：3.0
				#pragma target 3.0
				//顶点输入结构体
				struct VertexInput
				{
					//顶点位置
					float4 vertex : POSITION;
					//一级纹理坐标
					float2 uv : TEXCOORD0;
					//法线向量坐标
					float3 normal : NORMAL;
				};
				//顶点输出结构体
				struct VertexOutput
				{
					//一级纹理坐标
					float2 uv : TEXCOORD0;
					//像素位置
					float4 vertex : SV_POSITION;
					//光照向量坐标
					float3 L : TEXCOORD1;
					//法线向量坐标
					float3 N : TEXCOORD2;
					//视角向量坐标
					float3 V : TEXCOORD3;
				};
				//变量
				//主纹理
				sampler2D _MainTex;
				//主纹理 ST（SamplerTexture）
				float4 _MainTex_ST;
				//菲涅尔基础值
				float _FresnelBase;
				//菲涅尔缩放
				float _FresnelScale;
				//菲涅尔系数
				float _FresnelIndensity;
				//菲涅尔反射光颜色
				float4 _FresnelColor;
				//顶点着色函数
				VertexOutput vert(VertexInput v)
				{
					//声明输出声明一个顶点输出结构对象
					VertexOutput o;
					//计算顶点
					o.vertex = UnityObjectToClipPos(v.vertex);
					//计算UV
					o.uv = TRANSFORM_TEX(v.uv, _MainTex);
					//将法线转到世界坐标
					o.N = mul(v.normal, (float3x3)unity_WorldToObject);
					//获取世界坐标的光向量
					o.L = WorldSpaceLightDir(v.vertex);
					//获取世界坐标的视角向量
					o.V = WorldSpaceViewDir(v.vertex);
					//返回返回此输出结构对象
					return o;
				}
				//片段函数
				fixed4 frag(VertexOutput i) : SV_Target
				{
					//获取颜色
					fixed4 col = tex2D(_MainTex, i.uv);
					//计算normal dir
					float3 N = normalize(i.N);
					//计算light dir
					float3 L = normalize(i.L);
					//计算view dir
					float3 V = normalize(i.V);
					//计算rgb
					col.rgb *= saturate(dot(N, L)) * _LightColor0.rgb;
					//菲涅尔公式
					float fresnel = _FresnelBase + _FresnelScale*pow(1 - dot(N, V), _FresnelIndensity);
					//计算rgb
					col.rgb += lerp(col.rgb, _FresnelColor, fresnel) * _FresnelColor.a;
					//返回最终颜色
					return col;
				}
			ENDCG
		}
	}
}