利用windows脚本实现文件的自动备份

我们在系统里面总是会有一些文件需要定期备份的。比如说web页面，某些应用程序的配置文件等。一般来说，在linux系统下，我们可以利用tar命令将指定的一些文件打包成一个文件。在windows系统下，可以利用winrar软件来实现同样的功能。如果为了将d:/web目录下的所有文件压缩成一个文件，则命令行方式如下：

winrar a -r -ibck webtar d:/web/

其中，a 表示创建rar文件，-r 表示包括子目录，-ibck 表示后台运行程序，webtar表示最终文件名。 

对于备份来说，一般有一台服务器专门保存备份的文件，比如说利用ftp协议进行传送。windows下自带的ftp的命令行执行方式如下：

ftp -s:myscript.scr

其中 myscript.scr 文件是自己编写的一个ftp脚本。如果为了将webtar文件传送到202.118.227.1的服务器上面，则myscript.scr文件示例如下： 

open 202.118.227.1
michael
yyxx3.0_2
cd backup
put webtar.rar
quit

最后，将编写好的脚本放入windows的自动执行里面，就可以实现自动备份了。

完整的示例如下：

=======================================

@echo off

rem
rem 定义一些参数
rem
set version=written by MichaelZheng, 2005.09.14, v0.3
set dest=e:/backups/datas
set dest_uedit=%dest%/UltraEdit
set dest_unispim=%dest%/unispim
set dest_radmin=%dest%/Radmin
set dest_favorites=%dest%/Favorites

rem 如果使用了参数 --version，就仅输出版本信息
if "%1"=="--version" goto label_about

echo **************************************************************
echo 本脚本备份一些绿色软件的配置文件，用于重装系统前收集系统信息用
echo %version%
echo **************************************************************

echo 配置文件将会被备份到%dest%目录下

:label_normal
mkdir %dest%
mkdir %dest_uedit%
mkdir %dest_unispim%
mkdir %dest_radmin%
mkdir %dest_favorites%

echo.
echo 拷贝 UltraEdit的配置文件 到 %dest_uedit% 目录下
xcopy %SystemRoot%/uedit32.ini %dest_uedit% /s/h/y
echo.
echo 拷贝 紫光输入法字库和配置 到 %dest_unispim% 下
xcopy "%APPDATA%/unispim" %dest_unispim% /s/h/y
echo.
echo 拷贝 radmin-client的配置文件 到 %dest_radmin% 目录下
copy "%APPDATA%/Radmin" %dest_radmin%
echo.
echo 拷贝 IE“收藏夹” 到 %dest_favorites% 目录下
xcopy "%USERPROFILE%/Favorites" %dest_favorites% /s/h/y

echo.
echo **************************************************************
echo 备份“知识库”文档和web脚本到 ftp://202.118.227.1 上面
echo **************************************************************

set wiki_datas=d:/docs/wikis
set wiki_programs=d:/GreenSofts/jakarta-tomcat-5.5.9/webapps

echo.
echo 删除老的备份...
del wiki-data-old.rar
del wiki-pro-old.rar
rename wiki-data.rar wiki-data-old.rar
rename wiki-pro.rar wiki-pro-old.rar

echo.
echo 开始压缩，可能需要等待几分钟...
winrar a -ibck wiki-data %wiki_datas%/*.txt
winrar a -r -ibck wiki-pro   %wiki_programs%/

echo.
echo 开始传送到远程计算机上...
ftp -s:ftp.scr

goto label_end

:label_about
echo %version%
goto label_end

:label_end
echo 备份结束
pause

rem %* 将列出所有参数， %1 列出第一个参数，%0列出批处理文件名