PowerDesigner使用笔记

PD的数据库设计使用：

一. 创建数据库连接：

• file ->
• 
• 选择对应的数据库--mysql，

• 选择使用数据库连接，创建JDBC连接池，并编写配置文件

• 编写配置文件：

• Connection profile name：JDBC配置文件名称，可随意填写
• Directory：配置文件保存路径   --------  这里系统默认的目录最好不要修改，修改后好像不能生成配置文件。
• Description：配置文件描述，可根据实际用途填写
• Connection type：连接方式，这里我们选择JDBC
• DBMS type：数据库类型，提供大部分主流数据库选择，我们选择MySQL
• User name：登录数据库的用户名
• JDBC driver class：指定驱动类，使用默认的com.mysql.jdbc.Driver
• JDBC connection URL：连接URL，格式jdbc:mysql://ServerIP/Hostname:port/firstdatabase?serverTimezone=UTC  ,此处firstdatabase是你想连接的数据库
• JDBC driver jar files：指定连接的jar包路径
• 连接测试

在连接过程中可能会报错‘无法初始化JVM’，原因是因为PD的内置JVM 是32位的，本机安装的是64位的，所以无法使用，解决方案：下载JDK32位然后安装，将mysql的连接jar包放在新安装JDK的bin路径下，然后修改环境变量，将JAVA_HOEM修改为32位的安装路径，并且在CLASSPATH环境变量中新增mysql连接jar的路径：C:\Program Files (x86)\Java\jdk1.8.131_32bit\bin\mysql-connector-java-8.0.16.jar。然后保存重启PD，即可解决该问题

 

二：将数据库导入PD，并显示注释

• 创建完成JDBC连接后，选择相应的数据库和数据表，完成导入
• 将导入的数据表显示注释，效果如下：

• 方案：

1. 在tool中选择Display Preferences

在Table中选择Comment，这样即可将表的注释显示出来

2. 将表字段的注释显示

Tools->Display Preferences->Table->Advanced...->Columns->List Columns，然后将Code移到最上面，保存

tools  -> Execute Commands _edit/run script

复制以下就脚本run：

'******************************************************************************
'* File:     comment2code.vbs
'* Purpose: 在PowerDesigner的PDM图形窗口中显示数据列的中文注释
'* Title:    将字段的comment赋值到字段的code中
'* Category: 打开物理模型，运行本脚本（Ctrl+Shift+X）
'* Copyright:[email protected],2006/07/25 .
'* Author:   foxzz
'* Created:
'* Modified:
'* Version: 1.0
'* Comment: 遍历物理模型中的所有表，将字段的comment赋值到字段的code中。
'            在将code置换为comment过程中，需要考虑的问题
'            1、code必须唯一，而comment有可能不唯一。
'               处理办法是如果字段的comment重复，则字段的code=comment+1、2、3...
'            2、comment值有可能为空，这种情况下对字段的code不处理。
'               针对oracle数据库,将comment on column 字段名称 is '';添加到C:\pdcomment.txt文件中。
'               在补充comment完毕后，便于在数据库中执行      
'******************************************************************************
 
Option Explicit
ValidationMode = True
InteractiveMode = im_Batch
 
Dim system, file
Set system = CreateObject("Scripting.FileSystemObject")
Dim ForReading, ForWriting, ForAppending   '打开文件选项
ForReading   = 1 ' 只读
ForWriting   = 2 ' 可写
ForAppending = 8 ' 可写并追加
'打开文本文件
Set file = system.OpenTextFile("C:\pdcomment.txt", ForWriting, true)
 
 
'判断当前model是否物理数据模型
Dim mdl
Set mdl = ActiveModel
If (mdl Is Nothing) Then
   MsgBox "处理对象无模型"
ElseIf Not mdl.IsKindOf(PdPDM.cls_Model) Then
   MsgBox "当前模型不是物理数据模型"
Else
   ProcessFolder mdl,file
End If
file.Close
 
 
'******************************************************************************
Private sub ProcessFolder(folder,file)
 
Dim i,j,k
i=0:j=0:k=0
 
'列数组，记录字段里不重复的comment
Dim ColumnComment()
Dim ColumnCommentNumber()
ReDim Preserve ColumnComment(i)
ReDim Preserve ColumnCommentNumber(i)
 
Dim tbl   '当前表
Dim col   '当前字段
dim curComment '当前字段comment
 
'处理模型中的表
for each tbl in folder.tables
    if not tbl.isShortcut then
       if len(trim(tbl.comment))<>0 then
          '可以在这里显示table的comment
          'tbl.code = tbl.code+"("+trim(tbl.comment)+")"
       end if 
 
       '处理表中的列
       for each col in tbl.columns
           k = 0
           curComment = trim(col.comment)
           if len(curComment)<>0 then
              '遍历相异的comment数组
              for j = 0 to i
                  if ColumnComment(j) = curComment then
                     '如果找到相同的comment,则相关计数器加1
                     ColumnCommentNumber(j) = ColumnCommentNumber(j) + 1
                     k = j
                  end if
              Next
              '如果没有相同的comment,则k=0,此时ColumnCommentNumber(0)也为0
              '否则ColumnCommentNumber(k)不为0
              if ColumnCommentNumber(k) <> 0 then
                 col.code = curComment & cstr(ColumnCommentNumber(k))
              else
                 col.code = curComment
                 'ColumnComment(0)、ColumnCommentNumber(0)永远为空
                 '将相异的comment记录添加到数组中
                 i = i + 1
                 ReDim Preserve ColumnComment(i)
                 ReDim Preserve ColumnCommentNumber(i)
                 ColumnComment(i) = curComment
                 ColumnCommentNumber(i) = 0
              end if
           else
              '写入文件中
              file.WriteLine "comment on column "+ tbl.code+"."+col.code+" is '';"         
           end if
       next
    end if
    '由于不同表的code允许相同,因此此时重新初始化。
    '因为ColumnComment(0)、ColumnCommentNumber(0)为空，可以保留
    ReDim Preserve ColumnComment(0)
    ReDim Preserve ColumnCommentNumber(0)
    i=0:j=0:k=0
 
next
 
Dim view '当前视图
for each view in folder.Views
    if not view.isShortcut then
       '可以在这里显示view的comment
       'view.code = view.comment
    end if
next
 
'对子目录进行递归
Dim subpackage 'folder
For Each subpackage In folder.Packages
    if not subpackage.IsShortcut then
       ProcessFolder subpackage , file
    end if
Next
 
end sub

参考博客：

https://blog.csdn.net/u011781521/article/details/78958529