物联网系列③——基于ESP8266与点灯科技平台的温湿度计设计（接入小爱同学）

一、设计目标

      前一阵子偶然接触到点灯科技平台，产生了制作一块ESP8266电路板，拥有以下功能：

1. 使用CH340对ESP8266进行程序下载
2. 使用DHT11进行温湿度数据读取
3. 使用点灯科技平台接入物联网，可通过手机APP获得室内温湿度
4. 接入小爱同学，通过语音获取室内温湿度信息
5. Mico USB 5V供电
6. 0.96OLED进行数据显示
7. 2按键进行画面切换
8. 多余IO口引出备用
   

二、电路展示

三、存在的问题

      电路板在制作的过程中比较匆忙，忽视了ESP8266 HSPI引脚难以复用的问题，错误地将其用于0.96寸OLED会导致该OLED无法显示，说明要驱动0.96寸OLED需通过普通IO口连接。同时这个设计也反应出ESP8266 IO口不足的问题。因此OLED显示和按键控制先搁置，目前仅实现物联网功能，通过点灯科技平台接入,以及通过小爱同学语音获取室内温湿度数据。

四、代码

#define BLINKER_PRINT Serial
#define BLINKER_WIFI
#define BLINKER_MIOT_SENSOR

#include 
#include 

dht11 DHT11;

char auth[] = "************";//设备号，由点灯平台获得
char ssid[] = "********";//无线账号
char pswd[] = "********";//无线密码

// 新建组件对象
BlinkerButton Button1("LED_Button");
BlinkerNumber HUM("hum");
BlinkerNumber TEMP("temp");

// 设置 DHT 引脚 为 Pin 16
#define DHT11PIN 16
//心跳包
void heartbeat()
{
    //DHT11.read(DHT11PIN);
    HUM.print((float)DHT11.humidity);
    TEMP.print((float)DHT11.temperature);
}
// 按下按键即会执行该函数
void button1_callback(const String & state) {
    BLINKER_LOG("get button state: ", state);
    digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
    if(digitalRead(LED_BUILTIN)==1)
    {
      Button1.print("off");
     }
     else
     {
       Button1.print("on");
      }
}
//云存储温湿度数据函数
void dataStorage()
{
    Blinker.dataStorage("temp_chart", (float)DHT11.temperature);//存储温度
    Blinker.dataStorage("hum_chart", (float)DHT11.humidity);//存储湿度
}
// 如果未绑定的组件被触发，则会执行其中内容
void dataRead(const String & data)
{
    BLINKER_LOG("Blinker readString: ", data);

}
//小爱同学处理函数
void miotQuery(int32_t queryCode)
{
    BLINKER_LOG("MIOT Query codes: ", queryCode);
    
    switch (queryCode)
    {
        
        case BLINKER_CMD_QUERY_HUMI_NUMBER :
            BLINKER_LOG("MIOT Query HUMI");
            BlinkerMIOT.humi(DHT11.humidity);
            BlinkerMIOT.print();
            break;
        case BLINKER_CMD_QUERY_TEMP_NUMBER :
            BLINKER_LOG("MIOT Query TEMP");
            BlinkerMIOT.temp(DHT11.temperature);
            BlinkerMIOT.print();
            break;
       case BLINKER_CMD_QUERY_ALL_NUMBER :
            BLINKER_LOG("MIOT Query All");
            BlinkerMIOT.temp(DHT11.temperature);
            BlinkerMIOT.humi(DHT11.humidity);
            BlinkerMIOT.print();
            break;
        default :
            BlinkerMIOT.temp(20);
            BlinkerMIOT.humi(20);
            //BlinkerMIOT.pm25(20);
            //BlinkerMIOT.co2(20);
            BlinkerMIOT.print();
            break;
    }
}

void setup() {
    // 初始化串口
    Serial.begin(115200);

    #if defined(BLINKER_PRINT)
        BLINKER_DEBUG.stream(BLINKER_PRINT);
    #endif

    // 初始化有LED的IO
    pinMode(LED_BUILTIN, OUTPUT);
    digitalWrite(LED_BUILTIN, HIGH);

    // 初始化blinker
    Blinker.begin(auth, ssid, pswd);
    Blinker.attachData(dataRead);
    Button1.attach(button1_callback);//按键
    Blinker.attachHeartbeat(heartbeat);//心跳包
    Blinker.attachDataStorage(dataStorage);//图表
    //小爱回调函数
    BlinkerMIOT.attachQuery(miotQuery);
}

void loop() {
    DHT11.read(DHT11PIN);
    Blinker.run();
}

      DHT11温湿度传感器库文件：https://download.csdn.net/download/weixin_43278295/15352131 解压至文档中arduino文件夹下的libraries中即可。

五、需要注意的问题

      新的ESP8266芯片首次烧写代码时需串口连接后手动将GPIO0电平拉低，再按下RST键完成烧写。之后的烧写就无须手动拉低了，直接串口下载即可。本人第一次烧写代码一直烧写失败，一度怀疑是串口下载电路设计上出现问题。
      ESP8266接收的命令需与云端（手机APP端）下发的命令一致，才能进行执行。所以在设置点灯APP时需注意代码中的接收命令与云端下发命令要一一对应。详细教程可根据点灯科技官方教程学习，本文提供的是温湿度计手机端控制和小爱童鞋语音控制的项目整合。
       根据以上代码，上电后ESP8266接入无线，在手机上的点灯APP中可看到设备在线，可获得温湿度数据并对ESP8266板载LED进行开关灯操作，可通过小爱同学语音获得室内温湿度数据。
       不足之处还望各位大佬不吝赐教！