【C语言详解】——函数栈帧的创建与销毁（动图详解）
前言：我们在写C语言代码的时候，经常会把一个独立的功能抽象为函数，以供main函数调用。所以C程序是以函数为基本单位的。表面来看调用的过程就是写出一个函数后，只需要在调用时中通过函数名将实参传给形参就实现了整个过程，但实际上调用的过程远比你想的复杂，函数是如何调用的？函数的返回值又是如何运作的？函数参数是如何传递的？这些问题都离不开函数栈帧在其中扮演着的关键作用。
目录
- 1. 什么是函数栈帧
- 2. 理解函数栈帧能解决什么问题呢？
- 3. 函数栈帧的创建和销毁解析
-
- 3.1 什么是栈？
- 3.2 认识相关寄存器和汇编指令
- 3.3 解析函数栈帧的创建和销毁
-
- 3.3.1 预备知识
- 3.3.2 函数的调用堆栈
- 3.3.3 准备环境
- 3.3.4 转到反汇编
- 3.3.5 函数栈帧的创建
- 3.3.6 Add函数栈帧的创建
- 3.3.7 函数栈帧的销毁
- 3.3.8 函数栈帧相关问题解答
1. 什么是函数栈帧
函数栈帧（stack frame）就是函数调用过程中在程序的调用栈（call stack）所开辟的空间，这些空间是用来存放：
- 函数参数和函数返回值
- 临时变量（包括函数的非静态的局部变量以及编译器自动生产的其他临时变量）
- 保存上下文信息（包括在函数调用前后需要保持不变的寄存器）。
| 区域 | 作用 |
|---|---|
| 栈区（stack） | 由编译器自动分配和释放，存放函数的参数值，局部变量的值等。操作方式类似与数据结构中的栈 |
| 堆区（heap） | 如动态内存开辟函数malloc 等，一般由程序员分配和释放，若程序员不释放，程序结束时可能由操作系统回收。与数据结构中的堆是两码事，分配方式类似于链表 |
| 静态区（static） | 全局变量和静态变量存放于此 |
| 文字常量区 | 常量字符串放在此，程序结束后由系统释放 |
| 程序代码区 | 存放函数体的二进制代码 |
2. 理解函数栈帧能解决什么问题呢？
比如说以下问题就能够很好的理解了：
- 局部变量是如何创建的？
- 为什么局部变量不初始化内容是随机的？
- 函数调用时参数时如何传递的？传参的顺序是怎样的？
- 函数的形参和实参的关系？
- 函数的返回值是如何带回的？
让我们一起走进函数栈帧的创建和销毁的世界里吧！
3. 函数栈帧的创建和销毁解析
3.1 什么是栈？
- 在经典的计算机科学中，栈被定义为一种特殊的容器，用户可以将数据压入栈中（入栈，push），也可以将已经压入栈中的数据弹出（出栈，pop），但是栈这个容器必须遵守一条规则：先入栈的数据后出栈（First In Last Out， FIFO）。和数据结构中栈的使用规则相似。
- 在计算机系统中，栈帧是一个具有以上属性的动态内存区域。程序可以将数据压入栈中，也可以将数据从栈顶弹出。压栈操作使得栈增大，而弹出操作使得栈减小。
- 在经典的操作系统中，栈总是向下增长（
由高地址向低地址）的。栈区总是先使用高地址，再使用低地址。- 在我们常见的i386或者x86-64下，栈顶由成为 esp 的寄存器进行定位的。
3.2 认识相关寄存器和汇编指令
在了解函数调用栈帧之前，我们先来认识几个寄存器（寄存器是集成在CPU上的，区别于内存）：
| 寄存器名称 | 作用 |
|---|---|
| eax | 累加(Accumulator)寄存器，保留临时数据，常用于函数返回值 |
| ebx | 基址(Base)寄存器，保留临时数据，以它为基址访问内存 |
| ecx | 计数器(Counter)寄存器，常用作字符串和循环操作中的计数器 |
| edx | 数据(Data)寄存器，常用于乘除法和I/O指针 |
| esi | 源变址寄存器 |
| dsi | 目的变址寄存器 |
| esp | 堆栈(Stack)指针寄存器，指向堆栈顶部 |
| ebp | 基址指针寄存器，指向当前堆栈底部 |
| eip | 指令寄存器，指向下一条指令的地址 |
| 汇编指令 | 用途 |
|---|---|
| mov | mov A,B 将数据B移动到A |
| push | 压栈（入栈），同时esp栈顶寄存器也要发生改变 |
| pop | 出栈到指定位置，同时esp栈顶寄存器也要发生改变 |
| call | 函数调用 |
| add | 加法 |
| sub | 减法 |
| rep | 重复 |
| lea | （load effective address）加载有效地址 |
| call | 函数调用，1. 压入返回地址 2. 转入目标函数 |
| jump | 通过修改eip，转入目标函数，进行调用 |
| ret | 恢复返回地址，压入eip，类似pop eip命令 |
3.3 解析函数栈帧的创建和销毁
3.3.1 预备知识
- 每一次函数调用，都要为本次函数调用开辟空间，就是函数栈帧的空间。
- 这块空间的维护是使用了2个寄存器： esp 和 ebp ， ebp 记录的是栈底的地址， esp 记录的是栈顶
的地址。
- 函数栈帧的创建和销毁过程，在不同的编译器上实现的方法大同小异，本次演示以VS2019为例。
3.3.2 函数的调用堆栈
演示代码：
#include 调试后，我们就可以观察到函数的调用堆栈（右击勾选【显示外部代码】），
函数调用堆栈是反馈函数调用逻辑的，那我们可以清晰的观察到， main 函数调用之前，是由
invoke_main 函数来调用main函数。
我们顺着堆栈帧列表依次点击，可以看到在main函数调用之前有更多的函数套娃调用。比如下图，return 0就被返回到这里了。
在本期探讨中，在 invoke_main函数之前的函数调用我们就暂时不考虑了。
那我们可以确定， invoke_main 函数应该会有自己的栈帧， main 函数和 Add 函数也会维护自己的栈
帧，每个函数栈帧都有自己的 ebp 和 esp 来维护栈帧空间。
那接下来我们从main函数的栈帧创建开始讲解：
3.3.3 准备环境
为了让我们研究函数栈帧的过程足够清晰，不要太多干扰，我们可以关闭下面的选项，让汇编代码中排
除一些编译器附加的代码：
3.3.4 转到反汇编
调试到main函数开始执行的第一行，右击鼠标转到反汇编。
注：VS编译器每次调试都会为程序重新分配内存，因此每次运行结果都会有差异。
int main()
{
//函数栈帧的创建
00651820 push ebp
00651821 mov ebp,esp
00651823 sub esp,0E4h
00651829 push ebx
0065182A push esi
0065182B push edi
0065182C lea edi,[ebp-24h]
0065182F mov ecx,9
00651834 mov eax,0CCCCCCCCh
00651839 rep stos dword ptr es:[edi]
//main函数的核心代码
int a = 10;
0065183B mov dword ptr [ebp-8],0Ah
int b = 20;
00651842 mov dword ptr [ebp-14h],14h
int ret = 0;
00651849 mov dword ptr [ebp-20h],0
ret = Add(a, b);
00651850 mov eax,dword ptr [ebp-14h]
00651853 push eax
00651854 mov ecx,dword ptr [ebp-8]
00651857 push ecx
00651858 call 006510B4
0065185D add esp,8
00651860 mov dword ptr [ebp-20h],eax
printf("%d\n", ret);
00651863 mov eax,dword ptr [ebp-20h]
00651866 push eax
00651867 push 657B30h
0065186C call 006510D2
00651871 add esp,8
return 0;
00651874 xor eax,eax
}
main 函数转化来的汇编代码如上所示。
3.3.5 函数栈帧的创建
接下来我们一行行拆解汇编代码
00651820 push ebp //把ebp寄存器中的值进行压栈，此时的ebp中存放的是invoke_main函数栈帧的ebp，esp-4
00651821 mov ebp,esp move指令会把esp的值存放到ebp中，相当于产生了main函数的ebp，这个值就是invoke_main函数栈帧的esp
00651823 sub esp,0E4h //sub会让esp中的地址减去一个16进制数字0xe4,产生新的esp，此时的esp是main函数栈帧的esp，此时结合上一条指令的ebp和当前的esp，ebp和esp之间维护了一个块栈空间，这块栈空间就是为main函数开辟的，就是main函数的栈帧空间，这一段空间中将存储main函数中的局部变量，临时数据已经调试信息等。
00651829 push ebx //将寄存器ebx的值压栈，esp-4
0065182A push esi //将寄存器esi的值压栈，esp-4
0065182B push edi //将寄存器edi的值压栈，esp-4
//上面3条指令保存了3个寄存器的值在栈区，这3个寄存器的在函数随后执行中可能会被修改，所以先保存寄存器原来的值，以便在退出函数时恢复。
下面的代码是在初始化main函数的栈帧空间。
-
先把ebp-24h的地址，放在edi中
-
把9放在ecx中
-
把0xCCCCCCCCh放在eax中
-
将从edi到ebp这一段的内存的每个字节都初始化为0xCC，同时把ebp赋值给edi。
0065182C lea edi,[ebp-24h]
0065182F mov ecx,9
00651834 mov eax,0CCCCCCCCh
00651839 rep stos dword ptr es:[edi] //dword）（4个字节）
上面这4句代码，等价于下面的伪代码：
edi = ebp-0x24;
ecx = 9;
eax = 0xCCCCCCCCh;
for(; ecx = 0; --ecx,edi+=4)
{
*(int*)edi = eax;
}
完整过程：
小知识：烫烫烫~
之所以上面的程序输出“烫”这么一个奇怪的字，是因为main函数调用时，在栈区开辟的空间的其中每一
个字节都被初始化为0xCC，而arr数组是一个未初始化的数组，恰好在这块空间上创建的，0xCCCC（两
个连续排列的0xCC）的汉字编码就是“烫”，所以0xCCCC被当作文本就是“烫”。
接下来我们再分析main函数中的核心代码：
int a = 10;
0065183B mov dword ptr [ebp-8],0Ah //将10存储到ebp-8的地址处，ebp-8的位置其实就是a变量
int b = 20;
00651842 mov dword ptr [ebp-14h],14h //将20存储到ebp-14h的地址处，ebp-14h的位置其实是b变量
int ret = 0;
00651849 mov dword ptr [ebp-20h],0 //将0存储到ebp-20h的地址处，ebp-20h的位置其实是ret变量
以上汇编代码表示的变量a,b,ret的创建和初始化，这就是局部的变量的创建和初始化。
其实是局部变量的创建时在局部变量所在函数的栈帧空间中创建的。
ret = Add(a, b); //调用Add函数时的传参，其实传参就是把参数push到栈帧空间中
00651850 mov eax,dword ptr [ebp-14h] //传递b，将ebp-14h处放的20放在eax寄存器中
00651853 push eax //将eax的值压栈，esp-4
00651854 mov ecx,dword ptr [ebp-8] //传递a，将ebp-8处放的10放在ecx寄存器中
00651857 push ecx //将ecx的值压栈，esp-4
//跳转调用函数
00651858 call 006510B4 //按F11进入
0065185D add esp,8
00651860 mov dword ptr [ebp-20h],eax
call 指令是要执行函数调用逻辑的，在执行call指令之前先会把call指令的下一条指令的地址进行压栈
操作，这个操作是为了解决当函数调用结束后要回到call指令的下一条指令的地方，继续往后执行。
3.3.6 Add函数栈帧的创建
当我们跳转到Add函数，就要开始观察Add函数的反汇编代码了。
int Add(int x, int y)
{
00BE1760 push ebp //将main函数栈帧的ebp保存,esp-4
00BE1761 mov ebp,esp //将main函数的esp赋值给新的ebp，ebp现在是Add函数的ebp
00BE1763 sub esp,0CCh //给esp-0xCC，求出Add函数的esp
00BE1769 push ebx //将ebx的值压栈,esp-4
00BE176A push esi //将esi的值压栈,esp-4
00BE176B push edi //将edi的值压栈,esp-4
int z = 0;
00BE176C mov dword ptr [ebp-8],0 //将0放在ebp-8的地址处，其实就是创建z
z = x + y; //接下来计算的是x+y，结果保存到z中
00BE1773 mov eax,dword ptr [ebp+8] //将ebp+8地址处的数字存储到eax中
00BE1776 add eax,dword ptr [ebp+0Ch] //将ebp+12地址处的数字加到eax寄存中
00BE1779 mov dword ptr [ebp-8],eax //将eax的结果保存到ebp-8的地址处，其实就是放到z中
return z;
00BE177C mov eax,dword ptr [ebp-8] //将ebp-8地址处的值放在eax中，其实就是把z的值存储到eax寄存器中，这里是想通过eax寄存器带回计算的结果，做函数的返回值。
}
00BE177F pop edi
00BE1780 pop esi
00BE1781 pop ebx
00BE1782 mov esp,ebp
00BE1784 pop ebp
00BE1785 ret
代码执行到Add函数的时候，就要开始创建Add函数的栈帧空间了。
在Add函数中创建栈帧的方法和在main函数中是相似的，在栈帧空间的大小上略有差异而已。
- 将main函数的 ebp 压栈
- 计算新的 ebp 和 esp
- 将 ebx ， esi ， edi 寄存器的值保存
- 计算求和，在计算求和的时候，我们是通过 ebp 中的地址进行偏移访问到了函数调用前压栈进去的
参数，这就是形参访问。 - 将求出的和放在 eax 寄存器准备带回
完整演示：
图片中的 x和 y其实就是 Add 函数的形参。这里很好的说明了函数的传参过程，以及函数在进行值传递调用的时候，形参其实是实参的一份临时拷贝。对形参的修改不会影响实参。
3.3.7 函数栈帧的销毁
当函数调用要结束返回的时候，前面创建的函数栈帧也开始销毁。
00BE177F pop edi //在栈顶弹出一个值，存放到edi中，esp+4
00BE1780 pop esi //在栈顶弹出一个值，存放到esi中，esp+4
00BE1781 pop ebx //在栈顶弹出一个值，存放到ebx中，esp+4
00BE1782 mov esp,ebp //再将Add函数的ebp的值赋值给esp，相当于回收了Add函数的栈
帧空间
00BE1784 pop ebp //弹出栈顶的值存放到ebp，栈顶此时的值恰好就是main函数的ebp，esp+4，此时恢复了main函数的栈帧维护，esp指向main函数栈帧的栈顶，ebp指向了main函数栈帧的栈
底。
00BE1785 ret //ret指令的执行，首先是从栈顶弹出一个值，此时栈顶的值就是call指令下一条指令的地址，此时esp+4，然后直接跳转到call指令下一条指令的地址处，继续往下执行。
完整演示：
之后回到了call指令的下一条指令的地方：
但调用完Add函数，回到main函数的时候，继续往下执行，可以看到：
0065185D add esp,8 //esp直接+8，相当于跳过了main函数中压栈的x和y
00651860 mov dword ptr [ebp-20h],eax //将eax中值，存档到ebp-0x20的地址处，其实就是存储到main函数中ret变量中，而此时eax中就是Add函数中计算的x和y的和，可以看出来，本次函数的返回值是由eax寄存器带回来的。程序是在函数调用返回之后，在eax中去读取返回值的。
拓展了解：
其实返回对象时内置类型时，一般都是通过寄存器来带回返回值的，返回对象如果时较大的对象时，一
般会在主调函数的栈帧中开辟一块空间，然后把这块空间的地址，隐式传递给被调函数，在被调函数中
通过地址找到主调函数中预留的空间，将返回值直接保存到主调函数的。具体可以参考《程序员的自我修养----“链接、装载与库”》。
到这里我们给大家完整的演示了main函数栈帧的创建，Add函数栈帧的创建和销毁的过程，相信大家
已经能够基本理解函数的调用过程，函数传参的方式,开头提出的问题，现在是否能解决了呢？当你掌握了这些，在面试的时候将会大放异彩，如果你跟面试官这么完整的讲，面试官一定会对你竖起大拇指 [doge]
3.3.8 函数栈帧相关问题解答
- 局部变量是如何创建的？
答：首先为函数分配好栈帧空间，初始化好一部分空间之后，再分配一部分空间。
- 为什么局部变量不初始化内容是随机的？
答：因为是我们手动放进去的（cc cc cc cc），一旦你初始化，就会把随机值覆盖了。
- 函数调用时参数时如何传递的？传参的顺序是怎样的？
答： 还没有调用的时候，就已经push把参数从右向左压栈进去了，当进入栈帧时，通过指针的偏移量找回了参数的值。
- 函数的形参和实参的关系？
答：形参是实参的一份临时拷贝。
- 函数的返回值是如何带回的？
答：ret 已经存下了地址，pop 的过程中 esp 也回到了原来的位置。返回值通过寄存器 eax 带回来了。
写到最后
呼~终于写完了。在自己学习函数栈帧的创建与销毁时，还是大概3个月前，当时学习的时候完全是一点不懂，因为从没接触过汇编语言难以理解发生了什么。现在基本上已经把C语言完整学完了一遍，回头看函数栈帧，似乎也没有那么难了。于是我决定使用代码+动图的形式直观为大家讲解（画图画了一天真滴好累），虽然其中省略了一些步骤，但是已尽力绘好每一张图。如遇到哪里有错误麻烦批评指正，感谢感谢。
对于函数栈帧，我认为并不需要专门去学习相关的汇编知识，只需要作为了解知识，并且能明白上面提出的问题即可了。做到这点，已经超过绝大多数的同学了。
OK，以上就是本期知识点“函数栈帧的创建与销毁”的知识啦~~，感谢友友们的阅读。后续还会继续更新，欢迎持续关注哟~