tarjan算法求有向图强连通分量

这两天学习了tarjan解决强连通分量的方法，来晒晒。。

参考 ：http://www.byvoid.com/blog/scc-tarjan/        （byvoid的）

          http://www.codewaysky.com/                        （codewaysky）

[有向图强连通分量]

 

在有向图G中，如果两个顶点间至少存在一条路径，称两个顶点强连通(strongly connected)。如果有向图G的每两个顶点都强连通，称G是一个强连通图。非强连通图有向图的极大强连通子图，称为强连通分量(strongly connected components)。

 

下图中，子图{1,2,3,4}为一个强连通分量，因为顶点1,2,3,4两两可达。{5},{6}也分别是两个强连通分量。

 

 

直接根据定义，用双向遍历取交集的方法求强连通分量，时间复杂度为O(N^2+M)。更好的方法是Kosaraju算法或Tarjan算法，两者的时间复杂度都是O(N+M)。本文介绍的是Tarjan算法。

[算法流程演示]

从节点1开始DFS，把遍历到的节点加入栈中。搜索到节点u=6时，DFN[6]=LOW[6]，找到了一个强连通分量。退栈到u=v为止，{6}为一个强连通分量。

返回节点5，发现DFN[5]=LOW[5]，退栈后{5}为一个强连通分量。

返回节点3，继续搜索到节点4，把4加入堆栈。发现节点4向节点1有后向边，节点1还在栈中，所以LOW[4]=1。节点6已经出栈，(4,6)是横叉边，返回3，(3,4)为树枝边，所以LOW[3]=LOW[4]=1。

继续回到节点1，最后访问节点2。访问边(2,4)，4还在栈中，所以LOW[2]=DFN[4]=5。返回1后，发现DFN[1]=LOW[1]，把栈中节点全部取出，组成一个连通分量{1,3,4,2}。

至此，算法结束。经过该算法，求出了图中全部的三个强连通分量{1,3,4,2},{5},{6}。

可以发现，运行Tarjan算法的过程中，每个顶点都被访问了一次，且只进出了一次堆栈，每条边也只被访问了一次，所以该算法的时间复杂度为O(N+M)。

求有向图的强连通分量还有一个强有力的算法，为Kosaraju算法。Kosaraju是基于对有向图及其逆图两次DFS的方法，其时间复杂度也是 O(N+M)。与Trajan算法相比，Kosaraju算法可能会稍微更直观一些。但是Tarjan只用对原图进行一次DFS，不用建立逆图，更简洁。 在实际的测试中，Tarjan算法的运行效率也比Kosaraju算法高30%左右。此外，该Tarjan算法与求无向图的双连通分量(割点、桥)的Tarjan算法也有着很深的联系。学习该Tarjan算法，也有助于深入理解求双连通分量的Tarjan算法，两者可以类比、组合理解。

求有向图的强连通分量的Tarjan算法是以其发明者Robert Tarjan命名的。Robert Tarjan还发明了求双连通分量的Tarjan算法，以及求最近公共祖先的离线Tarjan算法，在此对Tarjan表示崇高的敬意。

代码：

我的pascal

View Code

 1    type
 2      ji=^rec;
 3      rec=record
 4        data:longint;
 5        next:ji;
 6      end;
 7    var
 8     i,j,n,m,k,l,tot,x,y,color,top:longint;
 9      lack,col,q,dfn,low:array[1..200000]of longint;
10      a:array[1..200000]of ji;
11    function min(x,y:longint):longint;
12      begin
13        if x<y then exit(x);
14        exit(y);
15      end;
16    procedure insert(x,y:longint);
17      var
18        p:ji;
19      begin
20        new(p);
21        p^.data:=y;
22        p^.next:=a[x];
23        a[x]:=p;
24      end;
25    procedure tarjan(x:longint);
26      var
27        now:ji;
28        i,j,y:longint;
29      begin
30        inc(tot);dfn[x]:=tot;low[x]:=tot;
31        inc(top);q[top]:=x;lack[x]:=top;
32        now:=a[x];
33        while now<>nil do
34          begin
35            y:=now^.data;
36            if dfn[y]=0 then
37              begin
38                tarjan(y);
39                low[x]:=min(low[x],low[y]);
40              end
41            else if lack[y]<>0 then low[x]:=min(low[x],dfn[y]);
42            now:=now^.next;
43          end;
44        if low[x]=dfn[x] then
45          begin
46            inc(color);
47            j:=lack[x];
48            for i:=j to top do
49              begin
50                col[q[i]]:=color;
51                lack[q[i]]:=0;
52              end;
53            top:=j-1;
54          end;
55      end;
56    begin
57      readln(n,m);
58      for i:=1 to m do
59        begin
60          readln(x,y);
61          insert(x,y);
62        end;
63      tarjan(1);
64      for i:=1 to n do writeln(col[i]);
65     end.