到目前为止，您已经对DAX的理论知识有了牢固的基础，是时候让我们开始用DAX来解决一些问题的场景了。本章节，我们会列举几个使用DAX的案例。
注意的是这章节的目的不是提供一个直接给您能立刻使用的模板。对于每个场景，我们建立函数，然后介绍使用DAX语言处理问题的思路。
我们的目标是帮助你用DAX进行思考问题。按我们的经验，只要你掌握了这种思考技能，DAX的使用就变得简单。DAX的语句和sql、excel、mdx或者其他语言有很大不同。一开始，学习的人会觉的，我理解这个函数，但是我没办法自己把它写出来。一段时间后，这个感觉逐渐褪去，然后你就可以自己书写一些比这里案例还要复杂的函数了。
计算百分数以及比率
第一个案例非常简单，我们之前的章节都有提到过。计算百分比也许是你第一个需要学习的，因为它是分析趋势和占比的常用指标。
百分比是除法的一种表现形式：一个指标的部分集合除以总数。例如，销售额的百分比。一个典型的案例如下：
图6-1是一个典型的报表包含了销售的绝对值和百分比。
图6-1中，百分比显示的是单元格对于总计值的比例。事实上，这里只用总计栏式100%，其他所有的单元格都是较小的数值，这个是因为year和color列的存在，导致各个单元格的值都会小于总计值。
这个表达式通常是按照下面这种除法的写法：
[Sales %] :=
DIVIDE (
[Sales Amount],
CALCULATE ( [Sales Amount], ALLSELECTED () )
)
在分母部分，calculate建立了一个筛选上下文，使用的是all selected()排除当前可见的筛选条件。
有的时候，你需要计算的不是针对销售总额的百分比。例如，你想知道的是每种color产品对于每年销售额的占比。例如下面这样的报表：
为了要计算当年的销售总额，在分母部分，我们要限制筛选条件，只要选择当年的数值而只忽略color的条件。这个计算简单的使用values条件就可以实现，values会返回筛选上下文当前列的所有值。
[Yearly %] :=
DIVIDE (
[Sales Amount],
CALCULATE (
[Sales Amount],
ALLSELECTED (),
VALUES ( Date[CalendarYear] )
))
这里需要注意的是，calculate的筛选条件会用and关系合并起来，然后应用到模型当中。因此，第一个条件allselected()会排除所有可见的筛选条件，values()会返回当且的year，对于每个单元格，都只包含了一个year。唯一例外的部分就是总计列，因此，对于每行，values都会返回两个年份。
如你所见，目前为止，我们使用了这样的方式来计算分母：
1.排除所有可见的筛选条件。
2.把需要限制的条件添加到筛选条件中去（例如我们这里添加了year）
你也可以使用相反的方式，来得到一样的结果。这次，不同先排除可见的筛选条件，再应用新的条件。我们一开始就排除已有的筛选条件对于的列。例如，要得到6-1的结果，我们可以分别还原color和year列的数值，而保留其他原有的筛选条件。
[Yearly %] :=
DIVIDE (
[Sales Amount],
CALCULATE (
[Sales Amount],
ALLSELECTED ( Product[Color] ),
ALLSELECTED ( Date[CalendarYear] )
))
我们要得到6-2的结果，我们可以使用下面这个代码，它只移除了color的筛选条件，而保持了year列的筛选。
[Yearly %-2] :=
DIVIDE (
[Sales Amount],
CALCULATE (
[Sales Amount],
ALLSELECTED ( Product[Color] )
))
虽然这些代码看起来差不多，而且可以得到一样的结果，但事实上，他们有很大的不同。yearly-2%排除了所有的筛选条件，只保留color。如果年份是唯一的筛选条件，那么结果是一样的，一旦你添加了前天的筛选条件到表格中，那么这两个度量值的结果就会不一样了。入下图：
可以看到 yearly%返回的百分比是针对了全年，而因为我们添加了month的条件，那么yearly%-2是针对月份。这里并不是说哪个正确哪个错误，而是说，我们要理解计算的过程，根据我们的需要来选择需要的度量值。
这里很重要的一点就是，当你要计算百分比的时候，你需要对分母是如何计算的要非常清晰，以及用户是否会添加更多的筛选条件的时候，会发生什么。