windows使用bat脚本一键配置java的环境变量

• 脚本请使用ANSI编码
• 请使用管理员权限执行脚本
• 

@echo off&setlocal enabledelayedexpansion

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

if '%errorlevel%' NEQ '0' (
    echo 需要管理员权限才能往下执行脚本！！！
    pause
    exit /b
)

echo 以下是java的版本信息：
if defined JAVA_HOME ( java -version ) else ( echo 未定义JAVA_HOME )
echo.
echo 以下是maven的版本信息：
if defined MAVEN_HOME ( call mvn -v ) else ( echo 未定义MAVEN_HOME )
echo.
if defined JAVA_HOME if defined MAVEN_HOME echo JDK和Maven都已配置完成,按任意键退出！&pause>nul &exit
set /p a=请选择配置啥[仅JDK-1/仅MAVEN-2/都配置-3]：
set RegV=HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment
set newp=%PATH%
set do=0
if %a% == 1 set do=1
if %a% == 3 set do=1
if %do% == 1 (
	if defined JAVA_HOME (
		echo JDK已配置,无需重复配置,按任意键继续！&pause>nul
	) else (
		echo 现在我们来配置JDK！
		set /p jpath=请输入JDK的安装目录[如:D:\java\jdk1.8]:
		set newp=%newp%;%%JAVA_HOME%%\bin\;%%JAVA_HOME%%\jre\bin\;
		set newc=.;%%JAVA_HOME%%\lib\dt.jar;%%JAVA_HOME%%\lib\tools.jar
		reg add "%RegV%" /v "JAVA_HOME" /d "!jpath!" /f
		reg add "%RegV%" /v "Path" /t REG_EXPAND_SZ /d "!newp!" /f
		reg add "%RegV%" /v "CLASSPATH" /d "!newc!" /f
		echo JDK配置完成！
	)
)
set do=0
if %a% == 2 set do=1
if %a% == 3 set do=1
if %do% == 1 (
	if defined MAVEN_HOME (
		echo MAVEN已配置,无需重复配置,按任意键继续！&pause>nul
	) else (
		echo 现在我们来配置MAVEN！
		set /p mpath=请输入Maven的安装目录[如:D:\java\apache-maven-3.3.9]:
		set newp=%newp%;%%MAVEN_HOME%%\bin\;
		reg add "%RegV%" /v "MAVEN_HOME" /d "!mpath!" /f
		reg add "%RegV%" /v "Path" /t REG_EXPAND_SZ /d "!newp!" /f
		echo MAVEN配置完成！
	)
)
echo 全部搞定^_^，按任意键跑路！&pause>nul

pause