Unity Shader GrabPass的玻璃效果

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

效果：

玻璃效果

原理：

通过GrabPass来获取当前屏幕图像，并用切线空间下的法线对屏幕纹理坐标偏移后，再对屏幕图像进行采样来模拟近似的折射效果。

shader代码：

// 通过GrabPass实现的玻璃效果
Shader "Custom/GlassRefraction"
{
    Properties
    {
        _MainTex ("_MainTex", 2D) = "white" { }
        _BumpMap ("Normal Map", 2D) = "bump" { } // 法线贴图
        _Cubemap ("Cubemap", Cube) = "_Skybox" { } // 立方体纹理
        _Distortion ("Distortion", Range(0, 100)) = 10 // 扭曲程度
        _RefractAmount ("Refract Amount", Range(0, 1)) = 1 // 折射程度，为0时全反射，为1时全折射
    }

    SubShader
    {
        // 渲染队列设为Transparent，确保此物体渲染时，其他所有不透明物体已经渲染了
        Tags { "RenderType" = "Opaque" "Queue" = "Transparent" }

        // 定义抓取图像的Pass，此Pass会将屏幕图像存入_RefractionTex纹理中
        GrabPass { "_RefractionTex" }

        pass
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            sampler2D _MainTex;
            // _MainTex纹理的缩放和偏移系数
            float4 _MainTex_ST;
            sampler2D _BumpMap;
            // _BumpMap纹理的缩放和偏移系数
            float4 _BumpMap_ST;
            samplerCUBE _Cubemap;
            float _Distortion;
            fixed _RefractAmount;
            sampler2D _RefractionTex;
            // _RefractionTex的纹素大小
            float4 _RefractionTex_TexelSize;

            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION; // 语义：模型顶点坐标
                float3 normal: NORMAL; // 语义：模型法线
                float4 tangent: TANGENT; // 语义：模型切线
                float4 texcoord: TEXCOORD0; // 语义：模型第一组纹理坐标
            };

            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION; // 语义：裁剪空间顶点坐标
                float4 scrPos: TEXCOORD0;
                float4 uv: TEXCOORD1;
                float4 TtoW0: TEXCOORD2;
                float4 TtoW1: TEXCOORD3;
                float4 TtoW2: TEXCOORD4;
            };

            v2f vert(a2v v)
            {
                v2f o;

                // 将顶点坐标从模型空间变换到裁剪空间
                // 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);

                // 根据裁剪坐标计算屏幕坐标
                o.scrPos = ComputeGrabScreenPos(o.pos);
                
                o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpMap);

                // 将顶点坐标从模型空间变换到世界空间
                float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                // 将法线从模型空间变换到世界空间
                fixed3 worldNormal = normalize(UnityObjectToWorldNormal(v.normal));
                // 将切线从模型空间变换到世界空间
                fixed3 worldTangent = UnityObjectToWorldDir(v.tangent);
                // 计算世界空间下的副法线
                fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;

                // 计算该顶点对应的从切线空间变换到世界空间的变换矩阵，并把每一行存储在TtoW0，TtoW1，TtoW2的xyz分量中
                // 这里使用的数学方法是，得到切线空间下的3个坐标轴(x副法线，y切线，z法线)在世界空间下的表示，再依次按列组成变换矩阵即可
                // w分量存储世界空间下顶点坐标，以减少占用的插值寄存器空间
                o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
                o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
                o.TtoW2 = float4(worldTangent.z, worldTangent.z, worldNormal.z, worldPos.z);

                return o;
            };

            fixed4 frag(v2f i): SV_Target
            {
                // 取出存在w分量里，世界空间下顶点坐标
                float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
                // 观察向量
                fixed3 worldViewDir = normalize(UnityObjectToViewPos(worldPos));

                // 若法线纹理Texture Type未设置成Normal map，
                // 要从像素映射回法线，即[0, 1]转化到[-1, 1]
                // bump.xy = ( tex2D(_BumpMap, i.uv.zw).xy * 2 - 1);
                // 如果设置了Normal map类型，Unity会根据平台使用不同的压缩方法，
                // _BumpMap.rbg值不是对应的切线空间的xyz值了，要用Unity内置函数UnpackNormal
                float3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));

                // 使用_Distortion属性以及_RefractionTex_TexelSize对屏幕图像的采样坐标进行偏移，模拟折射效果
                float2 offset = bump.xy * _Distortion * _RefractionTex_TexelSize.xy;
                i.scrPos.xy = offset * i.scrPos.z + i.scrPos.xy;

                // 下面的i.scrPos.xy / i.scrPos.w操作，是因为scrPos此时并不是真正的屏幕坐标，需要进行透视除法，即除以裁剪坐标的w分量
                // w分量范围：如果是正交投影w分量恒为1，如果是透视投影w分量范围为[1/Near, 1/Far]，Near和Far对应了Camera组件上的近远裁剪平面
                // Unity内置函数没有直接进行透视除法后返回，是为了防止破坏插值的结果，因为如果在顶点着色器这么做，那么就需要对x/w, y/w直接进行插值，这样在片元着色器中得到插值后的数据就会不准确。
                // 折射颜色
                fixed3 refrCol = tex2D(_RefractionTex, i.scrPos.xy / i.scrPos.w).rgb;

                // 法线从切线坐标变换到世界坐标中(使用变换矩阵的每一行，即TtoW0、TtoW1和TtoW2，分别和法线方向点乘，构成新的法线方向)
                bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));

                // 反射方向
                fixed3 reflDir = reflect(-worldViewDir, bump);

                fixed4 texColor = tex2D(_MainTex, i.uv.xy);

                // 反射颜色
                fixed3 reflCol = texCUBE(_Cubemap, reflDir).rgb * texColor.rgb;

                // 使用_RefractAmount属性，对反射和折射颜色混合
                fixed3 finalColor = reflCol * (1 - _RefractAmount) + refrCol * _RefractAmount;

                return fixed4(finalColor, 1);
            }

            ENDCG

        }
    }

    FallBack "Diffuse"
}