Unity Shader 卡通渲染效果

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

效果：

游戏《大神》（英文名：Okami）的游戏截图

卡通风格的渲染效果

左图：未对高光区域进行抗锯齿处理。右图：使用fwidth函数对高光区域进行抗锯齿处理

原理：

1、渲染轮廓线；
2、添加高光；

绘制模型轮廓线的方法有5种类型：

• 基于观察角度和表面法线的轮廓线渲染。这种方法使用视角方向和表面法线的点乘结果来得到轮廓线的信息。这种方法简单快速，可以在 Pass 中就得到渲染结果，但局限性很大，很多模型渲染出来的描边效果都不尽如人意。
• 过程式几何轮廓线渲染。这种方法的核心是使用两个 Pass 渲染。第一个Pass渲染背面的面片，并使用某些技术让它的轮廓可见；第二个 Pass 再正常渲染正面的面片。这种方法的优点在于快速有效，并且适用于绝大多数表面平滑的模型，但它的缺点是不适合类似于立方体这样平整的模型。
• 基于图像处理的轮廓线渲染。使用卷积核进行边界检测。这种方法的优点在于可以适用于任何种类的模型。但它也有自身的局限所在，一些深度和法线变化很小的轮廓无法被检测出来，例如桌子上的纸张。
• 基于轮廓边检测的轮廓线渲染。上面提到的各种方法，一个最大的问题是，无法控制轮廓
  线的风格渲染。对于一些情况，我们希望可以渲染出独特风格的轮廓线，例如水墨风格等。为此，我们希望可以检测出精确的轮廓边，然后直接渲染它们。检测一条边是否是轮廓边的公式很简单，我们只需要检查和这条边相邻的两个三角面片是否满足以下条件：
  
  其中，和分别表示两个相邻三角面片的法向， 是从视角到该边上任意顶点的方向。上述公式的本质在于检查两个相邻的三角面片是否一个朝正面、一个朝背面。我们可以在几何着色器(Geometry hader 的帮助下实现上面的检测过程。当然，这种方法也有缺点，除了实现相对复杂外，它还会有动画连贯性的问题。也就是说，由于是逐帧单独提取轮廓，所以在帧与帧之间会出现跳跃性。
• 最后一个种类就是混合了上述的几种渲染方法。例如，首先找到精确的轮廓边，把模型和轮廓边渲染到纹理中，再使用图像处理的方法识别出轮廓线，并在图像空间下进行风格化渲染。

在本篇中，将会在 Unity 中使用过程式几何轮廓线渲染的方法来对模型进行轮廓描边。将使用两个 Pass 渲染模型：在第一个Pass中，我们会使用轮廓线颜色渲染整个背面的面片，在视角空间下把模型顶点沿着法线方向向外扩张一段距离，以此来让背部轮廓线可见。

shader代码：

// 卡通渲染效果
Shader "Custom/ToonShading"
{
    Properties
    {
        _Color ("ColorTint", Color) = (1, 1, 1, 1)
        _MainTex ("Texture", 2D) = "white" { }
        _Ramp ("Ramp Texture", 2D) = "white" { }// 控制漫反射色调的渐变纹理
        _Outline ("Outline", Range(0, 1)) = 0.1 // 控制轮廓线宽度
        _OutlineColor ("OutlineColor", Color) = (0, 0, 0, 1) // 轮廓线颜色
        _Specular ("Specular", Color) = (1, 1, 1, 1) // 高光反射颜色
        _SpecularScale ("SpecularScale", Range(0, 0.1)) = 0.01 // 控制计算高光反射区域大小
    }

    SubShader
    {
        Tags { "RenderType" = "Opaque" "Queue" = "Geometry" }

        // 定义渲染轮廓线需要的 Pass
        Pass
        {
            // 使用 NAME 命令为该 Pas 定义了名称，这样别的Shader可以通过此名字调用此Pass
            // 因为描边在非真实感渲染中是非常常见的效果 为该Pass义名称可以让我们在后面的使用中不需要再重复编写此 Pass
            // 而只需要调用它的名字即可，如: UsePass "Cusstom/ToonShading/OUTLINE"
            NAME "OUTLINE"

            // 剔除正面，只渲染背面
            Cull Front

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            float _Outline;
            fixed4 _OutlineColor;

            // 应用传递给定点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION; // 语义：模型空间下的顶点坐标
                float4 normal: NORMAL; // 语义：模型空间下的法线
            };

            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION; // 语义：裁剪空间下的顶点坐标
            };

            // 顶点着色器函数
            v2f vert(a2v v)
            {
                v2f o;

                // 将顶点坐标从模型空间变换到观察空间
                float4 pos = mul(UNITY_MATRIX_MV, v.vertex);
                // 将法线从模型空间变换到观察空间
                float3 normal = mul((float3x3)UNITY_MATRIX_IT_MV, v.normal);
                // 是为了尽可能避免背面扩张后的顶点挡住正面的面片
                normal.z = 0.5;
                // 将顶点沿法线方向上扩张
                pos = pos + float4(normalize(normal), 0) * _Outline;
                // 将顶点坐标从观察空间变换到裁剪空间
                o.pos = mul(UNITY_MATRIX_P, pos);

                return o;
            }

            // 片元着色器函数
            fixed4 frag(v2f i): SV_TARGET
            {
                // 用轮廓线颜色渲染整个背面
                return fixed4(_OutlineColor.rgb, 1);
            }

            ENDCG

        }

        // Base Pass 计算平行光、环境光
        Pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            Cull Back
            
            CGPROGRAM

            // 编译指令，保证在pass中得到Pass中得到正确的光照变量
            #pragma multi_compile_fwdbase

            #pragma vertex vert
            #pragma fragment frag
            
            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"
            #include "UnityShaderVariables.cginc"
            
            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _Ramp;
            fixed4 _Specular;
            fixed _SpecularScale;
            
            // 应用传递给定点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION; // 语义: 顶点坐标
                float3 normal: NORMAL; // 语义: 法线
                float4 texcoord: TEXCOORD0; // 语义: 纹理坐标
                float4 tangent: TANGENT; // 语义: 切线
            };
            
            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION; // 语义: 裁剪空间的顶点坐标
                float2 uv: TEXCOORD0;
                float3 worldNormal: TEXCOORD1;
                float3 worldPos: TEXCOORD2;
                SHADOW_COORDS(3) // 内置宏：声明一个用于对阴影纹理采样的坐标 (这个宏参数需要是下一个可用的插值寄存器的索引值，这里是3)
            };

            // 顶点着色器
            v2f vert(a2v v)
            {
                v2f o;

                // 将顶点坐标从模型空间变换到裁剪空间
                // 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);

                // 计算纹理坐标(缩放和平移)
                // 等价于o.uv = v.texcoord * _MainTex_ST.xy + _MainTex_ST.zw;
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);

                // 将法线从模型空间变换到世界空间
                // 等价于o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                // 将顶点坐标从模型空间变换到世界空间
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

                // 内置宏：用于计算声明的阴影纹理坐标
                TRANSFER_SHADOW(o);
                
                return o;
            }

            // 片元着色器
            fixed4 frag(v2f i): SV_TARGET
            {
                fixed3 worldNormal = normalize(i.worldNormal);
                // 世界空间光向量
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                // 世界空间观察向量
                fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
                // 世界半角向量，用于计算高光反射
                fixed3 worldHalfDir = normalize(worldLightDir + worldViewDir);
                
                fixed4 c = tex2D(_MainTex, i.uv);
                // 计算材质反射率
                fixed3 albedo = c.rgb * _Color.rgb;

                // 环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                // 计算阴影值和光照衰减
                UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);

                // 计算半兰伯特漫反射系数
                fixed diff = dot(worldNormal, worldLightDir);
                // 和阴影值相乘得到最终的漫反射系数
                diff = (diff * 0.5 + 0.5) * atten;
                
                // 使用漫反射系数对渐变纹理_Ramp进行采样，并将结果和材质的反射率、光照颜色相乘 作为最后的漫反射光照
                fixed3 diffuse = _LightColor0.rgb * albedo * tex2D(_Ramp, float2(diff, diff)).rgb;

                fixed spec = dot(worldNormal, worldHalfDir);
                // 高光区域的边缘不是平滑渐变的，而是由0突变到1，对其进行抗锯齿处理，可以在边界处很小的一块区域内进行平滑处理
                // 使用smoothstep函数，w个很小的值，当spec-threshold小于-w 时，返回0；大于w时，返回1；否则在0-1之间进行插值。
                // 这样的效果是，我们可以在[-w, w] 区间内，即高光区域的边界处，得到一个从0到1平滑变化的 spec 值，从而实现抗锯齿的目的
                // 尽管我可以把w设为一个很小的定值，不过更好的是选择使用邻域像素之间的近似导数值，这可以通过 fwidth 函数来得到
                // 使用step(0.0001, _SpecularScale)，这是为了在 SpecularScaJe 可以完全消除高光反射的光照
                fixed w = fwidth(spec) * 2.0;
                fixed3 specular = _Specular.rgb * lerp(0, 1, smoothstep(-w, w, spec + _SpecularScale - 1)) * step(0.0001, _SpecularScale);

                return fixed4(ambient + diffuse + specular, 1);
            }


            ENDCG

        }
    }

    // 设置Fallback，产生正确的阴影投射效果
    Fallback "Diffuse"
}