Hive09_函数

HIVE函数

系统内置函数

1）查看系统自带的函数

hive> show functions;

2）显示自带的函数的用法

hive> desc function upper;

3）详细显示自带的函数的用法

hive> desc function extended upper;

hive函数分类

1、UDF：用户定义（普通）函数，只对单行数值产生作用；（一进一出）

2、UDAF：User- Defined Aggregation Funcation；用户定义聚合函数，可对多行数据产生作用；等同与SQL中常用的SUM()，AVG()，也是聚合函数；（多进一出）

3.UDTF：User-Defined Table-Generating Functions，用户定义表生成函数，用来解决输入一行输出多行（炸裂函数，一进多出）；

常用内置函数

1 空字段赋值 NVL

1）函数说明
NVL：给值为 NULL 的数据赋值，它的格式是 NVL( value，default_value)。它的功能是如
果 value 为 NULL，则 NVL 函数返回 default_value 的值，否则返回 value 的值，如果两个参数
都为 NULL ，则返回 NULL。

2）数据准备：

采用员工表

3）查询：

如果员工的 comm 为 NULL，则用-1 代替

hive (default)> select comm,nvl(comm, -1) from emp;

OK
comm _c1
NULL -1.0
300.0 300.0
500.0 500.0
NULL -1.0
1400.0 1400.0
NULL -1.0
NULL -1.0
NULL -1.0
NULL -1.0
0.0 0.0
NULL -1.0
NULL -1.0
NULL -1.0
NULL -1.0

4）查询：

如果员工的 comm 为 NULL，则用领导 id 代替

hive (default)> select comm, nvl(comm,mgr) from emp;
OK
comm _c1
NULL 7902.0
300.0 300.0
500.0 500.0
NULL 7839.0
1400.0 1400.0
NULL 7839.0
NULL 7839.0
NULL 7566.0
NULL NULL
0.0 0.0
NULL 7788.0
NULL 7698.0
NULL 7566.0
NULL 7782.0

2 CASE WHEN THEN ELSE END

1) 数据准备

2）需求求出不同部门男女各多少人。

结果如下：

dept_Id 男孩 女孩

A 2 1

B 1 2

select 
	dept_id,
	sum(case sex when '男'  then 1 else 0 end) as "男孩"，
	sum(case sex when '女' then 1 else 0 end) as "女孩"
from 
	emp_sex 
group by 
	dept_id;

3）创建本地 emp_sex.txt，导入数据

[root@localhost datas]$ vi emp_sex.txt
悟空	A	男
大海	A	男
宋宋	B	男
凤姐	A	女
婷姐	B	女
婷婷	B	女

4）创建 hive 表并导入数据

create table emp_sex(
name string, 
dept_id string, 
sex string) 
row format delimited fields terminated by "\t";

load data local inpath '/usr/soft/datas/emp_sex.txt' into table emp_sex;

5）按需求查询数据

select
 dept_id,
 sum(case sex when '男' then 1 else 0 end) male_count,
 sum(case sex when '女' then 1 else 0 end) female_count
from emp_sex
group by dept_id;

3 行转列

1）相关函数说明

CONCAT(string A/col, string B/col…)：
返回输入字符串连接后的结果，支持任意个输入字符串;

CONCAT_WS(separator, str1, str2,…)：

它是一个特殊形式的 CONCAT()。第一个参数剩余参数间的分隔符。分隔符可以是与剩余参数一样的字符串。如果分隔符是 NULL，返回值也将为 NULL。这个函数会跳过分隔符参数后的任何 NULL 和空字符串。分隔符将被加到被连接的字符串之间;
注意: CONCAT_WS must be "string or array

COLLECT_SET(col)：

函数只接受基本数据类型，它的主要作用是将某字段的值进行去重汇总，产生 Array 类型字段。

2）数据准备

3）需求
把星座和血型一样的人归类到一起。结果如下：

射手座,A 大海|凤姐
白羊座,A 孙悟空|猪八戒
白羊座,B 宋宋|紫霞

select 
	t.cb,
	concat_ws('|',collect_set(t.name))
from
	(select name ,concat_ws(',',constellation,blood_type)cb from person_info) t
group by
	t.cb;
	
	

name		cb
孙悟空		白羊座,A
大海		射手座,A
宋宋		白羊座,B
猪八戒		白羊座,A
凤姐		射手座,A
紫霞		白羊座,B

4）创建本地 constellation.txt，导入数据

[root@localhost datas]$ vim person_info.txt
孙悟空  白羊座  A
大海    射手座  A
宋宋    白羊座  B
猪八戒  白羊座  A
凤姐    射手座  A
紫霞    白羊座  B

5）创建 hive 表并导入数据

create table person_info(
name string, 
constellation string, 
blood_type string) 
row format delimited fields terminated by "\t";

load data local inpath "/usr/soft/datas/person_info.txt" into table person_info;

6）按需求查询数据

SELECT
	t1.c_b,
	CONCAT_WS("|",collect_set(t1.name))
FROM (
    SELECT
    	NAME,
    	CONCAT_WS(',',constellation,blood_type) c_b
    FROM person_info
    )t1
	GROUP BY t1.c_b

4 列转行

1）函数说明

EXPLODE(col)：将 hive 一列中复杂的 Array 或者 Map 结构拆分成多行。

LATERAL VIEW
用法：LATERAL VIEW udtf(expression) tableAlias AS columnAlias
解释：用于和 split, explode 等 UDTF 一起使用，它能够将一列数据拆成多行数据，在此基础上可以对拆分后的数据进行聚合。

String s =“hello,world”;

s.split(“,”); =====> [ “悬疑” , “动作” ,“科幻”]

2）数据准备

split( “category” , “,”) -----> [ “悬疑” ， “动作”, “科幻”, “剧情” ] array

explode (array) -----> 悬疑 动作 科幻 剧情

LATERAL VIEW

3）需求

将电影分类中的数组数据展开。结果如下：

《疑犯追踪》 悬疑
《疑犯追踪》 动作
《疑犯追踪》 科幻
《疑犯追踪》 剧情
《Lie to me》 悬疑
《Lie to me》 警匪
《Lie to me》 动作
《Lie to me》 心理
《Lie to me》 剧情
《战狼 2》 战争
《战狼 2》 动作
《战狼 2》 灾难

select 
	movie,cates
from
	movie_info
lateral view 
	explode(split(category,",")) cate as cates;
	
	
	
	
	
select   lateral view( explode(  split(category,",")  ) ) from movie_info;

4）创建本地 movie.txt，导入数据

[root@localhost datas]$ vi movie_info.txt

《疑犯追踪》 悬疑,动作,科幻,剧情
《Lie to me》悬疑,警匪,动作,心理,剧情
《战狼 2》 战争,动作,灾难

5）创建 hive 表并导入数据

create table movie_info(
 	movie string,
 	category string)
row format delimited fields terminated by "\t";

load data local inpath "/usr/soft/datas/movie_info.txt" into table movie_info;

6）按需求查询数据

SELECT
	movie,
	category_name
FROM
	movie_info
lateral VIEW
	explode(split(category,",")) movie_info_tmp AS category_name;

5）创建 hive 表并导入数据

create table movie_info(
 	movie string,
 	category string)
row format delimited fields terminated by "\t";

load data local inpath "/usr/soft/datas/movie_info.txt" into table movie_info;

6）按需求查询数据

SELECT
	movie,
	category_name
FROM
	movie_info
lateral VIEW
	explode(split(category,",")) movie_info_tmp AS category_name;