遍历 XML 结构

转自 http://help.adobe.com/zh_CN/as3/dev/WS5b3ccc516d4fbf351e63e3d118a9b90204-7e6b.html

遍历 XML 结构

Flash Player 9 和更高版本，Adobe AIR 1.0 和更高版本

• 访问父节点和子节点

• 访问属性

• 按属性或元素值过滤

• 使用 for..in 和 for each..in 语句

XML 的一个强大功能是它能够通过文本字符的线性字符串提供复杂的嵌套数据。将数据加载到 XML 对象时，ActionScript 会分析数据并将其分层结构加载到内存（如果 XML 数据格式有误，它会发送运行时错误）。

利用 XML 和 XMLList 对象的运算符和方法可以轻松遍历 XML 数据的结构。

使用点 (.) 运算符和后代存取器 (..) 运算符可以访问 XML 对象的子属性。请考虑下面的 XML 对象：

var myXML:XML =  
    <order> 
        <book ISBN="0942407296"> 
            <title>Baking Extravagant Pastries with Kumquats</title> 
            <author> 
                <lastName>Contino</lastName> 
                <firstName>Chuck</firstName> 
            </author> 
            <pageCount>238</pageCount> 
        </book> 
        <book ISBN="0865436401"> 
            <title>Emu Care and Breeding</title> 
            <editor> 
                <lastName>Case</lastName> 
                <firstName>Justin</firstName> 
            </editor> 
            <pageCount>115</pageCount> 
        </book> 
    </order>

对象 myXML.book 是一个 XMLList 对象，它包含名为 book 的 myXML 对象的子属性。它们是两个 XML 对象，与 myXML 对象的两个 book 属性相匹配。

对象 myXML..lastName 是一个 XMLList 对象，它包含名字为 lastName 的所有后代属性。它们是两个 XML 对象，与 myXML 对象的两个 lastName 相匹配。

myXML.book.editor.lastName 对象是一个 XMLList 对象，它包含 myXML 对象的名为 book 的子对象的名为 editor 的子对象的名为 lastName 的所有子对象：在本例中，XMLList 对象只包含一个 XML 对象（值为 "Case" 的lastName 属性）。

访问父节点和子节点

parent() 方法返回 XML 对象的父项。

可以使用子级列表的序数索引值访问特定的子对象。例如，假设 XML 对象 myXML 有两个名为 book 的子属性。每个名为 book 的子属性都有一个与之关联的索引编号：

myXML.book[0] 
myXML.book[1]

若要访问特定的孙项，可为子项和孙项名称同时指定索引编号：

myXML.book[0].title[0]

不过，如果 x.book[0] 只有一个名为 title 的子项，则可以省略索引引用，如下所示：

myXML.book[0].title

同样，如果对象 x 只有一个 book 子对象，并且该子对象只有一个 title 对象，则可以同时省略两个索引引用，如下所示：

myXML.book.title

可以使用 child() 方法导航到名称基于变量或表达式的子项，如下面的示例所示：

var myXML:XML =  
        <order> 
            <book> 
                <title>Dictionary</title> 
            </book> 
        </order>; 
 
var childName:String = "book"; 
 
trace(myXML.child(childName).title) // output: Dictionary

访问属性

使用 @ 符号（属性标识符运算符）可以访问 XML 或 XMLList 对象的属性，如下面的代码所示：

var employee:XML =  
    <employee id="6401" code="233"> 
        <lastName>Wu</lastName> 
        <firstName>Erin</firstName> 
    </employee>; 
trace(employee.@id); // 6401

可将 * 通配符和 @ 符号一起使用来访问 XML 或 XMLList 对象的所有属性，如下面的代码所示：

var employee:XML =  
    <employee id="6401" code="233"> 
        <lastName>Wu</lastName> 
        <firstName>Erin</firstName> 
    </employee>; 
trace(employee.@*.toXMLString());  
// 6401 
// 233

可以使用 attribute() 或 attributes() 方法访问 XML 或 XMLList 对象的特定属性或所有属性，如下面的代码所示：

var employee:XML =  
    <employee id="6401" code="233"> 
        <lastName>Wu</lastName> 
        <firstName>Erin</firstName> 
    </employee>; 
trace(employee.attribute("id")); // 6401 
trace(employee.attribute("*").toXMLString());  
// 6401 
// 233 
trace(employee.attributes().toXMLString());  
// 6401 
// 233

请注意，还可以使用以下语法访问属性，如下面的示例所示：

employee.attribute("id") 
employee["@id"] 
employee.@["id"]

其中每一个都等效于 employee.@id。但是，语法 employee.@id 是首选方式。

按属性或元素值过滤

可以使用括号运算符 — ( 和 ) — 过滤具有特定元素名称或属性值的元素。请考虑下面的 XML 对象：

var x:XML =  
    <employeeList> 
        <employee id="347"> 
            <lastName>Zmed</lastName> 
            <firstName>Sue</firstName> 
            <position>Data analyst</position> 
        </employee> 
        <employee id="348"> 
            <lastName>McGee</lastName> 
            <firstName>Chuck</firstName> 
            <position>Jr. data analyst</position> 
        </employee> 
    </employeeList>

以下表达式都是有效的：

• x.employee.(lastName == "McGee") — 这是第二个 employee 节点。

• x.employee.(lastName == "McGee").firstName — 这是第二个employee 节点的firstName 属性。

• x.employee.(lastName == "McGee").@id — 这是第二个 employee 节点的 id 属性的值。

• x.employee.(@id == 347) — 第一个 employee 节点。

• x.employee.(@id == 347).lastName — 这是第一个 employee 节点的 lastName 属性。

• x.employee.(@id > 300) — 这是具有两个 employee 属性的 XMLList。

• x.employee.(position.toString().search("analyst") > -1) — 这是具有两个position 属性的 XMLList。

如果您尝试过滤不存在的属性或元素，会引发异常。例如，以下代码的最后一行产生一个错误，因为第二个 p 元素没有id 属性：

var doc:XML =  
            <body> 
                <p id='123'>Hello, <b>Bob</b>.</p> 
                <p>Hello.</p> 
            </body>; 
trace(doc.p.(@id == '123'));

同样，以下代码的最后一行也会产生一个错误，因为第二个 p 元素没有 b 属性：

var doc:XML =  
            <body> 
                <p id='123'>Hello, <b>Bob</b>.</p> 
                <p>Hello.</p> 
            </body>; 
trace(doc.p.(b == 'Bob'));

为避免出现这些错误，可以使用 attribute() 和 elements() 方法来识别具有匹配属性或元素的属性，如以下代码所示：

var doc:XML =  
            <body> 
                <p id='123'>Hello, <b>Bob</b>.</p> 
                <p>Hello.</p> 
            </body>; 
trace(doc.p.(attribute('id') == '123')); 
trace(doc.p.(elements('b') == 'Bob'));

还可以使用 hasOwnProperty() 方法，如下面的代码所示：

var doc:XML =  
            <body> 
                <p id='123'>Hello, <b>Bob</b>.</p> 
                <p>Hello.</p> 
            </body>; 
trace(doc.p.(hasOwnProperty('@id') && @id == '123')); 
trace(doc.p.(hasOwnProperty('b') && b == 'Bob'));

使用 for..in 和 for each..in 语句

ActionScript 3.0 包含 for..in 语句和 for each..in 语句，用于遍历 XMLList 对象。例如，我们来看下面的 XML 对象 myXML 和 XMLList 对象myXML.item。XMLList 对象myXML.item 由 XML 对象的两个item 节点组成。

var myXML:XML =  
    <order> 
        <item id='1' quantity='2'> 
            <menuName>burger</menuName> 
            <price>3.95</price> 
        </item> 
        <item id='2' quantity='2'> 
            <menuName>fries</menuName> 
            <price>1.45</price> 
        </item> 
    </order>;

for..in 语句用于遍历 XMLList 中的一组属性名称：

var total:Number = 0; 
for (var pname:String in myXML.item) 
{ 
    total += myXML.item.@quantity[pname] * myXML.item.price[pname]; 
}

for each..in 语句用于遍历 XMLList 中的属性：

var total2:Number = 0; 
for each (var prop:XML in myXML.item) 
{ 
    total2 += prop.@quantity * prop.price; 
}