U-Boot重定位代码分析

概述

重定位（relocate）代码将BootLoader自身由Flash复制到SDRAM，以便跳转到SDRAM执行。之所以需要进行重定位是因为在Flash中执行速度比较慢，而系统复位后总是从0x00000000地址取指。

重定位代码，位于/U-Boot/cpu/s3c44b0/start.S ：

relocate:                /* relocate U-Boot to RAM              */

    adr r0, _start    /* r0 <- current position of code      */

    ldr r1, _TEXT_BASE    /* test if we run from flash or RAM    */

    cmp     r0, r1        /* don't reloc during debug         */

    beq     stack_setup

 

    ldr r2, _armboot_start

    ldr r3, _bss_start

    sub r2, r3, r2    /* r2 <- size of armboot    */

    add r2, r0, r2    /* r2 <- source end address */

 

copy_loop:

    ldmia r0!, {r3-r10}     /* copy from source address [r0]   */

    stmia r1!, {r3-r10}     /* copy to target address [r1] */

    cmp r0, r2               /* until source end address [r2]   */

    ble copy_loop

以上代码首先判断是否需要进行重定位，如果需要的话首先确定复制的源基址、源大小和目标基址，然后以r3 ~ r13为媒介，将BootLoader复制到SDRAM中。

分析

copy_loop很容易理解，这里主要分析relocate处的前两条指令：

1.       adr r0, _start

adr是一条伪指令，汇编器总是试图为它产生add/sub这样的指令，（在这里）以pc为基址装载目标寄存器。以下是arm-elf-objdump产生的反汇编代码：

c700048:   e24f0050 sub r0, pc, #80   ; 0x50

e24f0050是指令对应的机器码，c700048是存放该机器码的地址（十六进制表示）。这个地址是怎么来的呢？在/U-Boot/config.mk中有问题的答案：

LDFLAGS += -Bstatic -T $(LDSCRIPT) -Ttext $(TEXT_BASE) $(PLATFORM_LDFLAGS)

上面的宏指定连接时的命令行参数，-Ttext设定了.text段的地址，而TEXT_BASE在/U-Boot/board/.../config.mk中定义为0x0C700000。这些信息最后都以硬编码的方式记录在程序映像文件中，程序的入口_start = TEXT_BASE = 0x0C700000 ：

Disassembly of section .text:

0c700000 <_start>:

c700000: ea00000a b   c700030 <reset>
...

但是，程序映像是烧写到Flash中并开始执行的，而Flash的地址从0x00000000开始。于是，程序映像的第一条指令对齐到0x00000000处。相应的，这条adr指令的地址应对齐到0x00000048处，执行后r0等于0。

2.       ldr r1, _TEXT_BASE

以下是arm-elf-objdump产生的反汇编代码：

c70004c:   e51f1034 ldr r1, [pc, #-52]    ; c700020 <_TEXT_BASE>

由此可见，这里的ldr并不是简单的将_TEXT_BASE地址处的4字节装载到r1，而同样是以pc为基址计算得到源地址的。这里的pc = 0x4c + 8 = 0x54，于是该指令把0x54 – 52 = 0x20处的4字节（即TEXT_BASE，亦即0x0C700000）装载到r1。

3.       源大小的确定

通过上面的分析，我们已经有了一个概念：程序的实际执行地址与连接时指定的加载地址可能是不一样的。我们已经得到BootLoader代码开始的运行时开始地址，存放于r0，还需要计算它的运行时结束地址。运行时结束地址 = 运行时开始地址 + 代码段大小。代码段大小由.bss段的期望开始地址 - .text段的期望开始地址获得。

小结

通过连接时的-Ttext选项，将.text段的地址硬编码到程序映像中。虽然程序映像在Flash中执行，其实际执行地址与期望执行地址不一致，但在relocate之前，通过以pc为基址进行相对寻址，使得这些代码的执行与其实际装载的地址无关。

 

转自：http://hi.baidu.com/chyankui/blog/item/903f582ebf91c5301f308981.html