JZOJ 1812. 【Usaco 2010 NOV Gold】奶牛的图片

Description

Farmer John希望给他的N(1<=N<=100,000)只奶牛拍照片,这样他就可以向他的朋友炫耀他的奶牛.这N只奶牛被标号为1..N.
在照相的那一天,奶牛们排成了一排.其中第i个位置上是标号为c_i(1<=c_i<=N)的奶牛.对于奶牛的站位,Farmer John有他自己的想法.
FJ是这么想的,标号为i(1<=i<=n-1)的奶牛只能站在标号为i+1的奶牛的左边,而标号为N的奶牛只能站在标号为1的奶牛的左边.当然,没有牛可以站在队列中最左边的奶牛的左边了.也就是说,最左边的奶牛编号是随意的.
这些奶牛都非常的饿,急切的希望吃到FJ承诺的在拍照后的大餐,所以FJ想尽快的拍照.奶牛们的方向感非常的不好,所以FJ每一分钟只可以选择相邻的两只奶牛然后让他们交换位置.FJ最小需要多少时间就能使奶牛站成一个可以接受的序列?
比方说一个有5只奶牛的例子,一开始序列是这样的:
左边 右边
3 5 4 2 1

第一分钟,FJ可以交换第二队奶牛(即5和4),交换后的队列:
3 4 5 2 1
第二分钟,FJ交换最右边的一对,序列变成这样:
3 4 5 1 2
这样,只用了2分钟,就是序列变为了一个FJ所希望的序列.

Input

第1行:一个单独的数N
第2到n+1行:第i+1行上的数表示站在第i的位置上的奶牛的编号(即c_i).

Output

一个整数,表示是奶牛的序列变为一个合法的序列的最小花费时间.

Sample Input

5
3
5
4
2
1

Sample Output

2

Solution

将一个凌乱的序列排成一个有序且升序的序列，我们可以想到逆序对。正解其实就是——先求这个凌乱的序列V每一个元素的位置w[i]，还有序列V转换成序列S（初始值为1-n）的步数ans。这个用树状数组求。最重要的部分是把最后面的那个数i移到最前面，像“1,2,3,4,5”就移成“5,1,2,3,4”。步数的初始值x显然是ans。中间将最后一个数i移到w[i]这个位置，这个序列称为S1，可以求得出V到S1的距离，就是x-(n-w[i])步，然后我们还要将i移到第一位，实现将i移到最前面，所以步数x还要加上w[i]-1步。总的来说，步数x=x-(n-w[i])+w[i]-1,整理后得x=x-n+2*w[i]-1。答案则为这些x的最小值。

Code

var c,w,v:array[0..100001] of int64;
    i,j,k,l,n,m,t,s:longint;
    x,ans,min:int64;
function lowbit(x:longint):longint;
begin
    exit(x and (-x));
end;
function get(x:longint):longint;
var a:longint;
begin
    a:=0;
    while x>0 do
    begin
        inc(a,c[x]);
        x:=x-lowbit(x);
    end;
    get:=a;
end;
procedure change(x:longint);
begin
    while x<=n do
    begin
        inc(c[x]);
        x:=x+lowbit(x);
    end;
end;
begin
    readln(n);
    for i:=1 to n do
    begin
        read(v[i]);
        w[v[i]]:=i;
    end;
    for i:=n downto 1 do
    begin
        ans:=ans+get(v[i]);
        change(v[i]);
    end;
    x:=ans;
    min:=x;
    for i:=n downto 2 do
    begin
        x:=x-n+2*w[i]-1;
        if x<min then min:=x;
    end;
    writeln(min);
end.

——2016.1.24 By Wzy