[JSOI2008]星球大战

题目描述 Description

很久以前，在一个遥远的星系，一个黑暗的帝国靠着它的超级武器统治者整个星系。某一天，凭着一个偶然的机遇，一支反抗军摧毁了帝国的超级武器，并攻下了星系中几乎所有的星球。这些星球通过特殊的以太隧道互相直接或间接地连接。
  但好景不长，很快帝国又重新造出了他的超级武器。凭借这超级武器的力量，帝国开始有计划地摧毁反抗军占领的星球。由于星球的不断被摧毁，两个星球之间的通讯通道也开始不可靠起来。现在，反抗军首领交给你一个任务：给出原来两个星球之间的以太隧道连通情况以及帝国打击的星球顺序，以尽量快的速度求出每一次打击之后反抗军占据的星球的连通快的个数。（如果两个星球可以通过现存的以太通道直接或间接地连通，则这两个星球在同一个连通块中）。

 输入输出格式 Input/output

输入格式：
输入文件第一行包含两个整数，N (1 <= N <= 2M) 和M (1 <= M <= 200,000)，分别表示星球的数目和以太隧道的数目。星球用0~N-1的整数编号。
接下来的M行，每行包括两个整数X, Y，其中（0<=X<>Y<N），表示星球X和星球Y之间有以太隧道。注意所有的以太隧道都是双向的。
接下来一行是一个整数K，表示帝国计划打击的星球个数。
接下来的K行每行一个整数X，满足0<=X<N，表示帝国计划打击的星球编号。帝国总是按输入的顺序依次摧毁星球的。
输出格式：
输出文件的第一行是开始时星球的连通块个数。

接下来的K行，每行一个整数，表示经过该次打击后现存星球的连通块个数。

题解：用并查集 但并查集只能并不能删 所以我们可以逆向思维反着做
从最后一个星球开始恢复 每恢复一个星球同时恢复相关的道路 记录下此时的连通块个数 最后逆序输出即可

代码：

var
  n,m,i,j,u1,u2,p,sum:longint;
  x,y,head,f,next,ans,a:array[0..400000] of longint;
  v:array[0..400000] of boolean;

function find(x:longint):longint;
begin
  if f[x]=x then exit(x);
  find:=find(f[x]);
  f[x]:=find;
end;

begin
  readln(n,m);
  for i:=1 to m do
  begin
    readln(x[i],y[i]);
    next[i*2-1]:=head[x[i]];
    head[x[i]]:=i*2-1;
    next[i*2]:=head[y[i]];
    head[y[i]]:=i*2;
  end;
  readln(p);
  fillchar(v,sizeof(v),true);
  for i:=1 to p do
  begin
    readln(a[i]);
    v[a[i]]:=false;
  end;
  for i:=0 to n-1 do
    f[i]:=i;
  sum:=n-p;
  for i:=1 to m do
    if (v[x[i]])and(v[y[i]]) then
    begin
      u1:=find(x[i]);
      u2:=find(y[i]);
      if u1<>u2 then
      begin
        dec(sum);
        f[u1]:=u2;
      end;
    end;
  ans[p]:=sum;
  for i:=p downto 1 do
  begin
    inc(sum);
    v[a[i]]:=true;
    j:=head[a[i]];
    while j>0 do
    begin
      if (v[x[(j+1) div 2]]=false)or(v[y[(j+1) div 2]]=false) then
      begin
        j:=next[j];
        continue;
      end;
      u1:=find(x[(j+1) div 2]);
      u2:=find(y[(j+1) div 2]);
      if u1<>u2 then
      begin
        dec(sum);
        f[u1]:=u2;
      end;
      j:=next[j];
    end;
    ans[i-1]:=sum;
  end;
  for i:=0 to p do
    writeln(ans[i]);
end.