adr和ldr
ARM汇编有ldr指令以及ldr、adr伪指令，他门都可以将标号表达式作为操作数，下面通过分析一段代码以及对应的反汇编结果来说明它们的区别。
ldr r0, _start
adr r0, _start
ldr r0, =_start
_start:
b _start
编译的时候设置 RO 为 0x30000000，下面是反汇编的结果：
0x00000000: e59f0004 ldr r0, [pc, #4] ; 0xc pc为当前地址加8
0x00000004: e28f0000 add r0, pc, #0 ; 0x0
0x00000008: e59f0000 ldr r0, [pc, #0] ; 0x10
0x0000000c: eafffffe b 0xc
0x00000010: 3000000c andcc r0, r0, ip (数据缓冲池）
1．ldr r0, _start
这是一条指令，从内存地址 _start 的位置把值读入。
在这里_start是一个标号（是一个相对程序的表达式），汇编程序计算相对于 PC 的偏移量，并生成相对于 PC的前索引的指令：ldr r0, [pc, #4]。执行指令后，r0 = 0xeafffffe。
ldr r0, _start是根据_start对当前PC的相对位置读取其所在地址的值，因此可以在和_start标号的相对位置不变的情况下移动。
2．adr r0, _start
这是一条伪指令，总是会被汇编程序汇编为一个指令。汇编程序尝试产生单个 ADD 或 SUB 指令来装载该地址。如果不能在一个指令中构造该地址，则生成一个错误，并且汇编失败。
在这里是取得标号_start 的地址到 r0，因为地址是相对程序的，因此ADR产生依赖于位置的代码，在此例中被汇编成：add r0, pc, #0。因此该代码可以在和标号相对位置不变的情况下移动；
假如这段代码在 0x30000000 运行，那么 adr r0, _start 得到 r0 = 0x3000000c；如果在地址 0 运行，就是 0x0000000c 了。
通过这一点可以判断程序在什么地方运行。U-boot中那段relocate代码就是通过adr实现当前程序是在RAM中还是flash中，下面进行简要分析。
3．ldr r0, =_start
这是一条伪指令，是一个相对程序的或外部的表达式。汇编程序将相对程序的标号表达式 label-expr 的值放在一个文字池中，并生成一个相对程序的 LDR 指令来从文字池中装载该值，在此例中生成的指令为：ldr r0, [pc, #0]，对应文字池中的地址以及值为：0x00000010: 3000000c。如果 label-expr 是一个外部表达式，或者未包含于当前段内，则汇编程序在目标文件中放置一个链接程序重定位命令。链接程序在链接时生成地址。
因此取得的是标号 _start 的绝对地址，这个绝对地址（运行地址）是在连接的时候确定的。它要占用 2 个 32bit 的空间，一条是指令，另一条是文字池中存放_start 的绝对地址。因此可以看出，不管这段代码将来在什么地方运行，它的结果都是 r0 = 0x3000000c。由于ldr r0, =_start取得的是_start的绝对地址，这句代码可以在_start标号的绝对位置不变的情况下移动；如果使用寄存器pc在程序中可以实现绝对转移。
用 LDR Rd, =const 加载
LDR Rd,= 伪指令可在单个指令中构造任何 32 位数字常数。 使用此伪指令可生成超出 constMOV 和 MVN 指令范围的常数。
LDR 伪指令可为特定的常数生成最高效的单个指令：
-
如果可以用单个
MOV或MVN指令构造该常数，则汇编器会生成适当的指令。 -
如果不能用单个
MOV或MVN指令构造该常数，则汇编器会执行下列操作：-
将该值放入文字池（在代码中嵌入的一部分内存，用于存放常数值）中。
-
生成一个使用程序相对地址的
LDR指令，用于从文字池中读取该常数。
例如：
LDR rn, [pc, #offset to literal pool] ; load registernwith one word ; from the address [pc + offset]必须确保文字池位于汇编器所生成的
LDR指令的范围内。 有关详细信息，请参阅放置文字池。 -
有关 LDR 伪指令语法的描述，请参阅LDR 伪指令。
放置文字池
汇编器将文字池放在每节的末尾。 这些节的末尾是由下一节开始处的 AREA 指令定义的，或者是由汇编代码末尾的 END 指令定义的。位于所包含的文件末尾的 END 指令并不表示一节的结束。
在较大的节中，缺省的文字池可能会超出一个或多个 LDR 指令的范围。 从 pc 到常数的偏移量必须符合下列条件：
-
在 ARM 或 Thumb-2 代码中小于 4KB，但可指向任何方向
-
在 Thumb-2 以前的 Thumb 代码中，或在 Thumb-2 代码中使用 16 位指令时，要小于 1KB 并指向前面。
当 LDR Rd,=const 伪指令要求将常数放入文字池时，汇编器会执行下列操作：
-
检查以前任何文字池中的常数是否可用以及是否可寻址。如果是，则会对现有常数进行寻址。
-
如果以前的文字池已经不可用，则会尝试将常数放入下一个文字池中。
如果下一个文字池超出范围（即超出了正负4kb)，汇编器会生成一条错误消息。 在这种情况下，必须使用 LTORG 指令在代码中放置一个附加的文字池。 LTORG 指令应放在失败的 LDR 伪指令之后，并位于范围 ±4KB（ARM，32 位 Thumb-2）或范围 0 到 +1KB（Thumb-2 以前的 Thumb、16 位 Thumb-2）内。 有关详细描述，请参阅LTORG。
文字池必须放在处理器不会试图将其当作指令来执行的位置上。 它们应放在无条件跳转指令的后面，或者放在子例程末尾处的返回指令的后面。
Example 2.4 显示了这一操作原理。在主示例目录 install_directory/RVDS/Examplesloadcon.s 文件形式提供了该示例。有关如何汇编、链接和执行该示例的说明，请参阅代码示例。
作为注释列出的指令是汇编器生成的 ARM 指令。
Example 2.4.
AREA Loadcon, CODE, READONLY ENTRY ; Mark first instruction to execute start BL func1 ; Branch to first subroutine BL func2 ; Branch to second subroutine stop MOV r0, #0x18 ; angel_SWIreason_ReportException LDR r1, =0x20026 ; ADP_Stopped_ApplicationExit SVC #0x123456 ; ARM semihosting (formerly SWI) func1 LDR r0, =42 ; => MOV R0, #42 LDR r1, =0x55555555 ; => LDR R1, [PC, #offset to ; Literal Pool 1] LDR r2, =0xFFFFFFFF ; => MVN R2, #0 BX lr LTORG ; Literal Pool 1 contains ; literal Ox55555555 func2 LDR r3, =0x55555555 ; => LDR R3, [PC, #offset to ; Literal Pool 1] ; LDR r4, =0x66666666 ; If this is uncommented it ; fails, because Literal Pool 2 ; is out of reach BX lr LargeTable SPACE 4200 ; Starting at the current location, ; clears a 4200 byte area of memory ; to zero END ; Literal Pool 2 is empty
转自：http://blog.csdn.net/liuchao1986105/article/details/6547245