通过这篇文章，可以了解到以下内容：
- 利用 Arduino 使用 5050全彩 LED 和 DTH11 温湿度传感器
- 利用 USB 与 Arduino，实现电脑与 Arduino 串口通讯
- 通过发送特定指令，控制 LED 变色以及获取温湿度数据
Arduino 与传感器接线方法
在这个 Arduino 微项目实践中，我们用到的传感器有两个：
- DTH11 温湿度传感器
- 5050 RGB LED 彩灯
DTH 温湿度传感器的使用方法很简单，可以参考购买传感器时商家提供的资料，或者参考我的另外一篇文章 《Arduino使用DHT11温湿度传感器获取环境温湿度》 来了解 DTH11 的使用。
5050 RGB 彩色 LED 灯，是一种把彩灯封装好的一个彩灯模块，模块上有 4 个引脚，分别是 GND R G B ，使用时，将模块上的 GND 与 Arduino 的 GND 相连接，然后 RGB引脚分别接到 Arduino 的三个数字输出 Pin 引脚，然后在 Arduino 中通过PWM驱动即可。
注意 由于 Frizing 的元件库中并没有找到国内网上常见的那种 5050 RGB LED 模块原件，因此找了一个类似的替代，在具体实践的时候，应根据自己购买的模块说明连接使用。
以下是 Arduino 电路连接示意图：
我们将 Arduino 的 Pin 9 ~ 11 分别连接 LED 模块的 G B R 引脚，Arduino GND 连接到 GND 模块上。DHT11模块 VCC 与 Arduino 5V 相连，GND 与 Arduino GND 相连，DATA 与 Arduino Pin 2 相连。这样，我们即完成了 Arduino 电路的连接。注意 实际实践的时候，需要根据自己购买的模块不同响应调整。
Arduino 代码编写
Arduino 程序主要有几个难点，分别是：
- 如何处理 Serial 输入，识别不同的命令进行处理
- LED 灯控制的技巧
- 获取温湿度数据
处理 Serial 输入
使用 Serial 传输数据，主要用到以下几个方法：
- Serial.read()
- Serial.available()
- Serial.parseInt()
下面简单介绍以下这三个方法的使用。
Serial.read() 用于返回 Serial 中的一个字节，如果没有可以返回的数据，则返回 -1，我们将会使用这个方法来获取 Serial 中的内容。
Serial.available() 用于检查 Serial 中剩余的数据，我们可以通过这个方法来检测是否由数据在 Serial 中。
Serial.parseInt() 用于解析 Serial 中的数值数据，将其转换为 int ，在这个项目中，我们将用这个方法来获取 LED 灯的颜色参数值。
接下来，我们面前有两个问题需要解决：
- Arduino 要如何判断我们的命令意图
- 如何返回程序的返回值
要使得 Arduino 能够处理 LED 灯变色，或者返回温湿度传感器的测量数据，首先要给 Arduino 发出不同的指令，然后 Arduino 通过判断不同的指令来作出相应的处理才能实现我们想要的结果。
因此，我们可以选择使用指令的第一个字母来判别不同的功能，在这个项目中，我们可以用 L 来表示进入 LED 灯控制模式，D 表示进入温湿度数据读取模式。除此之外，我们还需要识别出命令的尾部，从而结束一行命令的解析，这里我们用换行 \n 来标记一条命令的结束。
这样，我们就基本解决了如何判断命令意图的问题，到这一步为止，我们的程序大致如下：
while(Serial.available() > 0){
char incomeByte = Serial.read();
if (incomeByte == 'L') {
// 进入 LED 控制部分
if (Serial.read() == '\n') {
// 命令结束，处理
} else {
// 不符合指令输入要求，返回错误处理
}
} else if (incomeByte == 'D') {
// 温湿度数据读取处理
}
}
我们现在已经解决了指令的识别，但还存在一个问题，就是加入输入的命令既不是 LED 控制，也不是温湿度数据获取，那么理想状态下应该会返回一个错误值。我们这里将采取通过判断 \n 来识别出指令的尾部，如果没有成功进入 LED 控制或者温湿度获取，而且 Serial 读取到指令尾部，那么我们就返回一个错误的返回值。程序实例如下：
while(Serial.available() > 0){
char incomeByte = Serial.read();
if (incomeByte == 'L') {
// 进入 LED 控制部分
if (Serial.read() == '\n') {
// 命令结束，处理
} else {
// 不符合指令输入要求，返回错误处理
}
} else if (incomeByte == 'D') {
// 温湿度数据读取处理
} else if (incomeByte == '\n') {
// 返回错误
}
}
到这里为止，我们就已经完成指令识别的功能。
LED 灯控制的技巧
我们所使用的 5050 RGB LED 模块，通过 PWM 驱动从而实现变色的，我们可以为 LED 变色编写一个方法，输入三个 0 ~ 255 的颜色参数，然后实现变色，方法代码如下：
boolean setLedColor(int red, int green, int blue)
{
analogWrite(redPin, red);
analogWrite(greenPin, green);
analogWrite(bluePin, blue);
return true;
}
这里有一点需要注意，因为用户的输入未必是 0 ~ 255 的数值，因此我们在使用这个变色方法之前，需要先对用户的输入进行过滤，代码示例如下：
// 获取 R G B 用户输入
int red = Serial.parseInt();
int green = Serial.parseInt();
int blue = Serial.parseInt();
// 过滤用户输入
redVal = constrain(red, 0, 255);
greenVal = constrain(green, 0, 255);
blueVal = constrain(blue, 0, 255);
这样，我们就完成了对 LED 灯的控制部分程序编写了。
温湿度数据获取
温湿度数据获取也比较简单，我们首先要检查温湿度传感器是否正常，然后再进行获取数据，检查传感器的示例代码如下：
int chk = DHT11.read(dth11Pin);
if (chk == DHTLIB_OK) {
// 传感器正常
} else {
// 传感器出现问题
}
接下来，我们像控制 LED 变色一样，编写一个获取并输出温湿度数据的方法，示例代码如下：
void printHT()
{
Serial.print("Status: 1, Data: {");
Serial.print((float)DHT11.humidity, 2);
Serial.print(',');
Serial.print((float)DHT11.temperature, 2);
Serial.print("}\n");
}
我们这里选择直接通过 Serial 输出，其中输出信息包括 Status: 1 的正确标识，然后 Data 中返回第一个返回值是湿度，第二个返回值是温度。
到这里为止，我们的 Arduino 程序就基本完成了，完整的代码入下：
/*
File : ComLEDHtSenSer.ino
Date : 2017-9-13
Author : Yan Wong (speculatecat)
Description : The program is a demo for using com serial to control the LED color and get the tempture and humidity form DHT11 senser.
*/
#include
dht11 DHT11;
// Define RGB pin
const int redPin = 11;
const int bluePin = 10;
const int greenPin = 9;
// Define DTH11 pin
const int dth11Pin = 2;
// Store LED color, default RGB - 255,255,255
int redVal = 255;
int blueVal = 255;
int greenVal = 255;
void printStatus(boolean flag)
{
Serial.print("Status:");
Serial.print(flag);
Serial.print('\n');
}
void printHT()
{
Serial.print("Status: 1, Data: {");
Serial.print((float)DHT11.humidity, 2);
Serial.print(',');
Serial.print((float)DHT11.temperature, 2);
Serial.print("}\n");
}
boolean setLedColor(int red, int green, int blue)
{
analogWrite(redPin, red);
analogWrite(greenPin, green);
analogWrite(bluePin, blue);
return true;
}
void setup()
{
// Set Serial port - 9600
Serial.begin(9600);
// Set LED pin model
pinMode(redPin, OUTPUT);
pinMode(bluePin, OUTPUT);
pinMode(greenPin, OUTPUT);
}
void loop()
{
boolean flag = false;
while(Serial.available() > 0){
char incomeByte = Serial.read();
if (incomeByte == 'L') {
// The first byte from serial is 'L', mean enter LED color change model.
int red = Serial.parseInt();
int green = Serial.parseInt();
int blue = Serial.parseInt();
if (Serial.read() == '\n') {
// The end of command is '\n'.
redVal = constrain(red, 0, 255);
greenVal = constrain(green, 0, 255);
blueVal = constrain(blue, 0, 255);
if (setLedColor(redVal, greenVal, blueVal)) {
flag = true;
printStatus(flag);
}
} else {
printStatus(flag);
}
} else if (incomeByte == 'D') {
// Get humidity and temperature from dht11.
int chk = DHT11.read(dth11Pin);
if (chk == DHTLIB_OK) {
printHT();
} else {
printStatus(false);
}
} else if (incomeByte == '\n') {
// Error command, return false.
printStatus(flag);
}
}
}
接下来，我们将程序编译好上传到 Arduino 即可。
项目演示
Arduino 和各个模块正确连接，并上传好 Arduino 程序后，我们就可以通过串口监视器来与 Arduino 进行通信。以下是串口监视器的部分通信截图：
可以看到，如果我们输入预设没有的指令，会返回 Status: 0 的错误信息，如果发送更改 LED 颜色的指令，可以看到 Status: 1 成功的返回值，发送温湿度数据获取的指令，可以看到温湿度数据的返回。
下面是我的 Arduino 与各个模块的连接以及运行时的照片，可供参考：
小结
到此为止，我们这个微项目实践已经完成。我们随后还可以在这个基础上，改造成通过蓝牙控制和获取数据，或者添加程序，使得 LED 等可以根据环境的不同温湿度来呈现不同的颜色。
如果你对这个微项目实践有疑问，可以在本文回复，我会尽力回答。
如果你觉得这篇文章对你有帮助，欢迎点击喜欢收藏，或者关注我。