实验17 ：安装一个新的int 7CH 中断例程，实现通过逻辑扇区号对软盘进行读写

参数说明

针对测试程序 test.asm 而言：

（1）用 ah 寄存器传递功能号： 0表示读，1表示写；
（2）用 dx 寄存器传递要读写的扇区的逻辑扇区号；
（3）用 es:bx 指向存储读出数据或写入数据的内存区

用逻辑扇区号与物理扇区号转换计算

L = 逻辑扇区号 = （面号*80 + 磁道号）*18 + 扇区号 - 1

面号 = int（逻辑扇区号/1440）
磁道号 = int（rem（逻辑扇区号/1440）/18）
扇区号 = rem（rem（逻辑扇区号/1440）/18）+1

进行开发环境配置，完成虚拟机XP 以及软盘的配置

软盘配置 https://www.jianshu.com/p/bfeed0397631

虚拟机XP配置 https://www.jianshu.com/p/43c8661b381d

完整源码

测试程序文件 test.asm

写扇区：将显存的内容写入软盘A的某一个扇区之中
读扇区：将软盘A的某一个扇区中的数据读到某一段开辟的内存空间

assume cs:code
stack segment
    db 550 dup(0)       
stack ends
code segment
start:
        mov ax,stack
        mov ss,ax
        mov sp,550
        
        ; write floppy
        mov ah,1    
        mov dx,20   
        
        mov bx,0B800H
        mov es,bx
        mov bx,0
        
        int 7ch
        
        ; read floppy to memory
        mov ah,0
        mov dx,20
        
        mov bx,stack
        mov es,bx
        mov bx,0000
        
        int 7ch
        
        mov ax,4c00H
        int 21H
    
code ends
end start

int 7CH 中断例程安装程序文件 setup.asm

功能：将新的int7CH中断例程安装到内存0000:0200H 开始

assume cs:code
code segment
    start:  ;------ 安装功能程序到 0000:0200H 开始 --------
            mov ax,cs
            mov ds,ax
            mov si, offset rw
            
            mov ax,0
            mov es,ax
            mov di,200H
            mov cx,offset rwend - offset rw
            cld
            rep movsb

            ;------ 在中断向量表 7Ch号表项处写入 
            ;       中断处理程序的入口地址0000:0200h -----
            mov ax,0
            mov es,ax
            mov word ptr es:[7CH*4],200H
            mov word ptr es:[7CH*4+2],0
            
            
            mov ax,4c00H
            int 21H
            
    ;---------- 7CH号中断处理程序本身 ---------     
            
    rw:         push ax
                
                mov ax,dx
                mov dx,0
                mov cx,05a0H
                div cx
                push ax
                
                mov ax,dx
                mov dx,0
                mov cx,0012H
                div cx
                push ax
                
                add dx,1
                mov cl,dl
                
                pop ax
                mov ch,al
                
                pop dx
                mov dh,dl
                
                mov dl,0
                
                pop ax
                add ah,2
                
                mov al,1
        
                int 13H
                
            iret
    rwend:  nop

    
    code ends
    end start

代码参考

中断处理程序以及安装

https://www.jianshu.com/p/6b00375b3046

32位÷16位除法寄存器的用法 DX|AX 余数放在DX 除数放在AX

https://www.jianshu.com/p/211cf4edd4d3

对BIOS int 13H 对磁盘进行读写操作的参数说明

https://www.jianshu.com/p/bfeed0397631

代码说明

测试程序 test.asm

什么是开辟的内存空间？有什么用？

在开头有一段
stack segment
    db 550 dup(0)       
stack ends

这里作为开辟的内存空间，用来存放从软盘某个扇区读来的内容，
软盘一个扇区大小是 512KB（字节），所以这里申请了 550个字节，足够存数据。

哪些参数是提供给程序员修改的？

以写扇区操作举例：

; write floppy
        mov ah,1        ; ah = 1表示写扇区，ah = 0 表示读扇区
        mov dx,20      ; 逻辑的扇区 20号 = 物理的 0 面 1道 3 扇区
        
        mov bx,0B800H
        mov es,bx
        mov bx,0        ;     es:bx 指定写入扇区的数据来自何方? 这里是来自显存
        
        int 7ch    ;     进入 int 7CH 中断

中断处理程序 setup.asm

中断处理程序本身开头的这句 rw: push ax是干什么用的？

顾名思义，就是保存 寄存器AX 的内容，
本质上是 保存 AH 的内容，AH 是功能号，
指明要进行读扇区还是写扇区操作，

但是因为后面需要用到 AX寄存器 反复进行 除法 运算，
会覆盖这个最初的功能号，
因此需要用 栈 将AX保存起来。

如何从逻辑扇区号计算出物理的扇区信息

从逻辑扇区号计算出物理的扇区信息.png

以 DX = 20D = 0014H 举例
要反复使用到 DX 以及 AX 寄存器做 32位÷16位的除法运算
基本上有用的结果都会在低8位寄存器 DL 或者 AL 里面
通过把计算过程中得到的有效信息 压入栈，从而可以反复使用 DX 和 AX 进行计算

之后再反复弹出栈中元素，
按照 BIOS int 13H 对磁盘读写的入口参数，
设置对应的寄存器即可


在测试程序中，使用 ah = 0 表示读扇区操作，ah = 1 表示写扇区操作，
而在BIOS int 13H 的入口参数设置汇总， ah = 2 表示写扇区，ah = 3表示读扇区，
因此需要  add ah,2 ，依次达到正确的参数设置。