1. 问题描述
ANSYS的诸多结构建模分析技术，往往需要一个最简单的案例进行测试。所有问题中，最简单、最有代表性的问题即为：简支钢梁的重力加载分析。
麻雀虽小，五脏俱全。极简算例包含了ANSYS结构分析的所有必要过程：
image_1b1qut4d1s53lst1cjjds38ug16.png-37.5kB
2. 技术背景
采用ANSYS命令流建模，保证模型的通用性。
3. 解决方案
建模参数：
- 材料：钢材；
- 梁长：10m；
- 边界：简支；
- 荷载：自重；
- 单元：beam188;
4. 实施示例
4.1 文件头
!---------------------------------------------------------------------
! 题目：钢材简支梁结构分析
! 要点：1. 简支钢梁建模
! 2. 加载：重力加载
! 3. 弯矩图绘制
! FRANK2015,HIT,2016.11.18
!---------------------------------------------------------------------
FINI
/CLEAR
4.2 几何建模
!---------------------------------几何建模 ---------------------------
/PREP7
K,1,0 ! 支座点
K,2,10
L,1,2
image_1b1qv2bq5b11e04v291cpl187m1j.png-15.2kB
4.2 材料参数
!---------------------------------材料参数 ---------------------------
MP,EX,1,2.0E11 ! 钢材，弹性模量
MP,PRXY,1,0.3 ! 弹性模量
MP,Dens,1,7800 ! 密度
ET,1,BEAM188 ! 三维梁单元
KEYOPT,1,3,3 ! 定义三次形函数
SECTYPE,1,BEAM,RECT ! 矩形截面
SECDATA,0.5,1
4.3 网格划分
!---------------------------------网格划分 ---------------------------
LSEL,ALL
LATT,1,,1,,,,1 ! 附加单元材料属性
LESIZE,ALL,,,10 ! 划分10段网格
LMESH,ALL ! 生成有限单元
n1 = node(0,0,0) ! 提取坐标节点
n2 = node(10,0,0)
4.4 边界条件
!---------------------------------边界条件 ---------------------------
D,n1,UY,,,,,UZ,ROTX,ROTZ ! 简支梁端支座
D,n1,UX
D,n2,UY,,,,,UZ,ROTX,ROTZ
/PNUM,ELEM,1 ! 显示单元号
/PBC,ALL ! 显示约束
4.5 重力加载求解
!-------------------------------重力求解 ---------------------------
/SOLU
ANTYPE,STATIC
ACEL,,,9.8 ! z向重力加载
SOLVE
FINISH
此处，ANSYS的Z方向重力为默认方向，直接输入重力加速度9.8即可。
4.6 后处理
!---------------------------------后处理 ---------------------------
/POST1
PLDISP,1 ! 变形图
ETABLE,MI,SMISC,2 ! MY
ETABLE,MJ,SMISC,15
PLLS,MI,MJ,1 ! 弯矩图
位移图.png-26kB
弯矩图.png-33.7kB
5. 常见问题
精简代码如下：
FINI
/CLEAR
!---------------------------------几何建模 ---------------------------
/PREP7
K,1,0 ! 支座点
K,2,10
L,1,2
!---------------------------------材料参数 ---------------------------
MP,EX,1,2.0E11 ! 钢材，弹性模量
MP,PRXY,1,0.3 ! 弹性模量
MP,Dens,1,7800 ! 密度
ET,1,BEAM188 ! 三维梁单元
KEYOPT,1,3,3 ! 定义三次形函数
SECTYPE,1,BEAM,RECT ! 矩形截面
SECDATA,0.5,1
!---------------------------------网格划分 ---------------------------
LSEL,ALL
LATT,1,,1,,,,1 ! 附加单元材料属性
LESIZE,ALL,,,10 ! 划分10段网格
LMESH,ALL ! 生成有限单元
n1 = node(0,0,0) ! 提取坐标节点
n2 = node(10,0,0)
!---------------------------------支座约束 ---------------------------
D,n1,UY,,,,,UZ,ROTX,ROTZ ! 简支梁端支座
D,n1,UX
D,n2,UY,,,,,UZ,ROTX,ROTZ
/PNUM,ELEM,1 ! 显示单元号
/PBC,ALL ! 显示约束
!---------------------------------求解 ---------------------------
/SOLU
ANTYPE,STATIC
ACEL,,,9.8 ! z向重力加载
SOLVE
FINISH
!---------------------------------后处理 ---------------------------
/POST1
PLDISP,1 ! 变形图
ETABLE,MI,SMISC,2 ! MY
ETABLE,MJ,SMISC,15
PLLS,MI,MJ,1 ! 弯矩图
本文用时 30 m。