王爽《汇编语言》实验7

老实说，自己的编程技能差的还太多，完成这个实验竟用了足足3个小时，包括构思、编辑、调试、修改、再调试……

不过，总算调通了，可以进行下一章的学习了。

assume cs:codesg

data segment
	db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
	db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
	db '1993','1994','1995'
	;以上是表示21年的21个字符串
	
	dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
	dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
	;以上是表示21年公司总收入的21个dword型数据
	
	dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
	dw 11542,14430,15257,17800
	;以上是表示21Ian公司雇员人数的21个word型数据	
data ends

table segment
	db 21 dup ('year summ ne ?? ')
table ends
;以上为书中给出的代码

stacksg segment
	dw 0,0,0,0,0,0,0,0
	;开辟栈空间，存放外层循环CX的值
stacksg ends

codesg segment
start:	mov ax,data
	mov ds,ax
		
	mov ax,table
	mov es,ax
		
	mov ax,stacksg
	mov ss,ax
	mov sp,16
		
	mov si,0		;定位data段中的每个年份和公司总收入的每个字节，0表示定位第一个字节
	mov bx,0		;bx定位table中的每一条记录，0表示定位第一条
	mov bp,0		;定位data段中每年雇员人数，0表示定位第一年的
		
	mov cx,21		;外层循环次数
s0:	push cx			;入栈
	mov di,0		;定位table段中年份和收入的每个字节
		
	mov cx,4
s1:	mov ax,0
	mov al,ds:[si]
	mov ah,ds:84[si]
	mov es:[bx].0[di],al		;写年份
	mov es:[bx].5[di],ah		;写收入
	inc si
	inc di
	loop s1
	;s1将年份和收入写入table段，按字节写入
		

s2:	mov ax,0		
	mov ax,ds:[bp].168
	mov es:[bx].10,ax
	add bp,2
	;s2仅作为标号，不进行循环，这段代码将雇员人数写入table，按字写入
		
	mov dx,es:[bx].7
	mov ax,es:[bx].5
	div word ptr es:[bx].10		
	mov es:[bx].13,ax
	;这段代码计算人均收入（取整）并写入table
		
	add bx,16	    ;定位下一条记录
	pop cx		    ;外循环次数出栈
	loop s0
		
	mov ax,4c00h
	int 21h

codesg ends
end start