区块链：Solidity值类型(String字符串&固定大小字节数组&动态大小字节数组)
String字符串
案例
字符串可以通过""或者''来表示字符串的值，Solidity中的string字符串不像C语言一样以\0结束，比如'goddreamwt'这个字符串的长度就为我们所看见的字母的个数，它的长度为10。
pragma solidity ^0.4.4;
contract StringLiterals{
string _name; // 状态变量
//构造函数
function StringLiterals() {
// 将我的微信号初始化
_name = "goddreamwt";
}
// set方法
function setString(string name) {
_name = name;
}
// get方法
function name() constant returns (string) {
return _name;
}
}备注：string字符串不能通过length方法获取其长度。
固定大小字节数组(Fixed-size byte arrays)
固定大小字节数组可以通过 bytes1, bytes2, bytes3, …, bytes32来进行声明。PS：byte的别名就是 byte1。
bytes1只能存储一个字节，也就是二进制8位的内容。
bytes2只能存储两个字节，也就是二进制16位的内容。
bytes3只能存储三个字节，也就是二进制24位的内容。
……
bytes32能存储三十二个字节，也就是二进制32 * 8 = 256 位的内容。
pragma solidity ^0.4.4;
contract C {
// 0x6c697975656368756e
byte public a = 0x6c; // 0110 1100
bytes1 public b = 0x6c; // 0110 1100
bytes2 public c = 0x6c69; // 0110 1100 0110 1001
bytes3 public d = 0x6c6979; // 0110 1100 0110 1001 0111 1001
bytes4 public e = 0x6c697975; // 0110 1100 0110 1001 0111 1001 0111 0101
// ...
bytes8 public f = 0x6c69797565636875; // 0110 1100 0110 1001 0111 1001 0111 0101 0110 0101 0110 0011 0110 1000 0111 0101
bytes9 public g = 0x6c697975656368756e; // // 0110 1100 0110 1001 0111 1001 0111 0101 0110 0101 0110 0011 0110 1000 0111 0101 0110 1110
}
成员函数
.length返回字节的个数。（只读）
pragma solidity ^0.4.4;
contract C {
bytes9 public g = 0x6c697975656368756e;
function gByteLength() constant returns (uint) {
return g.length;
}
}
不可变深度解析
- 长度不可变
pragma solidity ^0.4.4;
contract C {
bytes9 name = 0x6c697975656368756e;
function setNameLength(uint length) {
// 报错
name.length = length;
}
}- 内部字节不可修改
bytesI(1 <= I <= 32)可以声明固定字节大小的字节数组变量，一旦声明，内部的字节和字节数组长度不可修改，当然可以通过索引读取(只读)对应索引的字节，或者通过length读取字节数组的字节数。
动态大小字节数组(Dynamically-sized byte array)
一、Dynamically-sized byte array
string是一个动态尺寸的UTF-8编码字符串，它其实是一个特殊的可变字节数组，string是引用类型，而非值类型。bytes动态字节数组，引用类型。
二、常规字符串 sting 转换为 bytes
string字符串中没有提供length方法获取字符串长度，也没有提供方法修改某个索引的字节码，不过我们可以将string转换为bytes，再调用length方法获取字节长度，当然可以修改某个索引的字节码。
pragma solidity ^0.4.4;
contract C {
bytes9 public g = 0x6c697975656368756e;
string public name = "gooddreamwt";
function gByteLength() constant returns (uint) {
return g.length;
}
function nameBytes() constant returns (bytes) {
return bytes(name);
}
function nameLength() constant returns (uint) {
return bytes(name).length;
}
function setNameFirstByteForL(bytes1 z) {
// 0x4c => "L"
bytes(name)[0] = z;
}
}三、汉字字符串或特殊字符的字符串转换为bytes
- 1、特殊字符
pragma solidity ^0.4.4;
contract C {
string public name = "a!+&520";
function nameBytes() constant returns (bytes) {
return bytes(name);
}
function nameLength() constant returns (uint) {
return bytes(name).length;
}
}在这个案例中，我们声明了一个name字符串，值为a!+&520，根据nameBytes和nameLength返回的结果中，我们不难看出，不管是字母、数字还是特殊符号，每个字母对应一个byte（字节）。
2、中文字符串
pragma solidity ^0.4.4;
contract C {
string public name = "王涛";
function nameBytes() constant returns (bytes) {
return bytes(name);
}
function nameLength() constant returns (uint) {
return bytes(name).length;
}
}
在上面的代码中，我们不难看出，王涛转换为bytes以后的内容为0xe78e8be6b69b，一共6个字节。也就是一个汉字需要通过3个字节来进行存储。那么问题来了，以后我们取字符串时，字符串中最好不要带汉字，否则计算字符串长度时还得特殊处理。
四、创建bytes字节数组
pragma solidity ^0.4.4;
contract C {
bytes public name = new bytes(1);
function setNameLength(uint length) {
name.length = length;
}
function nameLength() constant returns (uint) {
return name.length;
}
}
五、bytes可变数组length和push两个函数的使用案例
pragma solidity ^0.4.4;
contract C {
// 0x6c697975656368756e
// 初始化一个两个字节空间的字节数组
bytes public name = new bytes(2);
// 设置字节数组的长度
function setNameLength(uint len) {
name.length = len;
}
// 返回字节数组的长度
function nameLength() constant returns (uint) {
return name.length;
}
// 往字节数组中添加字节
function pushAByte(byte b) {
name.push(b);
}
}
说明：当字节数组的长度只有2时，如果你通过push往里面添加了一个字节，那么它的长度将变为3，当字节数组里面有3个字节，但是你通过length方法将其长度修改为2时，字节数组中最后一个字节将被从字节数组中移除。
五、总结
对比分析：
- 不可变字节数组
我们可以通过bytes1,bytes2,bytes3,bytes4,……,bytes32来声明字节数组变量，不过通过bytesI来声明的字节数组为不可变字节数组，字节不可修改，字节数组长度不可修改。
- 可变字节数组
我们可以通过bytes name = new bytes(length) - length为字节数组长度，来声明可变大小和可修改字节内容的可变字节数组。