关押罪犯(prison.pas/cpp/in/out)

 

关押罪犯(prison.pas/cpp/in/out)

 

题目描述

S 城现有两座监狱，一共关押着N 名罪犯，编号分别为1~N。他们之间的关系自然也极不和谐。很多罪犯之间甚至积怨已久，如果客观条件具备则随时可能爆发冲突。我们用“怨气值”（一个正整数值）来表示某两名罪犯之间的仇恨程度，怨气值越大，则这两名罪犯之间的积怨越多。如果两名怨气值为c 的罪犯被关押在同一监狱，他们俩之间会发生摩擦，并造成影响力为c 的冲突事件。

每年年末，警察局会将本年内监狱中的所有冲突事件按影响力从大到小排成一个列表，然后上报到S 城Z 市长那里。公务繁忙的Z 市长只会去看列表中的第一个事件的影响力，如果影响很坏，他就会考虑撤换警察局长。

在详细考察了N 名罪犯间的矛盾关系后，警察局长觉得压力巨大。他准备将罪犯们在两座监狱内重新分配，以求产生的冲突事件影响力都较小，从而保住自己的乌纱帽。假设只要处于同一监狱内的某两个罪犯间有仇恨，那么他们一定会在每年的某个时候发生摩擦。那么，应如何分配罪犯，才能使Z 市长看到的那个冲突事件的影响力最小？这个最小值是多少？

 

【输入输出样例说明】

罪犯之间的怨气值如下面左图所示，右图所示为罪犯的分配方法，市长看到的冲突事件影响力是3512（由2 号和3 号罪犯引发）。其他任何分法都不会比这个分法更优。

【数据范围】
对于30%的数据有N≤ 15。
对于70%的数据有N≤ 2000，M≤ 50000。
对于100%的数据有N≤ 20000，M≤ 100000。

输入格式

输入文件的每行中两个数之间用一个空格隔开。
第一行为两个正整数N 和M，分别表示罪犯的数目以及存在仇恨的罪犯对数。

接下来的M 行每行为三个正整数aj，bj，cj，表示aj 号和bj 号罪犯之间存在仇恨，其怨气值为cj。数据保证1

输出格式

共1 行，为Z 市长看到的那个冲突事件的影响力。如果本年内监狱中未发生任何冲突事件，请输出0。

 

样例输入

4 6

1 4 2534

2 3 3512

1 2 28351

1 3 6618

2 4 1805

3 4 12884

 

样例输出

3512

===============================

这是一个最大值最小的问题，我们可以用二分答案

猜测一个mid，判断命题“所有冲突都<=mid” 也就是冲突>mid的要关在不同的监狱

=============================== 

type
  node=^re;
  re=record
       x,cost:longint;
       next:node;
     end;
     
var
  n,m:longint;
  t:array[1..20000]of node;
  f:array[1..20000]of longint;
  l,r,mid:longint;
procedure init;
begin
  assign(input,'prison.in');
  assign(output,'prison.out');
  reset(input); rewrite(output);
end;

procedure terminate;
begin
  close(input); close(output);
  halt;
end;

procedure insert(a,b,c:longint);
var
  p:node;
begin
  new(p);
  p^.x:=b;
  p^.cost:=c;
  p^.next:=t[a];
  t[a]:=p;
end;

function dfs(tu:longint):boolean;
var
  p:node;
begin
  dfs:=true;
  p:=t[tu];
  while p<>nil do
    begin
      if p^.cost>mid then
        begin
          if f[p^.x]=f[tu] then
            begin
              exit(false);
            end;
          if f[p^.x]=-1 then
            begin
              f[p^.x]:=2-f[tu];
              if not dfs(p^.x) then exit(false);
            end;
        end;
      p:=p^.next;
    end;
end;

procedure main;
var
  i:longint;
  a,b,c,ans:longint;
  flag:boolean;
begin
  readln(n,m);
  for i:=1 to n do
    t[i]:=nil;
  for i:=1 to m do
    begin
      readln(a,b,c);
      insert(a,b,c);
      insert(b,a,c);
    end;
  l:=0; r:=1000000000;
  while l<=r do
    begin
      mid:=(l+r) shr 1;
      fillchar(f,sizeof(f),$ff);
      for i:=1 to n do
        begin
          if f[i]=-1 then
            begin
              f[i]:=0;
              flag:=dfs(i);
              if not flag then break;
            end;
        end;
      if flag then begin r:=mid-1; ans:=mid; end
              else l:=mid+1;
    end;
  writeln(ans);
end;

begin
  init;
  main;
  terminate;
end.