UnityShader入门精要笔记（6）——基础纹理

基础纹理

一、单张纹理

1、纹理贴图属性

• Wrap Mode：（决定当纹理坐标超过[0,1]范围后将会如何被平铺）
  Repeat： 如果纹理坐标超过1，那么它整数部分就会被舍弃，直接使用小数部分进行采样，这样的结果是纹理将会不断重复；
  Clamp：如果纹理坐标超过1，那么将会截取到1，如果小于0，则截取到0.
• Filter Mode：（决定了当纹理由于变换而产生拉伸时将会采用哪种滤波模式）
  Point、Bilinear、Trilinear：得到的图片滤波效果依次提升，但是耗费的性能也依次增大。

2、shader代码

Shader "Unlit/SingleTexture"
{
    Properties{
        _Color("Color Tint",Color) = (1,1,1,1)
        _MainTex("Main Texture",2D) = "white"{}
        _Specular("Specular",Color) = (1,1,1,1)
        _Gloss("Gloss",Range(8.0,256)) = 20
    }
    SubShader{
        Pass{
            Tags{
                "LightMode"="ForwardBase"
            }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            #include "UnityCG.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            //需要使用纹理名_ST的方式来声明某个纹理的属性，ST是缩放和平移的缩写，_MainText_ST可以得到纹理的缩放和平移值
            //_MainTex_ST.xy存储的是缩放值，_MainTex_ST.zw存放的是偏移值
            float4 _MainTex_ST;  
            fixed4 _Specular;
            float _Gloss;

            struct a2v{
                float4 vertex : POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0; 
            };

            struct v2f{
                float4 pos:SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos:TEXCOORD1;
                //存储纹理坐标，以便在片元着色器中使用该坐标进行纹理采样
                float2 uv:TEXCOORD2;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                //使用_MainTex_ST.xy对顶点纹理坐标进行缩放，再用_MainTex_ST.zw对结果进行偏移
                //o.uv = v.texcoord.xy * _MainTex_ST.xy + MainTex_ST.zw;
                o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);//该函数的作用相当于上述公式
                return o;
            }

            fixed4 frag(v2f i):SV_Target{
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
                fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,worldLightDir));
                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);
                return fixed4(ambient + diffuse + specular,1.0);
            }
            ENDCG


        }
    }
}

二、凹凸映射

1、目的：使用一张纹理来修改模型表面的法线

2、方法：

• 高度纹理（又称高度映射）：模拟表面位移，得到一个修改后的法线值。
• 法线纹理（又称法线映射）：直接存储表面法线。
• 需要注意的是：我们常常将凹凸映射和法线映射当成是相同的技术。

3、高度纹理

高度图中存储的是强度值，用于表示模型表面局部的海拔高度。颜色越浅表面越外凸，颜色越深表面该位置越往里凹。
缺点：计算更加复杂，在实时计算中不能直接得到表面法线，而是需要由像素的灰度值计算得到。

4、法线纹理

• 法线纹理中存储的是表面的法线方向。由于法线方向的分量范围在[1,-1]，而像素的分量范围是[0,1]，因此需要做个映射：
  pixel = (normal+1)/2
• 因此在shader中对法线纹理进行纹理采样之后，需要对结果进行一次反映射的过程，以得到原先的法线方向。
  noral = pixel*2 - 1
• 对于模型顶点自带的法线，是定义在模型空间中的，因此修改后的模型空间中的表面法线存储在一张纹理中，这种纹理被称为模型空间的法线纹理。
• 在实际的制作中，采用的是模型顶点的切线空间。切线空间的原点是该顶点的本身，而z轴是顶点的法线方向（n），x轴是顶点的切线方向（t），y轴由法线和切线的叉积而得，也被称为副切线或者副法线。
• 想用unity的内置函数UnpackNormal来得到正确的法线方向，需要把法线纹理的纹理类型标识成Normal map。

三、渐变纹理

1、作用：用渐变纹理控制漫反射光照

代码：

Shader "Unlit/RampTextureMat"
{
    Properties
    {
        _Color("Color Tint",Color) = (1,1,1,1)
        _RampTex("Ramp Tex",2D) = "white"{}
        _Specular("Specular",Color) = (1,1,1,1)
        _Gloss("Gloss",Range(8.0,256)) = 20
    }
    SubShader
    {
        Pass{
            Tags{"LightMode" = "ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _RampTex;
            float4 _RampTex_ST;
            float4 _Specular;
            float _Gloss;

            struct a2v{
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 texcoord : TEXCOORD0;
            };

            struct v2f{
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float2 uv : texcoord2;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                o.uv = TRANSFORM_TEX(v.texcoord,_RampTex);
                return o;
            };
            fixed4 frag(v2f i):SV_TARGET{
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                //使用半兰伯特模型，将原本的[-1,1]的值映射到[0,1]之间
                fixed halfLambert = 0.5 * dot(worldNormal,worldLightDir)+0.5;
                //使用halfLambert构建一个纹理坐标，并用这个纹理坐标对渐变纹理_RampTex进行采样，然后把从渐变纹理采样得到的颜色和材质颜色_Color相乘，得到最终的漫反射颜色
                fixed3 diffuseColor = tex2D(_RampTex, fixed2(halfLambert,halfLambert)).rgb * _Color.rgb;
                
                fixed3 diffuse = _LightColor0.rgb * diffuseColor;
                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
                fixed3 halfDir = normalize(worldLightDir + viewDir);

                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);
                return fixed4(ambient + diffuse + specular,1.0);
            }
            ENDCG
        }

    }
}

四、遮罩纹理

1、作用：允许保护某些区域，使它们免于某些修改。可以让美术人员更加精准（像素级别）地控制模型表面的各种性质

2、流程：

通过采样得到遮罩纹理的纹素值，使用其中某个（或几个）通道的值（例如texel.r）来与某种表面属性进行相乘，这样，当通道的值为0 的时候，可以保护表面不受该属性的影响。

3、代码

Shader "Unlit/MaskTexture"
{
    Properties
    {
        _Color("Color Tint",Color) = (1,1,1,1)
        _MainTex("Main Tex",2D) = "white"{}
        _BumpMap("Normal Map",2D) = "bump"{}
        _BumpScale("Bump Scale",Float) = 1.0
        _SpecularMask("Specular Mask",2D) = "white"{}
        _SpecularScale("Specular Scale",Float) = 1.0
        _Specular("Specular",Color) = (1,1,1,1)
        _Gloss("Gloss",Range(8.0,256)) = 20
    }
    SubShader
    {
       Pass{
           Tags{ "LightMode"="FrowardBase" }
           CGPROGRAM
           #pragma vertex vert
           #pragma fragment frag
           #include "Lighting.cginc"
           #include "UnityCG.cginc"

           fixed4 _Color;
           sampler2D _MainTex;
           float4 _MainTex_ST;
           sampler2D _BumpMap;
           float4 _BumpMap_ST;
           float _BumpScale;
           sampler2D _SpecularMask;
           float4 _SpecularMask_ST;
           float _SpecularScale;
           fixed4 _Specular;
           float4 _Gloss;

           struct a2f{
               float4 vertex : POSITION;
               float3 normal : NORMAL;
               float4 tangent:TANGENT;
               float4 texcoord : TEXCOORD0;
           };
           struct v2f{
               float4 pos : SV_POSITION;
               float2 uv : TEXCOORD0;
               float3 lightDir : TEXCOORD1;
               float3 viewDir:TEXCOORD2;
           };

           v2f vert(a2f v){
               v2f o;
               o.pos = UnityObjectToClipPos(v.vertex);
               o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
               float3 binormal = cross(normalize(v.normal),normalize(v.tangent.xyz)) * v.tangent.w;
               float3x3 rotation = float3x3(v.tangent.xyz,binormal,v.normal);
               //TANGENT_SPACE_ROTATION;
               //对光照方向和视角进行坐标空间变化，从模型空间变换到切线空间中，以便在片元着色器中和法线进行光照运算
               o.lightDir = mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;
               o.viewDir = mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;
               return o;
           }

           fixed4 frag(v2f i):SV_TARGET{
               fixed3 tangentLightDir = normalize(i.lightDir);
               fixed3 tangentViewDir = normalize(i.viewDir);

               fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap,i.uv));
               tangentNormal.xy *= _BumpScale;
               tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy,tangentNormal.xy)));

               fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;

               fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
               fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(tangentNormal,tangentLightDir));
               fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
               fixed specularMask = tex2D(_SpecularMask,i.uv).r * _SpecularScale;

               fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(tangentNormal,halfDir)),_Gloss) * specularMask;
               return fixed4(ambient+diffuse+specular ,1.0);
           }
           ENDCG

       }
    }
}