《Unity Shader入门精要》第七章 笔记
法线贴图，在切线空间中计算光照的 shader:
Shader "Unity Shaders Book/Chapter7" {
Properties
{
_Color("Color Tint", Color) = (1,1,1,1)
_MainTex("Main Tex", 2D) = "white" {}
_BumpMap("Normal Map", 2D) = "bump" {}
_BumpScale("Bump Scale", Float) = 1.0
_Specular("Specular", Color) = (1,1,1,1)
_Gloss("Gloss", Range(8.0,256)) = 20
}
SubShader
{
Pass
{
Tags {"LightMode" = "ForwardBase"}
CGPROGRAM
//定义顶点着色器函数和片段着色器函数
#pragma vertex vert
#pragma fragment frag
//为了访问光源相关参数，要引入 Lighting 库
#include "Lighting.cginc"
float4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;
float4 _Specular;
float _Gloss;
//传入顶点着色器的参数
struct a2v
{
float4 vertex : POSITION; //顶点坐标
float3 normal : NORMAL; //法线方向
float4 tangent : TANGENT; //切线方向
float4 texcoord : TEXCOORD0; //纹理坐标
};
//片元着色器参数，在顶点着色器返回值上进行插值后传入
struct v2f
{
float4 pos : SV_POSITION; //必须的参数，而且是固定的转换方式，把顶点坐标从模型空间转到裁剪空间中，利用 UnityObjectToClipPos(vertex)
float4 uv: TEXCOORD0; //纹理坐标(存于xy中)，法线纹理(存于zw中)
float3 lightDir : TEXCOORD1; //切线空间中的光线方向
float3 viewDir : TEXCOORD2; //切线空间中的视线方向
};
//顶点着色器，顶点着色器只作用在每个顶点，其它像素点通过插值传入片元着色器处理
v2f vert(a2v v)
{
v2f o;
//固定写法，把顶点坐标从模型空间转换到世界坐标
o.pos = UnityObjectToClipPos(v.vertex);
//计算纹理 uv 等于纹理坐标 x 纹理缩放 + 纹理位移
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
//o.uv = TRANSFORM_TEX(v.textcoord, _MainTex);
//计算法线纹理 uv 等于纹理坐标 x 纹理缩放 + 纹理位移
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;
//计算从模型空间到切线空间的转换矩阵
float3 binormal = cross(normalize(v.normal),normalize(v.tangent.xyz)) * v.tangent.w;
float3x3 rotation = float3x3(v.tangent.xyz,binormal,v.normal);
//把光线方向从世界空间转换到切线空间
o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
//把视线方向从世界空间转换到切线空间
o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;
return o;
}
fixed4 frag(v2f i) : SV_Target
{
//切线空间中光线的方向，指向光源的方向
fixed3 tangentLightDir = normalize(i.lightDir);
//计算高光反射 Bilinn 模型
//世界坐标下的视角方向，从点到相机的方向
fixed3 tangentViewDir = normalize(i.viewDir);
//获取切线空间下的法线方向，固定算法
fixed4 packedNormal = tex2D(_BumpMap, i.uv.zw);
fixed3 tangentNormal;
tangentNormal = UnpackNormal(packedNormal);
tangentNormal.xy *= _BumpScale;
tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
//纹理颜色采样，注意 tex2D(_MainTex, i.uv).rgb * _Color.rgb 是一个矢量，而不是标量，它的结果 = (tex2D(_MainTex, i.uv).r * _Color.r, tex2D(_MainTex, i.uv).g * _Color.g, tex2D(_MainTex, i.uv).b * _Color.b)
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
//获取环境光部分，环境光直接加到输出结果中即可
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
//注意用了 saturate 操作之后，与光线方向夹角大于 90 的面是完全不吃光的，这样背光的地方漫反射的颜色就为 (0,0,0)，最终看到的颜色只是环境光与纹理颜色混合之后的结果
fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(tangentNormal, tangentLightDir));
//求视角方向和光线方向的平均方向
fixed3 halfDir = normalize(tangentViewDir + tangentLightDir);
//计算高光反射的值，因为是 pow 的关系，而且 dot(tangentNormal, halfDir) 小于 1，所以 _Gloss 越大 高光部分越小
//注意高光反射的还是光源的颜色，并没有以纹理颜色为基础
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(tangentNormal, halfDir)), _Gloss);
//返回最终颜色，把 环境光 加 漫反射 加 高光反射 写入结果
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
//如果上面的 shader 都不行，则用默认的 Specular Shader
FallBack "Specular"
}在世界空间中计算光照:
Shader "Unity Shaders Book/Chapter7" {
Properties
{
_Color("Color Tint", Color) = (1,1,1,1)
_MainTex("Main Tex", 2D) = "white" {}
_BumpMap("Normal Map", 2D) = "bump" {}
_BumpScale("Bump Scale", Float) = 1.0
_Specular("Specular", Color) = (1,1,1,1)
_Gloss("Gloss", Range(8.0,256)) = 20
}
SubShader
{
Pass
{
Tags {"LightMode" = "ForwardBase"}
CGPROGRAM
//定义顶点着色器函数和片段着色器函数
#pragma vertex vert
#pragma fragment frag
//为了访问光源相关参数，要引入 Lighting 库
#include "Lighting.cginc"
float4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;
float4 _Specular;
float _Gloss;
//传入顶点着色器的参数
struct a2v
{
float4 vertex : POSITION; //顶点坐标
float3 normal : NORMAL; //法线方向
float4 tangent : TANGENT; //切线方向
float4 texcoord : TEXCOORD0; //纹理坐标
};
//片元着色器参数，在顶点着色器返回值上进行插值后传入
struct v2f
{
float4 pos : SV_POSITION; //必须的参数，而且是固定的转换方式，把顶点坐标从模型空间转到裁剪空间中，利用 UnityObjectToClipPos(vertex)
float4 uv: TEXCOORD0; //纹理坐标(存于xy中)，法线纹理(存于zw中)
float4 TtoW0 : TEXCOORD1;
float4 TtoW1 : TEXCOORD2;
float4 TtoW2 : TEXCOORD3;
};
//顶点着色器，顶点着色器只作用在每个顶点，其它像素点通过插值传入片元着色器处理
v2f vert(a2v v)
{
v2f o;
//固定写法，把顶点坐标从模型空间转换到世界坐标
o.pos = UnityObjectToClipPos(v.vertex);
//计算纹理 uv 等于纹理坐标 x 纹理缩放 + 纹理位移
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
//o.uv = TRANSFORM_TEX(v.textcoord, _MainTex);
//计算法线纹理 uv 等于纹理坐标 x 纹理缩放 + 纹理位移
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;
//顶点坐标从模型空间转换到世界空间下 (在世界空间中计算光照需要片元点的坐标)
fixed3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;
o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);
return o;
}
fixed4 frag(v2f i) : SV_Target
{
//片元点在世界空间下的坐标
float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
//世界空间中光线的方向，指向光源的方向
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
//世界空间中的视线方向，指向视点
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
//获取世界空间下的法线方向，固定算法
fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));
bump.xy *= _BumpScale;
bump.z = sqrt(1.0 - saturate(dot(bump.xy, bump.xy)));
//把法线从切线空间转换到世界空间中
bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
//纹理颜色采样，注意 tex2D(_MainTex, i.uv).rgb * _Color.rgb 是一个矢量，而不是标量，它的结果 = (tex2D(_MainTex, i.uv).r * _Color.r, tex2D(_MainTex, i.uv).g * _Color.g, tex2D(_MainTex, i.uv).b * _Color.b)
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
//获取环境光部分，环境光直接加到输出结果中即可
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
//注意用了 saturate 操作之后，与光线方向夹角大于 90 的面是完全不吃光的，这样背光的地方漫反射的颜色就为 (0,0,0)，最终看到的颜色只是环境光与纹理颜色混合之后的结果
fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(bump, lightDir));
//求视角方向和光线方向的平均方向
fixed3 halfDir = normalize(viewDir + lightDir);
//计算高光反射的值，因为是 pow 的关系，而且 dot(bump, halfDir) 小于 1，所以 _Gloss 越大 高光部分越小
//注意高光反射的还是光源的颜色，并没有以纹理颜色为基础
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(bump, halfDir)), _Gloss);
//返回最终颜色，把 环境光 加 漫反射 加 高光反射 写入结果
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
//如果上面的 shader 都不行，则用默认的 Specular Shader
FallBack "Specular"
}
渐变纹理：
Shader "Unlit/Chapter7-2"
{
Properties
{
_Color ("Color Tint", Color) = (1,1,1,1)
_RampTex ("Ramp Tex", 2D) = "white" {}
_Specular ("Specular", Color) = (1,1,1,1)
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader
{
Pass
{
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Color;
sampler2D _RampTex;
float4 _RampTex_ST;
fixed4 _Specular;
float _Gloss;
struct a2v
{
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct v2f
{
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float3 worldPos : TEXCOORD1;
float2 uv : TEXCOORD2;
};
v2f vert (a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
o.uv = TRANSFORM_TEX(v.texcoord, _RampTex);
return o;
}
fixed4 frag (v2f i) : SV_Target
{
fixed3 worldNormal = normalize(i.worldNormal);
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
//halfLambert 为吃光度， 范围是 [0,1]
fixed halfLambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
//RampTexure 是一个一维纹理，用 halfLambert 查找对应的颜色，RampTexure 越小，对于的纹理颜色越深
fixed3 diffuseColor = tex2D(_RampTex, fixed2(halfLambert, halfLambert)).rgb * _Color.rgb;
fixed3 diffuse = _LightColor0.rgb * diffuseColor;
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
fixed3 halfDir = normalize(worldLightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal, halfDir)), _Gloss);
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
FallBack "Specular"
}