扩充PL/0语言语法的EBNF描述

<程序> ::= <分程序>.
<分程序> ::= [<常量说明部分>] [<变量说明部分>] [<过程说明部分>] <语句>
<常量说明部分> ::= const <常量定义> { , <常量定义> };
<常量定义> ::= 	<标识符> = <无符号整数>
<无符号整数> ::= <数字>{<数字>}
<变量说明部分> ::= var <变量声明> { , <变量声明> } ;
<变量声明> ::= <标识符> | <标识符>(<数组界>:<数组界>)
<数组界> ::= <标识符> | <无符号整数>
<标识符> ::= <字母>{<字母>|<数字>}
<过程说明部分> ::= <过程首部> <分程序> {; <过程说明部分> }; 
<过程首部> ::= procedure <标识符>
<语句> ::= <赋值语句> | <复合语句> | <条件语句> | <当型循环语句> | <重复语句> | <过程调用语句> | <读语句> | <写语句>
<赋值语句> ::= <变量引用>:=<表达式>
<变量引用> ::= <标识符> | <标识符>‘(‘<表达式> ‘)’
<复合语句> ::= begin <语句>{;<语句>}end
<条件语句> ::= if <条件> then <语句> [else <语句>]
<条件> ::= <表达式><关系运算符><表达式>|odd<表达式>
<表达式> ::= [+|-]<项>{<加法运算符><项>} 
<项> ::= <因子>{ <乘法运算符><因子> } 
<因子> ::= <变量引用> | <无符号整数> | ‘(‘<表达式>’)’
<加法运算符> ::= + | -
<乘法运算符> ::= * | /
<关系运算符> ::= = | # | < | <= | > | >=
<当型循环语句> ::= while <条件> do <语句>
<过程调用语句> ::= call <标识符>[‘(’<传值参数> {,<传值参数> }‘)’]
<传值参数> ::= <表达式>
<读语句> ::= read ‘(’<变量引用> { , <变量引用> }‘)’
<写语句> ::= write‘(’<表达式> {, <表达式> }‘)’
<字母> ::= a|b|...|X|Y|Z
<数字> ::= 0|1|...|8|9