Unity3D 模板测试实现平面描边（一）

最近群里有个朋友想做个平面描边，使用模型的描边不起作用，想来应该是模型的描边是通过计算模型背面的法线向外扩散来实现描边的，而纯平面背面一般不存在顶点，所以无法实现描边。之前在学习opengl的时候，记得模板测试有个例子就是用模板测试来实现描边，于是按照同样的思路尝试在Unity3D中实现平面描边。其实核心思路非常简单，就是一个pass正常绘制，并写入一个模板缓存值，另一个pass将平面进行扩大，然后进行模板测试，扩大部分顶点可以测试通过，原来区域的顶点无法通常模板测试，得到一个外边框区域，填充上颜色就是需要的描边。

首先在Properties中加入_Expand 和_OutlineCol属性，分别用于调节描边的宽度和颜色

Properties {
     ... 
     _Expand ("Thickness", Range(1,1.5)) = 1.2//放大系数，影响描边的粗细
     _OutlineCol ("Outline Color", Color) = (0,1,0,1)//描边的颜色
}

第一个pass正常绘制，并且总是通过模板测试，然后将值1写入模板缓存区

//模板测试总是通过，并写入模板缓存区值为1
Stencil
{
     Ref 1
     Comp always
     Pass replace
     Fail keep
     ZFail keep
}

第二个pass中对顶点坐标三个轴向放大

fixed4 _OutlineCol;//描边的颜色
float _Expand;//放大系数，影响描边的粗细

v2f vert (appdata v)
{
    v2f o;
    v.vertex.xyz *= _Expand;//对象空间中将顶点坐标放大
    o.vertex = UnityObjectToClipPos(v.vertex);
    return o;
}

在第二个pass中对第一个pass中写入的模板值1进行反向测试，这样的目的就是为了使放大的区域通过模板测试，正常的区域丢弃。

Stencil
{
    Ref 1
    Comp notequal
    Pass decrWrap
    Fail keep
    ZFail keep
}

效果如下：

平面描边

可以通过Thickness 调节放大系数来调节描边的粗细，Outline Color调节描边的颜色。
好了，最后给出完整代码。 如果原来的平面有自带的shader，直接合并关键代码部分即可。

Shader "Custom/PlaneOutline" {
Properties {
    _MainTex ("Base (RGB)", 2D) = "white" {}
    _Color ("Color", Color) = (1,1,1,1)
    //------------关键代码---------
    _Expand ("Thickness",Range(1,1.5)) = 1.1
    _OutlineCol ("Outline Color", Color) = (0,1,0,1)
    //------------关键代码---------
}

SubShader {
    Tags { "RenderType"="Opaque" }
    LOD 300

    Pass {
        //------------关键代码---------
        //模板测试总是通过，并写入模板缓存区值为1
        Stencil
        {
            Ref 1
            Comp always
            Pass replace
            Fail keep
            ZFail keep
        }
        //------------关键代码---------

        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #pragma target 2.0

        #include "UnityCG.cginc"

        struct appdata_t {
            float4 vertex : POSITION;
            float2 texcoord : TEXCOORD0;
            UNITY_VERTEX_INPUT_INSTANCE_ID
        };

        struct v2f {
            float4 vertex : SV_POSITION;
            float2 texcoord : TEXCOORD0;
            UNITY_FOG_COORDS(1)
            UNITY_VERTEX_OUTPUT_STEREO
        };

        sampler2D _MainTex;
        float4 _MainTex_ST;
        fixed4 _Color;

        v2f vert (appdata_t v)
        {
            v2f o;
            UNITY_SETUP_INSTANCE_ID(v);
            UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);
            o.vertex = UnityObjectToClipPos(v.vertex);
            o.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
            return o;
        }

        fixed4 frag (v2f i) : SV_Target
        {
            fixed4 col = tex2D(_MainTex, i.texcoord);
            col = col * _Color;
            UNITY_OPAQUE_ALPHA(col.a);
            return col;
        }
        ENDCG
    }

    //------------关键代码---------
    Pass {
        //模板缓存区的值与1比较，不相同即测试失败，并保持模板缓存区的值不变
        Stencil
        {
            Ref 1
            Comp notequal
            Pass decrWrap
            Fail keep
            ZFail keep
        }

        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #pragma target 2.0

        #include "UnityCG.cginc"

        struct appdata {
            float4 vertex : POSITION;
        };

        struct v2f {
            float4 vertex : SV_POSITION;
        };

        fixed4 _OutlineCol;
        float _Expand;

        v2f vert (appdata v)
        {
            v2f o;
            v.vertex.xyz *= _Expand;//对象空间中将顶点坐标放大
            o.vertex = UnityObjectToClipPos(v.vertex);
            return o;
        }

        fixed4 frag (v2f i) : SV_Target
        {
            return _OutlineCol;
        }
    ENDCG
    }
    //------------关键代码---------
}
}